check_output_control.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!  Subroutine: CHECK_OUTPUT_CONTROL                                    !
!  Purpose: Check the output control namelist section                  !
!                                                                      !
!  Author: P. Nicoletti                               Date: 27-NOV-91  !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_output_control

! Global Variables:
!---------------------------------------------------------------------//
! Time intervalue between updating the RES and SPx files.
      use output, only: res_dt, spx_dt
! Time-step intervalue between updating the .LOG file.
      use output, only: nlog
! Flag: Use the K-Epsilon model
      use run, only: k_epsilon
! Number of arrays to store in SPA
      use rxns, only: nrr
! VTK
      use vtk
      USE run, only: run_name
      USE physprop, only: mmax
      USE scalars, only :nscalar
      USE mpi_utility, only: xlength,ylength,zlength
      USE discretelement, only:discrete_element
      USE discretelement, only: particle_orientation
      USE cutcell, only: use_stl

! Global Parameters:
!---------------------------------------------------------------------//
! Number aliases
      use param1, only: undefined, undefined_i, zero, large_number
! Number of SPx files.
      USE param1, only: n_spx

! Global Module procedures:
!---------------------------------------------------------------------//
      use error_manager

      IMPLICIT NONE

! Local Variables:
!---------------------------------------------------------------------//
! Loop counter
      INTEGER :: LC

      INTEGER :: L,M,N,LV,N_VTK_REGIONS,R

!......................................................................!


! Initialize the error manager.
      CALL init_err_msg("CHECK_OUTPUT_CONTROL")


! Check the values specified for the RES file.
      IF (res_dt==undefined)THEN
         WRITE(err_msg,1000) 'RES_DT'
         CALL flush_err_msg(abort=.true.)
      ELSEIF(res_dt <= zero) THEN
         WRITE(err_msg,1002) 'RES_DT', res_dt
         CALL flush_err_msg(abort=.true.)
      ENDIF


! Check the SPx Files
      spx_lp: DO lc = 1, n_spx

! Disable writing the .SPA file if nRR is unspecified.
         IF(lc == 10) THEN
            IF(nrr == 0) THEN
               IF (spx_dt(lc) == undefined) spx_dt(lc) = large_number
               cycle spx_lp
            ENDIF

! Disable writing the .SPB file if K-Epsilon is unspecified.
         ELSEIF(lc == 11) THEN
            IF(.NOT.k_epsilon) THEN
               IF (spx_dt(lc)==undefined)spx_dt(lc) = large_number
               cycle spx_lp
            ENDIF

! Verify the remaining SPx files.
         ELSE
            IF(spx_dt(lc) == undefined) THEN
               WRITE(err_msg,1000) ivar('SPX_DT',lc)
               CALL flush_err_msg(abort=.true.)

            ELSEIF(spx_dt(lc) <= zero) THEN
               WRITE(err_msg,1001) ivar('SPX_DT',lc), spx_dt(lc)
               CALL flush_err_msg(abort=.true.)
            ENDIF
         ENDIF
      ENDDO spx_lp

! Verify that the LOG frequency is valid.
      IF(nlog <= 0) THEN
         WRITE(err_msg,1003) 'NLOG', nlog
         CALL flush_err_msg(abort=.true.)
      ENDIF

! Check VTK regions

      IF(frame(1)<-1) THEN
         WRITE(err_msg, 2000) trim(ival(frame(1)))
         CALL flush_err_msg(abort=.true.)
      ENDIF

 2000 FORMAT('Error 2000: Invalid value for FRAME = ',a'. Acceptable ',&
         'values',/'are integers >= -1. Please correct mfix.dat and',/ &
         'try again.')

      IF(vtk_dt(1)<zero) THEN
          WRITE(err_msg,2001) trim(ival(vtk_dt(1)))
         CALL flush_err_msg(abort=.true.)
      ENDIF

 2001 FORMAT('Error 2001: Invalid value for VTK_DT = ',a'. Acceptable',&
         ' values',/'are positive numbers (e.g., 0.1).  Please ',      &
         'correct mfix.dat and',/'try again.')

      n_vtk_regions = 0
      DO l = 1, dimension_vtk
         vtk_defined(l) = .false.
         IF (vtk_x_w(l) /= -undefined)   vtk_defined(l) = .true.
         IF (vtk_x_e(l) /=  undefined)   vtk_defined(l) = .true.
         IF (vtk_y_s(l) /= -undefined)   vtk_defined(l) = .true.
         IF (vtk_y_n(l) /=  undefined)   vtk_defined(l) = .true.
         IF (vtk_z_b(l) /= -undefined)   vtk_defined(l) = .true.
         IF (vtk_z_t(l) /=  undefined)   vtk_defined(l) = .true.

         IF(.NOT.vtk_defined(l)) cycle
         n_vtk_regions =  n_vtk_regions + 1
      ENDDO   ! end loop over (l = 1,dimension_vtk)

! There must be at least one VTK region defined
! If this is not the case, define the entire domain as default region
      IF(write_vtk_files.AND.n_vtk_regions==0) THEN
         vtk_defined(1) = .true.
         vtk_x_w(1) = zero
         vtk_x_e(1) = xlength
         vtk_y_s(1) = zero
         vtk_y_n(1) = ylength
         vtk_z_b(1) = zero
         vtk_z_t(1) = zlength
         vtk_filebase(1) = run_name
      ENDIF

