check_gas_phase.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Module name: CHECK_GAS_PHASE                                        !
!  Purpose: Check the gas phase input section                          !
!                                                                      !
!  Author: P.Nicoletti                                Date: 02-DEC-91  !
!          J.Musser                                   Date: 01-FEB-14  !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_gas_phase


! Global Variables:
!---------------------------------------------------------------------//
! Flag: Solve species equations.
      use run, only: species_eq, energy_eq
! Flag: Use legacy reaction rates implementation
      use rxns, only: use_rrates
! User specified: Constant gas viscosity
      use physprop, only: mu_g0
! User specified: Constant gas thermal conductivity
      use physprop, only: k_g0
! User specified: Constant gas mixture diffusion coefficient
      use physprop, only: dif_g0
! User specified: Constant gas specific heat
      use physprop, only: c_pg0
! User specified: Constant gas density
      use physprop, only: ro_g0
! User specified: Constant gas mixture molecular weight
      use physprop, only: mw_avg

      use mms, only: use_mms
! Global Parameters:
!---------------------------------------------------------------------//
! Parameter constants
      use param1, only: undefined, zero

! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager


      IMPLICIT NONE


! Local Variables:
!---------------------------------------------------------------------//
! NONE

!......................................................................!


! Initialize the error manager.
      CALL init_err_msg("CHECK_GAS_PHASE")


! CHECK MU_g0
      IF (mu_g0 <= zero) THEN
         WRITE(err_msg,1001) 'MU_G0', ival(mu_g0)
         CALL flush_err_msg(abort=.true.)
      ENDIF

! CHECK K_g0
      IF (k_g0 < zero) THEN
         WRITE(err_msg,1001) 'K_G0', ival(k_g0)
         CALL flush_err_msg(abort=.true.)
      ENDIF

! CHECK C_pg0
      IF (c_pg0 < zero) THEN
         WRITE(err_msg,1001) 'C_PG0', ival(c_pg0)
         CALL flush_err_msg(abort=.true.)
      ENDIF

! CHECK DIF_g0
      IF (dif_g0 < zero) THEN
         WRITE(err_msg,1001) 'DIF_g0', ival(dif_g0)
         CALL flush_err_msg(abort=.true.)
      ENDIF

! Check the input specifications for gas species.
      IF(use_rrates)THEN
         CALL check_gas_species_legacy
      ELSE
         CALL check_gas_species
      ENDIF

! Currently MMS uses constant properties. These are in place simply
! to give the developer a heads-up that the code/setup may not fully
! encompass the use of non-constant properties
      IF (use_mms) THEN
         IF (mu_g0 == undefined) THEN
            WRITE(err_msg, 1200) 'MU_G0'
            CALL flush_err_msg(abort=.true.)
         ENDIF
         IF (k_g0 == undefined .AND. energy_eq) THEN
            WRITE(err_msg, 1200) 'K_G0'
            CALL flush_err_msg(abort=.true.)
         ENDIF
         IF (dif_g0 == undefined .AND. species_eq(0)) THEN
            WRITE(err_msg, 1200) 'DIF_G0'
            CALL flush_err_msg(abort=.true.)
         ENDIF

 1200 FORMAT('Error 1200: ',a,' must be defined when USE_MMS is T.',/,&
         'Please correct the mfix.dat file.')
      ENDIF

! CHECK MW_AVG
      IF (species_eq(0)) THEN
! MW_AVG is defined and the gas phase species equations are solved, then
! the user specified average molecular weight is ignored. The gas phase
! mixture molecular weight (MW_MIX_g) is used instead.
         IF (mw_avg /= undefined) THEN
            WRITE (err_msg, 1100) 'solving species equations'
            CALL flush_err_msg
            mw_avg = undefined
         ENDIF
      ELSE
