check_solids_model_prereqs.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  SUBROUTINE: CHECK_SOLIDS_MODEL_PREREQS                              !
!  Purpose: Check the distributed parallel namelist variables.         !
!                                                                      !
!  Author: P. Nicoletti                               Date: 14-DEC-99  !
!  Reviewer: J.Musser                                 Date: 16-Jan-14  !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_solids_model_prereqs

! Modules
!---------------------------------------------------------------------//
! Flag: Use DES E-L model
      use discretelement, only: discrete_element
! Flag: Use TFM and DEM solids models.
      use discretelement, only: des_continuum_hybrid
! Flag: gas/solids E-L simulation, otherwise granular flow.
      use discretelement, only: des_continuum_coupled
! Flag: Fluid affects particles, but particles do not impact fluid.
      use discretelement, only: des_oneway_coupled
! Number of discrete solids phases.
      use discretelement, only: des_mmax
! Print E-L data.
      use discretelement, only: print_des_data

      use error_manager

! Maximum number of solids phases.
      use param, only: dim_m

! Number of phases specified by the user.
      use physprop, only: mmax, smax
! User specified constant gas density
      use physprop, only: ro_g0

! Flag: Use MPPIC E-L model
      use mfix_pic, only: mppic
! Flag: Method of manufactured solutions (MMS)
      use mms, only: use_mms

      use run, only: solids_model
! Flag: Use DES E-E solids model
      use run, only: tfm_solids, tfm_count
      use run, only: dem_solids, dem_count
      use run, only: pic_solids, pic_count
! Flag: Solve species eq.
      USE run, only: species_eq, any_species_eq
! Kinetic theory model for TFM solids.
      use run, only: kt_type

! Number of scalar equations to solve
      USE scalars, only: nscalar, phase4scalar
! Phase associated with scalar transport.
      USE scalars, only: phase4scalar
      implicit none

! Local Variables
!---------------------------------------------------------------------//
! Loop counter
      INTEGER :: M ! Phase index
! Error indicator for mmax
      LOGICAL :: ERR_MMAX
! Dummy integer
      INTEGER :: N
!......................................................................!


! Initialize the error manager.
      CALL init_err_msg("CHECK_SOLIDS_MODEL_PREREQS")

! Moved this here but will need to discuss if this is best route
! going forward
      err_mmax = .false.
      IF (mmax < 0) err_mmax = .true.
      IF(trim(kt_type) == 'GHD') THEN
         IF (mmax+1 > dim_m) err_mmax = .true.
      ELSE
         IF (mmax > dim_m) err_mmax = .true.
      ENDIF
      IF((use_mms).AND.(mmax > 1)) err_mmax = .true.

! Check MMAX
      IF (err_mmax) THEN
         WRITE(err_msg, 1000) ival(dim_m)
         CALL flush_err_msg(abort=.true.)
      ENDIF
 1000 FORMAT('Error 1000: MMAX out of range. Min: 0, Max: ',a)

! Loop over the phases to see what was specified.
      DO m=1, mmax
         solids_model(m) = trim(adjustl(solids_model(m)))
         SELECT CASE(solids_model(m))
         CASE ('TFM'); tfm_count = tfm_count + 1
         CASE ('DEM'); dem_count = dem_count + 1
         CASE ('PIC'); pic_count = pic_count + 1

         CASE DEFAULT
            WRITE(err_msg,1001) ivar('SOLIDS_MODEL',m), solids_model(m)
            CALL flush_err_msg(abort=.true.)

 1001 FORMAT('Error 1001: Unknown solids model: ',a,' = ',a)

         END SELECT
      ENDDO

! Set the number of discrete phases.
      des_mmax = dem_count + pic_count

! Set the number of TFM phases.  (should be equivalent to tfm_count)
      mmax = mmax - des_mmax
      smax = mmax   ! USE smax in the TFM code for the number of TFM phases
! For GHD theory increase MMAX by one to serve as 'mixture' phase
      IF(trim(kt_type) == 'GHD') THEN
         mmax = mmax + 1
         tfm_count = tfm_count + 1
         solids_model(mmax) = 'TFM'
      ENDIF