! If VTK_VAR is defined, fill-up the variable list
! for the vtk subdomains
      DO l = 1, dim_vtk_var
         IF(vtk_var(l)/=undefined_i) vtk_varlist(:,l) = vtk_var(l)
      ENDDO


      DO l = 1, dimension_vtk

         IF(.NOT.vtk_defined(l)) cycle

         DO lv = 1, dim_vtk_var

            SELECT CASE (vtk_varlist(l,lv))

               CASE (1)
                  vtk_ep_g(l) = .true.

               CASE (2)
                  vtk_p_g(l)    = .true.
                  vtk_p_star(l) = .true.

               CASE (3)
                  vtk_vel_g(l) = .true.

               CASE (4)
                  DO m = 1,mmax
                     vtk_vel_s(l,m) = .true.
                  END DO

               CASE (5)
                  DO m = 1,mmax
                     vtk_rop_s(l,m) = .true.
                  END DO

               CASE (6)
                  vtk_t_g(l) = .true.
                  DO m = 1,mmax
                     vtk_t_s(l,m) = .true.
                  END DO

               CASE (7)
                 !DO N = 1,NMAX(0)
                    vtk_x_g(l,:) = .true.
                 !END DO

                  DO m = 1, mmax
                    !DO N = 1,NMAX(M)
                        vtk_x_s(l,m,:) = .true.
                    !END DO
                  END DO

               CASE (8)
                  DO m = 1,mmax
                     vtk_theta_m(l,m) = .true.
                  END DO

               CASE (9)
                  DO n = 1,nscalar
                     vtk_scalar(l,n) =.true.
                  END DO

               CASE (10)
                  DO r = 1,nrr
                     vtk_rrate(l,r) = .true.
                  END DO

               CASE (11)
                  IF(k_epsilon) THEN
                     vtk_k_turb_g(l) = .true.
                     vtk_e_turb_g(l) = .true.
                  ENDIF

               CASE (12)
                  vtk_vorticity(l) = .true.
                  vtk_lambda_2(l)  = .true.

               CASE (100)
                  vtk_partition(l) = .true.

               CASE (101)
                  vtk_bc_id(l) = .true.

               CASE (102)
                  vtk_dwall(l) = .true.

               CASE (103)
                  IF(discrete_element.AND.use_stl) THEN
                     vtk_facet_count_des(l) = .true.
                  ENDIF

               CASE (104)
                  IF(discrete_element.AND.use_stl) THEN
                     vtk_nb_facet_des(l) = .true.
                  ENDIF

               CASE(999)
                  vtk_ijk(l) = .true.

               CASE(1000)
                  vtk_normal(l) = .true.

               CASE (1001)
                  vtk_debug(l,1) = .true.

               CASE (1002)
                  vtk_debug(l,2) = .true.

               CASE (1003)
                  vtk_debug(l,3) = .true.

               CASE (1004)
                  vtk_debug(l,4) = .true.

               CASE (1005)
                  vtk_debug(l,5) = .true.

               CASE (1006)
                  vtk_debug(l,6) = .true.

               CASE (1007)
                  vtk_debug(l,7) = .true.

               CASE (1008)
                  vtk_debug(l,8) = .true.

               CASE (1009)
                  vtk_debug(l,9) = .true.

               CASE (1010)
                  vtk_debug(l,10) = .true.

               CASE (1011)
                  vtk_debug(l,11) = .true.

               CASE (1012)
                  vtk_debug(l,12) = .true.

               CASE (1013)
                  vtk_debug(l,13) = .true.

               CASE (1014)
                  vtk_debug(l,14) = .true.

               CASE (1015)
                  vtk_debug(l,15) = .true.


               CASE (0) ! do nothing

               CASE (undefined_i) ! do nothing

               CASE DEFAULT
                  WRITE(err_msg,2100) trim(ival(l)),                   &
                     trim(ival(vtk_var(l)))
                  CALL flush_err_msg(abort=.true.)
            END SELECT

 2100 FORMAT(' Error 2100: Unknown VTK variable flag ',a,':',a,       /&
         'Available flags are:',                                      /&
         '  1 : Void fraction (EP_g)',                                /&
         '  2 : Gas pressure, solids pressure (P_g, P_star)',         /&
         '  3 : Gas velocity (U_g, V_g, W_g)',                        /&
         '  4 : Solids velocity (U_s, V_s, W_s)',                     /&
         '  5 : Solids density (ROP_s)',                              /&
         '  6 : Gas and solids temperature (T_g, T_s1, T_s2)',        /&
         '  7 : Gas and solids mass fractions (X_g, X-s)',            /&
         '  8 : Granular temperature (G)',                            /&
         '  9 : User defined scalars',                                /&
         ' 10 : Reaction Rates',                                      /&
         ' 11 : Turbulence quantities (k and ε)',                     /&
         ' 12 : Gas Vorticity magn and Lambda_2(VORTICITY,LAMBDA_2)', /&
         '100: Processor assigned to scalar cell (Partition)',        /&
         '101: Boundary condition flag for scalar cell (BC_ID)',      /&
         'Please correct the mfix.dat file.')


         ENDDO

! Activate particle orientation calculation if one vtk region needs it.
         IF(vtk_part_orientation(l)) particle_orientation = .true.

      ENDDO   ! end loop over (l = 1,dimension_vtk)

! Finalize the error manager.
      CALL finl_err_msg

      RETURN

 1000 FORMAT('Error 1000: Required input not specified: ',a,/'Please ',&
         'correct the mfix.dat file.')

 1001 FORMAT('Error 1001: Illegal or unknown input: ',a,' = ',a,/      &
         'Please correct the mfix.dat file.')

 1002 FORMAT('Error 1002: Illegal or unknown input: ',a,' = ',e14.6,/  &
         'Please correct the mfix.dat file.')

 1003 FORMAT('Error 1003: Illegal or unknown input: ',a,' = ',i4,/     &
         'Please correct the mfix.dat file.')

      END SUBROUTINE check_output_control