! When the species equations are not solved and the gas phase is
! compressible, verify that the user provided average molecular weight
! has a physical value. (This does not include the case where MW_AVG
! is UNDEFINED.)
         IF (ro_g0 == undefined) THEN
            IF (mw_avg <= zero) THEN
               WRITE(err_msg, 1001) 'MW_AVG', ival(mw_avg)
               CALL flush_err_msg(abort=.true.)
            ENDIF
         ELSE
! Gas density for incompressible flows must be positive.
            IF (ro_g0 < zero) THEN
               WRITE(err_msg, 1001) 'RO_G0', ival(ro_g0)
               CALL flush_err_msg(abort=.true.)
            ENDIF
! Incompressible simulations do not need MW_AVG. Notify the user that
! the provided data is ignored.
            IF (mw_avg /= undefined)THEN
               WRITE(err_msg, 1100) 'RO_g0 is specified'
               CALL flush_err_msg
            ENDIF

         ENDIF
      ENDIF


! Finalize the error manager
      CALL finl_err_msg


      RETURN

 1000 FORMAT('Error 1000: Required input not specified: ',a,/'Please ',&
            'correct the mfix.dat file.')

 1001 FORMAT('Error 1001: Illegal or unknown input: ',a,' = ',a,/      &
         'Please correct the mfix.dat file.')


 1100 FORMAT('Message 2000: MW_AVG is not needed when ',a,'.')

      END SUBROUTINE check_gas_phase



!----------------------------------------------------------------------!
! Subroutine: CHECK_GAS_SPECIES                                        !
! Purpose: Gas phase species checks.                                   !
!                                                                      !
! Author: J. Musser                                  Date: 07-FEB-14   !
!----------------------------------------------------------------------!
      SUBROUTINE check_gas_species


! Global Variables:
!---------------------------------------------------------------------//
! Flag: Solve energy equations
      use run, only: energy_eq
! Flag: Solve species equations
      use run, only: species_eq
! Flag: Database for phase X was read for species Y
      use rxns, only: rdatabase
! Flag: Code is reinitializing
      use run, only: reinitializing
! Gas phase species database names.
      use rxns, only: species_g
! Gas phase molecular weights.
      use physprop, only: mw_g
! Number of gas phase species.
      use physprop, only: nmax, nmax_g
! User specified: Constant gas phase specific heat
      use physprop, only: c_pg0
! User specified: Constant gas density
      use physprop, only: ro_g0
! User specified: Constant gas phase mixture molecular weight
      use physprop, only: mw_avg


! Global Parameters:
!---------------------------------------------------------------------//
! Maximum number of gas phase species.
      USE param, only: dim_n_g
! Constants.
      USE param1, only: undefined, undefined_i, undefined_c
      USE param1, only: zero


! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager


      implicit none


! Local Variables:
!---------------------------------------------------------------------//
! Loop counter.
      INTEGER :: N

! Flag that the energy equations are solved and constant gas phase
! specific heat is undefined.
! If true, a call to the thermochemical database is made.
      LOGICAL EEQ_CPG

! Flag that the average molecular weight (MW_AVG) and constant gas
! phase density are undefined.
! If true, a call to the thermochemical database is made.
      LOGICAL MWg_ROg

! Flag that the gas phase species equations are solved and the
! molecular weight for a species is not given in the data file.
! If true, a call to the thermochemical database is made.
      LOGICAL SEQ_MWg


!......................................................................!


! Initialize the error manager.
      CALL init_err_msg("CHECK_GAS_SPECIES")


! Reconcile the new species input method with the legacy input method.
      IF(species_eq(0)) THEN

         IF(nmax_g == undefined_i) THEN
            WRITE(err_msg,1000) 'NMAX_g'
            CALL flush_err_msg(abort=.true.)
         ELSEIF(nmax_g > dim_n_g) THEN
            WRITE(err_msg,1001) 'NMAX_g', ival(nmax_g)
            CALL flush_err_msg(abort=.true.)
         ELSE
            nmax(0) = nmax_g
         ENDIF