! Clear out the unused phases.
      solids_model((mmax+des_mmax)+1:dim_m) = '---'

! Set the runtime flags:
      tfm_solids = (tfm_count > 0)
      dem_solids = (dem_count > 0)
      pic_solids = (pic_count > 0)

! MPPIC and continuum solids don't mix.
      IF(pic_solids .AND. tfm_solids)THEN
         WRITE(err_msg, 1002)
         CALL flush_err_msg(abort=.true.)
      ENDIF
 1002 FORMAT('Error 1002: MPPIC solids and continuum solids cannot ',&
         'be combined.',/'Please correct the mfix.dat file.')


! MPPIC and DEM solids don't mix.
      IF(pic_solids .AND. dem_solids)THEN
         WRITE(err_msg, 1003)
         CALL flush_err_msg(abort=.true.)
      ENDIF
 1003 FORMAT('Error 1003: MPPIC solids and DES solids cannot be ',     &
         'combined.',/'Please correct the mfix.dat file.')

! temporary move for now since these rely on definition of mmax/smax
! Set variable ANY_SPECIES_EQ
      m = max(smax, des_mmax)
      any_species_eq = any(species_eq(:m))

! Check phase specification for scalars
      DO n = 1, nscalar
         IF(phase4scalar(n) < 0 .OR. phase4scalar(n) > mmax) THEN
            WRITE(err_msg,1004) ivar('Phase4Scalar',n), &
               ival(phase4scalar(n))
            CALL flush_err_msg(abort=.true.)
         ENDIF
      ENDDO
 1004 FORMAT('Error 1004: Illegal or unknown input: ',a,' = ',a,/  &
         'Please correct the mfix.dat file.')

! Set the DEM runtime flag.
      discrete_element = dem_solids .OR. pic_solids
! Set the MMPIC runtime flag.
      mppic = pic_solids
! Set the Hybird flag.
      des_continuum_hybrid = (dem_solids .AND. tfm_solids)
! Set flag for coupled simulations
      des_continuum_coupled = .NOT.(ro_g0 == 0.0d0)

      IF(des_continuum_hybrid) CALL hybrid_hack

! Overwrite user settings if no Lagrangian solids
      IF(.NOT.discrete_element) THEN
         des_continuum_coupled = .false.   ! This keyword might get removed.
         print_des_data = .false.
         des_oneway_coupled = .false.
      ENDIF

      CALL finl_err_msg

      RETURN

      END SUBROUTINE check_solids_model_prereqs


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  SUBROUTINE: Hybrid_HACK                                             !
!  Purpose: Check the distributed parallel namelist variables.         !
!                                                                      !
!  Author: P. Nicoletti                               Date: 14-DEC-99  !
!  Reviewer: J.Musser                                 Date: 16-Jan-14  !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE hybrid_hack

! Modules
!---------------------------------------------------------------------//
! Maximum number of solids phases.
      use param, only: dim_m
      use error_manager
      use run, only: solids_model

! Local variables
!---------------------------------------------------------------------//
      integer :: TFM_MAX
      integer :: DEM_MIN
      integer :: M
!......................................................................!

! Initialize the error manager.
      CALL init_err_msg("HYBRID_HACK")

! Initialize the loop variables.
      tfm_max = -dim_m
      dem_min =  dim_m

! Loop over the phases to see what was specified.
      DO m=1, dim_m
         SELECT CASE(solids_model(m))
         CASE ('TFM'); tfm_max = max(m, tfm_max)
         CASE ('DEM'); dem_min = min(m, dem_min)
         END SELECT
      ENDDO

      write(*,*)'  MAX TFM index: ', tfm_max
      write(*,*)'  MIN DEM index: ', dem_min

      IF(dem_min < tfm_max) THEN
         WRITE(err_msg, 2000)
         CALL flush_err_msg(abort=.true.)
      ENDIF

 2000 FORMAT('Error 2000: Illegal phase specification for hybrid ',    &
         'model. All TFM',/'solids must be defined before DEM solids.',&
         /'Please correct the mfix.dat file.')

      CALL finl_err_msg

      RETURN
      END SUBROUTINE hybrid_hack