calc_k_g.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Subroutine: CALC_K_g                                                C
!  Purpose: Calculate the effective conductivity of fluid phase        C
!                                                                      C
!                                                                      C
!  Comments:                                                           C
!  This routine will not be called if k_g0 is defined                  C
!                                                                      C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
      SUBROUTINE calc_k_g()

! Modules
!---------------------------------------------------------------------//
      USE param1, only: undefined
      USE physprop, only: k_g0, k_g
      USE sendrecv, only: send_recv
! invoke user defined quantity
      USE usr_prop, only: usr_kg, calc_usr_prop
      USE usr_prop, only: gas_conductivity
      IMPLICIT NONE
!---------------------------------------------------------------------//

      IF (usr_kg) THEN
         CALL calc_usr_prop(gas_conductivity,lm=0)
      ELSEIF (k_g0 == undefined) THEN
! unncessary check but included for clarity
         CALL calc_default_kg
      ENDIF

      CALL send_recv(k_g, 2)

      RETURN
      END SUBROUTINE calc_k_g


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Purpose: Compute the default value for gas conductivity where the   C
!  gas phase is assumed to be air                                      C
!  Author:M. Syamlal                                  Date: 24-APR-96  C
!                                                                      C
!  Literature/Document References:                                     C
!  Bird, Stewart, and Lightfoot (1960) --                              C
!    Temperature dependence from formula 8.3-12 on p. 255 and          C
!    conductivity value at 300 K from p. 263                           C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
      SUBROUTINE calc_default_kg

! Modules
!---------------------------------------------------------------------//
      use compar, only: ijkstart3, ijkend3
      USE fldvar, only: t_g
      USE functions, only: fluid_at
      USE param1, only: zero
      USE physprop, only: k_g
      USE run, only: units
      IMPLICIT NONE

! Local variables
!---------------------------------------------------------------------//
! Indices
      INTEGER :: IJK
!---------------------------------------------------------------------//

!!$omp parallel do private(ijk) &
!!$omp& schedule(dynamic,chunk_size)
      DO ijk = ijkstart3, ijkend3
         IF (fluid_at(ijk)) THEN
! Gas conductivity (air) in cal/(s.cm.K)
            k_g(ijk) = 6.02d-5*sqrt(t_g(ijk)/300.d0)
         ELSE
            k_g(ijk) = zero
         ENDIF

! 1 cal = 4.183925D0 J
         IF (units == 'SI') k_g(ijk) = 418.3925d0*k_g(ijk)      !J/s.m.K

      ENDDO

      RETURN
      END SUBROUTINE calc_default_kg