! Set the number of species to one if the species equations are not solved and
! the number of species is not specified.
      ELSE
         nmax(0) = merge(1, nmax_g, nmax_g == undefined_i)
      ENDIF

! Flag that the energy equations are solved and specified solids phase
! specific heat is undefined.
      eeq_cpg = (energy_eq .AND. c_pg0 == undefined)
      IF(eeq_cpg .AND. .NOT.reinitializing) THEN
         WRITE(err_msg,2000)
         CALL flush_err_msg
      ENDIF

 2000 FORMAT('Message: 2000 The energy equations are being solved ',   &
         '(ENERGY_EQ) and',/'the constant gas specific heat is ',      &
         'undefined (C_PG0). Thus, the thermo-',/'chemical database ', &
         'will be used to gather specific heat data on the',/          &
         'individual gas phase species.')

      mwg_rog = .false.
      seq_mwg = .false.
      IF(mw_avg == undefined) THEN
         DO n=1,nmax(0)
            IF(mw_g(n) == undefined) THEN
               IF(ro_g0 == undefined) mwg_rog = .true.
               IF(species_eq(0)) seq_mwg = .true.
            ENDIF
         ENDDO
      ENDIF

      IF(mwg_rog .AND. reinitializing) THEN
         WRITE(err_msg, 2001)
         CALL flush_err_msg
      ENDIF

 2001 FORMAT('Message 2001: MW_AVG and RO_G0 are undefined and one or',&
         ' more species',/'molecular weights are undefined. The therm',&
         'ochemical database will be',/'used in an attempt to gather ',&
         'missing molecular weight data.')

      IF(seq_mwg .AND. reinitializing) THEN
         WRITE(err_msg, 2002)
         CALL flush_err_msg
      ENDIF

 2002 FORMAT('Message 2002: One or more species molecular weights are',&
         ' undefined and',/'the gas phase species equations are being',&
         ' solved (SOLVE_EQ(0)). The',/'thermochemical database will ',&
         'be used in an attempt to gather missing',/'molecular weight',&
         ' data.')

! Initialize flag indicating the database was read for a species.
      rdatabase(0,:) = .false.

      IF(eeq_cpg .OR. seq_mwg .OR. mwg_rog) THEN

         IF(.NOT.reinitializing) THEN
            WRITE(err_msg, 3000)
            CALL flush_err_msg(footer=.false.)
         ENDIF

 3000 FORMAT('Message 3000: Searching thermochemical databases for ',  &
         'gas phase',/'species data.',/'  ')

         DO n = 1, nmax(0)
            IF(eeq_cpg .OR. mw_g(n) == undefined) THEN
! Notify the user of the reason the thermochemical database is used.
! Flag that the species name is not provided.
               IF(species_g(n) == undefined_c) THEN
                  WRITE(err_msg,1000) trim(ivar('SPECIES_g',n))
                  CALL flush_err_msg(abort=.true.)
               ENDIF
! Update the log files.
               IF(.NOT.reinitializing) THEN
                  WRITE(err_msg, 3001) n, trim(species_g(n))
                  CALL flush_err_msg(header=.false., footer=.false.)
               ENDIF
               3001 FORMAT(/2x,'>',i3,': Species: ',a)
! Read the database.
               CALL read_database(0, n, species_g(n), mw_g(n))
! Flag variable to stating that the database was read.
               rdatabase(0,n) = .true.
            ENDIF

         ENDDO ! Loop over species
         IF(.NOT.reinitializing) CALL flush_err_msg(header=.false.)
      ENDIF

