calc_gama.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Subroutine: CALC_GAMA                                               C
!                                                                      C
!  Purpose: Calculate gas-solids heat transfer coefficients            C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
      SUBROUTINE calc_gama(M)

! Modules
!---------------------------------------------------------------------//
      USE sendrecv, only: send_recv
      USE energy, only: gama_gs
      USE usr_prop, only: usr_gama, calc_usr_prop
      USE usr_prop, only: gassolids_heattransfer
      IMPLICIT NONE

! Dummy arguments
!---------------------------------------------------------------------//
! solids phase index
      INTEGER, INTENT(IN) :: M
!---------------------------------------------------------------------//

      IF (usr_gama(m)) THEN
         CALL calc_usr_prop(gassolids_heattransfer,lm=m)
      ELSE
         CALL calc_default_gama_gs(m)
      ENDIF
      call send_recv(gama_gs,2)

      RETURN
      END SUBROUTINE calc_gama


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Subroutine: CALC_DEFAULT_GAMA_GS                                    C
!  Purpose: Compute the default value for the gas-solids heat transfer C
!  coefficients.                                                       C
!                                                                      C
!  Author: M. Syamlal                                 Date: 15-JUL-92  C
!                                                                      C
!  Literature/Document References:                                     C
!  Gunn, D. J., (1978), International Journal of Heat and Mass         C
!    Transfer, Vol. 21, p 467-476.                                     C
!  Bird, Stewart, and Lightfoot (1960, p.663)                          C
!                                                                      C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
      SUBROUTINE calc_default_gama_gs(M)

! Modules
!---------------------------------------------------------------------//
      USE compar, only: ijkstart3, ijkend3
      USE energy, only: gama_gs
      USE fldvar, only: u_g, v_g, w_g, u_s, v_s, w_s
      USE fldvar, only: ep_g, ro_g, d_p, ep_s
      Use fun_avg, only: avg_x_e, avg_y_n, avg_z_t
      USE functions, only: fluidorp_flow_at
      use functions, only: im_of, jm_of, km_of
      use indices, only: i_of
      USE param1, only: zero, half, one, small_number, large_number
      USE physprop, only: mu_g, k_g, c_pg
      USE rxns, only: r_phase
      IMPLICIT NONE

! Dummy Arguments
!---------------------------------------------------------------------//
! solids phase index
      INTEGER, INTENT(IN) :: M

! Local Variables
!---------------------------------------------------------------------//
! Indices
      INTEGER :: I, IJK, IMJK, IJMK, IJKM
! Cell center value of U_g, Vg, and Wg 
      DOUBLE PRECISION :: UGC, VGC, WGC
! Cell center value of U_sm, V_sm, W_sm
      DOUBLE PRECISION :: USCM, VSCM, WSCM
! Gas-solids relative velocity
      DOUBLE PRECISION :: VREL
! function of Prandtl number, Pr^(1/3)
      DOUBLE PRECISION :: Pr1o3
! Reynolds number, Re
      DOUBLE PRECISION :: Re
! EP_g^2
      DOUBLE PRECISION :: EP_g2
! a factor
      DOUBLE PRECISION :: FAC
! index for storing interphase mass transfer coefficients in the upper
! triangle of the matrix. 
      INTEGER :: LM
!---------------------------------------------------------------------//

      DO ijk = ijkstart3, ijkend3
         IF (fluidorp_flow_at(ijk)) THEN
            i = i_of(ijk)
            imjk = im_of(ijk)
            ijmk = jm_of(ijk)
            ijkm = km_of(ijk)
            ep_g2 = ep_g(ijk)*ep_g(ijk)

! Calculate Prandtl number to the 1/3 power
            if(k_g(ijk) > zero) then
              pr1o3 = (c_pg(ijk)*mu_g(ijk)/k_g(ijk))**(1.d0/3.d0)
            else
              pr1o3 = large_number
            endif

! Calculate velocity components at i, j, k
            ugc = avg_x_e(u_g(imjk),u_g(ijk),i)
            vgc = avg_y_n(v_g(ijmk),v_g(ijk))
            wgc = avg_z_t(w_g(ijkm),w_g(ijk))

            uscm = avg_x_e(u_s(imjk,m),u_s(ijk,m),i)
            vscm = avg_y_n(v_s(ijmk,m),v_s(ijk,m))
            wscm = avg_z_t(w_s(ijkm,m),w_s(ijk,m))

! Calculate the magnitude of gas-solids relative velocity
            vrel=sqrt((ugc-uscm)**2+(vgc-vscm)**2+(wgc-wscm)**2)

            if(mu_g(ijk) > zero)then
               re = ep_g(ijk)*d_p(ijk,m)*vrel*ro_g(ijk)/mu_g(ijk)
            else
               re = large_number
            endif

! Calculate gas-solids heat transfer coefficient (Gunn 1978)
            gama_gs(ijk,m) = ((7.d0 - 10.d0*ep_g(ijk)+5.d0*ep_g2)*&
                              (one+0.7d0*re**0.2d0*pr1o3)+&
                              (1.33d0 - 2.4d0*ep_g(ijk)+1.2d0*ep_g2)*&
                              re**0.7d0*pr1o3)*(k_g(ijk)/d_p(ijk,m))*&
                              (6.d0*ep_s(ijk,m)/d_p(ijk,m))

! Correct the heat transfer coefficient for transpiration
! Bird, Stewart, and Lightfoot (1960, p.663)
            IF (gama_gs(ijk,m) > small_number) THEN
! Only the effect of gas-solids heat transfer is accounted for so find
! corresponding lm index for gas-solids mass transfer
               lm = 1+ (m-1)*m/2
               fac = r_phase(ijk,lm)*c_pg(ijk)/gama_gs(ijk,m)
               IF (abs(fac) < 0.1d0) THEN
                  gama_gs(ijk,m) = gama_gs(ijk,m)/&
                                   (one+fac/2.d0+fac*fac/6.d0)
               ELSE
                  IF (r_phase(ijk,lm) > zero) THEN
                     gama_gs(ijk,m) = r_phase(ijk,lm)*c_pg(ijk)*&
                                      exp((-fac))/(one - exp((-fac)))
                  ELSE
                     gama_gs(ijk,m) = r_phase(ijk,lm)*c_pg(ijk)/&
                                      (exp(fac) - one)
                  ENDIF
               ENDIF
            ENDIF   ! end if gama_gs(ijk,M) > 0

         ENDIF   ! end if (fluidorp_flow_at(ijk)
      ENDDO    ! end do loop (ijk=ijkstart3,ijkend3)


      RETURN
      END SUBROUTINE calc_default_gama_gs