cn_extrapol.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Module name: CN_EXTRAPOL                                            C
!                                                                      C
!  Purpose: Performs the explicit extrapolation phase when             C
!           Crank-Nicholson based second order accurate time           C
!           integration is activated (CN_ON = TRUE)                    C
!                                                                      C
!           Make sure dt is set to dt/2 when CN_ON=T                   C
!                                                                      C
!  Author: Aeolus Research, Inc. (A.Gel)             Date: APR-30-01   C
!                                                                      C
!  Literature/Document References:                                     C
!                                                                      C
!  Variables referenced: ROP_g, EP_g, ROP_s, IJKMAX2, MMAX, U_s, V_s,  C
!                        W_s                                           C
!                                                                      C
!  Variables modified: 19 field variables are time integrated
!                      EP_g , EP_go  : Void fraction at t & t-dt time  C
!                      P_G , P_go    : Gas pressure at t & t-dt time   C
!                      P_star,P_staro: Solids pressure that maintains  C
!                                      EP_g >= EP_star                 C
!                      RO_g , RO_go  : Gas density                     C
!                      ROP_g , ROP_go: Macroscopic gas density         C
!                      U_g , U_go    : x-component of gas velocity     C
!                      V_g , V_go    : y-component of gas velocity     C
!                      W_g , W_go    : z-component of gas velocity     C
!                      T_g , T_go    : Gas phase temperature           C
!                      X_g , X_go    : Gas species mass fraction       C
!                      Scalar,Scalaro: User-defined Scalars            C
!                      ROP_s , ROP_so: Macroscopic density of solids   C
!                                      phases                          C
!                      T_s , T_so    : Solid phase temperature         C
!                      THETA_m,THETA_mo: Granular temperature of m^th  C
!                                        phase                         C
!                      trD_S_C, trD_S_Co: trace of D_s                 C
!                      U_s , U_so    : x-component of solid velocity   C
!                      V_s , V_so    : y-component of solid velocity   C
!                      W_s , W_so    : z-component of solid velocity   C
!                      X_s , X_so    : Solid species mass fraction     C
!                                                                      C
!                                                                      C
!  Local variables: NONE                                               C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
!
      SUBROUTINE cn_extrapol
!...Translated by Pacific-Sierra Research VAST-90 2.06G5  12:17:31  12/09/98
!...Switches: -xf
!
!-----------------------------------------------
!   M o d u l e s
!-----------------------------------------------
      USE param
      USE param1
      USE parallel
      USE scales
      USE constant
      USE physprop
      USE fldvar
      USE scalars
      USE trace
      USE run
      USE geometry
      USE indices
      USE compar
      USE mpi_utility
      USE functions
      IMPLICIT NONE
!-----------------------------------------------
!   G l o b a l   P a r a m e t e r s
!-----------------------------------------------
!-----------------------------------------------
!   L o c a l   P a r a m e t e r s
!-----------------------------------------------
!-----------------------------------------------
!   L o c a l   V a r i a b l e s
!-----------------------------------------------
!
!                    Indices
      INTEGER :: M, IJK
!-----------------------------------------------
!
!!!$omp    parallel do private(IJK)
      DO ijk = ijkstart3, ijkend3
!          IF(.NOT.IS_ON_myPE_OWNS(I_OF(IJK), J_OF(IJK), K_OF(IJK))) CYCLE
          ep_g(ijk)   = 2.*ep_g(ijk) - ep_go(ijk)
!AE TIME Pressure is not postprocessed/calculated in the current implementation
!          P_G(ijk)    = 2.*P_G(ijk)  - P_GO(ijk)
!          P_STAR(ijk) = 2.*P_STAR(ijk) - P_STARO(ijk)
          ro_g(ijk)   = 2.*ro_g(ijk) - ro_go(ijk)
          rop_g(ijk)  = 2.*rop_g(ijk)- rop_go(ijk)
          u_g(ijk) = 2.*u_g(ijk) - u_go(ijk)
          v_g(ijk) = 2.*v_g(ijk) - v_go(ijk)
          w_g(ijk) = 2.*w_g(ijk) - w_go(ijk)
          IF (energy_eq) t_g(ijk) = 2.*t_g(ijk) - t_go(ijk)

!AE TIME Update P_g with state equation based on extrapolated ro_g, T_g
!          EOSG = UNSCALE(PG)*MW/(GAS_CONST*TG)
!          IF (.NOT.WALL_AT(IJK)) THEN
!             P_G(ijk) = ((RO_G(ijk)*(GAS_CONST*T_G(ijk))/MW_MIX_G(IJK))- P_ref)/P_scale
!             P_G(ijk) = ((RO_G(ijk)*(GAS_CONST*T_G(ijk))/MW_MIX_G(IJK)))
!         ENDIF

          IF (species_eq(0)) THEN
            IF (nmax(0) > 0) THEN
              x_g(ijk,:nmax(0)) = 2.*x_g(ijk,:nmax(0)) - x_go(ijk,:nmax(0))
            ENDIF
          ENDIF

          IF (nscalar > 0) THEN
            scalar(ijk,:nscalar) = 2.*scalar(ijk,:nscalar) - scalaro(ijk,:nscalar)
          ENDIF

          DO m = 1, mmax
            rop_s(ijk,m) = 2.*rop_s(ijk,m) - rop_so(ijk,m)
            IF (energy_eq) t_s(ijk,m) = 2.*t_s(ijk,m) - t_so(ijk,m)
            IF (granular_energy) THEN
              theta_m(ijk,m) = 2.*theta_m(ijk,m) - theta_mo(ijk,m)
              trd_s_c(ijk,m) = 2.*trd_s_c(ijk,m) - trd_s_co(ijk,m)
            ENDIF
            u_s(ijk,m) = 2.*u_s(ijk,m) - u_so(ijk,m)
            v_s(ijk,m) = 2.*v_s(ijk,m) - v_so(ijk,m)
            w_s(ijk,m) = 2.*w_s(ijk,m) - w_so(ijk,m)
            IF (species_eq(m)) THEN
              IF (nmax(m) > 0) THEN
                x_s(ijk,m,:nmax(m)) = 2.*x_s(ijk,m,:nmax(m)) - x_so(ijk,m,:nmax(m))
              ENDIF
            ENDIF
          END DO


      END DO


      RETURN
      END SUBROUTINE cn_extrapol

!// Comments on the modifications for DMP version implementation
!// 120 Replaced the index for initialization: (:IJKMAX2) to just (:)