write_spx0.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Module name: WRITE_SPX0(L, unit_add)                                !
!  Author: P. Nicoletti                               Date: 13-DEC-91  !
!                                                                      !
!  Purpose: Write out the initial single percision data files.         !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE write_spx0(L, UNIT_ADD)

! Global Variables:
!---------------------------------------------------------------------//
! User defined run_name
      use run, only: run_name
! Calendar information for start of run.
      use machine, only: id_month, id_day, id_year
! Time information for start of run.
      use machine, only: id_hour, id_minute, id_second
! Base file unit for SPx files.
      use funits, only: unit_spx
! Flag: Use distributed I/O
      USE cdist, only: bdist_io
! Rank of current process.
      use compar, only: mype
! Rank assigned to serial I/O
      use compar, only: pe_io

      IMPLICIT NONE

! Passed Variables:
!----------------------------------------------------------------------!
! Index of SPx file.
      INTEGER, INTENT(IN) :: L
! Offset for use in post_mfix
      INTEGER, INTENT(IN) :: UNIT_ADD

! Local Variables:
!----------------------------------------------------------------------!
! File version ID
      CHARACTER(LEN=512) :: VERSION
! UNIT_SPX + offset from post_mfix
      INTEGER :: USPX
! Generic SPx end characters.
      CHARACTER(len=15), PARAMETER :: EXT_END = '123456789ABCDEF'

!......................................................................!

! Serial I/O: only PE_IO writes to a single file [default]
! Distributed I/O: all ranks write their own output file.
      IF(mype /= pe_io .AND. .NOT.bdist_io) RETURN

! Construct the file version string.
      version = 'SPx = 02.00'
      WRITE(version(3:3),"(A1)") ext_end(l:l)

! Calculate the SPx file unit
      uspx = unit_spx + unit_add + l

! Write the SPx file header.
      WRITE(uspx, rec=1) version
      WRITE(uspx, rec=2) run_name, id_month, id_day, id_year,          &
         id_hour, id_minute, id_second

!  The first field contains the pointer to the next record.
!  The second field contains the number of records written each time step
!  (The 4 and -1 are overwritten in WRITE_SPX1)
      WRITE (uspx, rec=3) 4, -1

      IF(unit_add == 0) FLUSH(uspx)

      RETURN
      END SUBROUTINE write_spx0