des_thermo_conv.f

Go to the documentation of this file.

#include "version.inc"
!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Module name: CONV_GS_DES1                                           !
!  Author: J.Musser: 16-Jun-10                                         !
!                                                                      !
!  Purpose: This routine is called from the DISCRETE side to calculate !
!  the gas-particle convective heat transfer.                          !
!                                                                      !
!  Comments: Explicitly coupled simulations use a stored convective    !
!  heat transfer coefficient. Otherwise, the convective heat transfer  !
!  coeff is calculated every time step and the total interphase energy !
!  transfered is 'stored' and used explictly in the gas phase. The     !
!  latter conserves all energy
!                                                                      !
!  REF: Zhou, Yu, and Zulli, "Particle scale study of heat transfer in !
!       packed and bubbling fluidized beds," AIChE Journal, Vol. 55,   !
!       no 4, pp 868-884, 2009.                                        !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE conv_gs_des1

      use constant, only: pi
      Use des_thermo
      Use discretelement
      Use fldvar
      Use interpolation
      Use param1
      use des_thermo, only: gammaxsa
      use geometry, only: no_k
      use particle_filter, only: des_interp_on
      use particle_filter, only: filter_cell
      use particle_filter, only: filter_weight
      use particle_filter, only: filter_size
      use functions, only: fluid_at
      use functions, only: is_normal
      IMPLICIT NONE

      DOUBLE PRECISION :: lTg, GAMMA
      DOUBLE PRECISION :: Qcv_DT, Qcv
      DOUBLE PRECISION :: l4Pi
      INTEGER :: IJK, LC, NP

      l4pi = 4.0d0*pi

      DO np=1,max_pip
         IF(.NOT.is_normal(np)) cycle

! Calculate the gas temperature.
         IF(des_interp_on) THEN
            ltg = zero
            DO lc=1,filter_size
               ijk = filter_cell(lc,np)
               ltg = ltg + t_g(ijk)*filter_weight(lc,np)
            ENDDO
         ELSE
            ijk = pijk(np,4)
            ltg = t_g(ijk)
         ENDIF

         ijk = pijk(np,4)

! Avoid convection calculations in cells without fluid (cut-cell)
         IF(.NOT.fluid_at(ijk)) THEN
            gammaxsa(np) = zero
            conv_qs(np) = zero

! For explicit coupling, use the heat transfer coefficient calculated
! for the gas phase heat transfer calculations.
         ELSEIF(des_explicitly_coupled) THEN
            conv_qs(np) = gammaxsa(np)*(ltg - des_t_s(np))

         ELSE

! Calculate the heat transfer coefficient.
            CALL calc_gamma_des(np, gamma)
            gammaxsa(np) = gamma* l4pi*des_radius(np)*des_radius(np)

! Calculate the rate of heat transfer to the particle
            qcv = gammaxsa(np)*(ltg - des_t_s(np))
! Store convection source in global energy source array.
            q_source(np) = q_source(np) + qcv

! Calculate the gas phase source term components.
            qcv_dt = qcv*dtsolid
            IF(des_interp_on) THEN
               DO lc=1,filter_size
                  conv_sc(ijk)=conv_sc(ijk)-qcv_dt*filter_weight(lc,np)
               ENDDO
            ELSE
               conv_sc(ijk) = conv_sc(ijk) - qcv_dt
            ENDIF
         ENDIF
      ENDDO

! Note that MPI sync is managed at the end of des_time_march for
! non-explicitly coupled cases that use interpolation.

      RETURN
      END SUBROUTINE conv_gs_des1


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: CONV_GS_GAS1                                            !
!  Author: J.Musser                                   Date: 21-NOV-14  !
!                                                                      !
!                                                                      !
!  Purpose: This routine is called from the CONTINUUM. It calculates   !
!  the scalar cell center drag force acting on the fluid using         !
!  interpolated values for the gas velocity and volume fraction. The   !
!  The resulting sources are interpolated back to the fluid grid.      !
!                                                                      !
!  NOTE: The loop over particles includes ghost particles so that MPI  !
!  communications are needed to distribute overlapping force between   !
!  neighboring grid cells. This is possible because only cells "owned" !
!  by the current process will have non-zero weights.                  !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE conv_gs_gas1