! Verify that no additional species information was given.
      DO n = nmax(0) + 1, dim_n_g
         IF(mw_g(n) /= undefined) THEN
            WRITE(err_msg, 1002) trim(ivar('MW_g',n))
            CALL flush_err_msg(abort=.true.)
         ENDIF
      ENDDO

      CALL finl_err_msg

      RETURN

 1000 FORMAT('Error 1000: Required input not specified: ',a,/'Please ',&
         'correct the mfix.dat file.')

 1001 FORMAT('Error 1001: Illegal or unphysical input: ',a,' = ',a,/   &
         'Please correct the mfix.dat file.')

 1002 FORMAT('Error 1002: Illegal input: ',a,' specified out of range.',&
         'Please correct the mfix.dat file.')

      END SUBROUTINE check_gas_species


!----------------------------------------------------------------------!
! Subroutine: CHECK_GAS_SPECIES_LEGACY                                 !
! Purpose: These are legacy checks for using rrates.f to specify       !
! chemical reactions.                                                  !
!                                                                      !
! Author: J. Musser                                  Date: 03-FEB-14   !
!----------------------------------------------------------------------!
      SUBROUTINE check_gas_species_legacy


! Global Variables:
!---------------------------------------------------------------------//
! Flag: Solve species equations
      use run, only: species_eq
! Gas phase molecular weights.
      use physprop, only: mw_g
! Number of gas phase species.
      use physprop, only: nmax, nmax_g
! Flag: Database was read. (legacy)
      use physprop, only: database_read


! Global Parameters:
!---------------------------------------------------------------------//
! Maximum number of gas phase species.
      USE param, only: dim_n_g
! Constants.
      USE param1, only: undefined_i, undefined, zero


! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager


      implicit none


! Local Variables:
!---------------------------------------------------------------------//
! Loop counter.
      INTEGER :: N


!......................................................................!


! Initialize the error manager.
      CALL init_err_msg("CHECK_GAS_SPECIES_LEGACY")


! Reconcile the new species input method with the legacy input method.
      IF(species_eq(0)) THEN
! Legacy checks for species equations.
         IF(nmax_g /= undefined_i) THEN
            WRITE(err_msg,2000) 'NMAX_g', 'undefined'
            CALL flush_err_msg(abort=.true.)
         ELSEIF(nmax(0) == undefined_i) THEN
            WRITE(err_msg,2000) trim(ivar('NMAX',0)), 'specified'
            CALL flush_err_msg(abort=.true.)
         ELSEIF(nmax(0) > dim_n_g) THEN
            WRITE(err_msg,1001) trim(ivar('NMAX',0)), ival(nmax(0))
            CALL flush_err_msg(abort=.true.)
         ENDIF
! Set the number of species to one if the species equations are not
! solved and the number of species is not specified.
      ELSE
         IF(nmax(0) == undefined_i) nmax(0) = 1
      ENDIF

! Check MW_g if solids species are present
      DO n = 1, nmax(0)
         IF(mw_g(n) == undefined) THEN
            WRITE(err_msg,2000)trim(ivar('MW_g',n)), 'specified'
            CALL flush_err_msg(abort=.true.)
         ELSEIF(mw_g(n) <= zero) THEN
            WRITE(err_msg,1001)trim(ivar('MW_g',n)), ival(mw_g(n))
            CALL flush_err_msg(abort=.true.)
         ENDIF
      ENDDO ! Loop over species
      DO n = nmax(0) + 1, dim_n_g
         IF(mw_g(n) /= undefined) THEN
            WRITE(err_msg,1001)trim(ivar('MW_g',n)), ival(mw_g(n))
            CALL flush_err_msg(abort=.true.)
         ENDIF
      ENDDO

      CALL finl_err_msg

! Set the legacy database flag. (Also in check_solids_common_all)
      database_read = .false.

      RETURN

 1001 FORMAT('Error 1001: Illegal or unphysical input: ',a,' = ',a,/   &
         'Please correct the mfix.dat file.')

 2000 FORMAT('Error 2000: Invalid input. ',a,' must be ',a,/'when ',    &
         'USE_RRATES is .TRUE.'/,'Please correct the mfix.dat file')

      END SUBROUTINE check_gas_species_legacy