! Flag: The fluid and discrete solids are explicitly coupled.
      use discretelement, only: des_explicitly_coupled
! Size of particle array on this process.
      use discretelement, only: max_pip
! Flag to use interpolation
      use particle_filter, only: des_interp_on
! Interpolation cells and weights
      use particle_filter, only: filter_cell, filter_weight, filter_size
! IJK of fluid cell containing particles center
      use discretelement, only: pijk
! Particle temperature
      use des_thermo, only: des_t_s
! Gas phase energy equation sources
      use des_thermo, only: conv_sp, conv_sc
      Use discretelement, only: des_radius
! Heat transfer coefficint (GAMMA) multiplied by sufrace area
      use des_thermo, only: gammaxsa
! Funtion for identifying fluid cells and normal particles.
      use functions, only: fluid_at
      use functions, only: is_normal
! MPI function for collecting interpolated data from ghost cells.
      use sendrecvnode, only: des_collect_gdata
! MPI wrapper for halo exchange.
      use sendrecv, only: send_recv

! Global Parameters:
!---------------------------------------------------------------------//
! Double precision values.
      use param1, only: zero, one
      use constant, only: pi

      IMPLICIT NONE

! Loop counters: Particle, fluid cell, neighbor cells
      INTEGER :: NP, IJK, LC
! Interpolation weight
      DOUBLE PRECISION :: WEIGHT
      DOUBLE PRECISION :: GAMMAxSAxTp, GAMMA
      DOUBLE PRECISION :: l4Pi

      l4pi = 4.0d0*pi

! Initialize fluid cell values.
      conv_sc = zero
      conv_sp = zero

! Calculate the gas phase forces acting on each particle.
      DO np=1,max_pip

         IF(.NOT.is_normal(np)) cycle
         IF(.NOT.fluid_at(pijk(np,4))) cycle

! Calculate the heat transfer coefficient.
         CALL calc_gamma_des(np, gamma)

! Calculate the surface area of the particle

         gammaxsa(np) = gamma*l4pi*des_radius(np)*des_radius(np)
         gammaxsaxtp = gammaxsa(np)*des_t_s(np)

         IF(des_interp_on) THEN
            DO lc=1,filter_size
               ijk = filter_cell(lc,np)
               weight = filter_weight(lc,np)

               conv_sc(ijk) = conv_sc(ijk) + weight*gammaxsaxtp
               conv_sp(ijk) = conv_sp(ijk) + weight*gammaxsa(np)
            ENDDO
         ELSE
            ijk = pijk(np,4)

            conv_sc(ijk) = conv_sc(ijk) + gammaxsaxtp
            conv_sp(ijk) = conv_sp(ijk) + gammaxsa(np)
         ENDIF

      ENDDO

! Add in data stored in ghost cells from interpolation. This call must
! preceed the SEND_RECV to avoid overwriting ghost cell data.
      IF(des_interp_on) THEN
         CALL des_collect_gdata(conv_sc)
         CALL des_collect_gdata(conv_sp)
      ENDIF

! Update the drag force and sources in ghost layers.
      CALL send_recv(conv_sc, 2)
      CALL send_recv(conv_sp, 2)

      RETURN
      END SUBROUTINE conv_gs_gas1




!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!  Subroutine: ZERO_ENERGY_SOURCE                                      !
!                                                                      !
!  Purpose: ZERO out the array that passes energy source terms back to !
!  the continuum model. Additional entries may be needed to include    !
!  heat transfer to the hybrid mode.                                   !
!                                                                      !
!  Author: J.Musser                                   Date: 15-Jan-11  !
!                                                                      !
!  Comments:                                                           !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE zero_energy_source

      Use des_thermo
      Use param1

      IMPLICIT NONE

      conv_sc = zero
      conv_sp = zero

      RETURN
      END SUBROUTINE zero_energy_source