calc_dif_s.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Subroutine: CALC_DIF_S                                              C
!  Purpose: Calculate the effective diffusivity of solids phases       C
!                                                                      C
!                                                                      C
!  Comments:                                                           C
!  This routine will not be called if dif_s0(M) is defined             C
!                                                                      C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
      SUBROUTINE calc_dif_s(M)

! Modules
!---------------------------------------------------------------------//
      USE param1, only: undefined
      USE physprop, only: dif_s0, dif_s
      USE sendrecv, only: send_recv
! invoke user defined quantity
      USE usr_prop, only: usr_difs, calc_usr_prop
      USE usr_prop, only: solids_diffusivity
      IMPLICIT NONE

! Dummy arguments
!---------------------------------------------------------------------//
! Solids phase index
      INTEGER, INTENT(IN) :: M

!---------------------------------------------------------------------//

      IF (usr_difs(m)) THEN
         CALL calc_usr_prop(solids_diffusivity,lm=m)
      ELSEIF (dif_s0(m) == undefined) THEN
         CALL calc_default_dif_solids(m)
      ENDIF

      CALL send_recv(dif_s, 2)

      RETURN
      END SUBROUTINE calc_dif_s


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Subroutine: CALC_DEFAULT_DIF_SOLIDS                                 C
!  Purpose: Compute the default value of each solids phases effective  C
!  diffusivity. Because species are not considered to diffuse in a     C
!  solids the default diffusivsity is zero.                            C
!                                                                      C
!  Author:M. Syamlal                                  Date: 13-EFB-98  C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
      SUBROUTINE calc_default_dif_solids(M)

! Modules
!---------------------------------------------------------------------//
      USE compar, only: ijkstart3, ijkend3
      USE functions, only: fluid_at
      USE fldvar, only: rop_s
      USE param1, only: zero
      USE physprop, only: nmax, dif_s
      USE run, only: units
      IMPLICIT NONE

! Dummy arguments
!---------------------------------------------------------------------//
! Solids phase index
      INTEGER, INTENT(IN) :: M

! Local variables
!---------------------------------------------------------------------//
! Indices
      INTEGER :: IJK
      INTEGER :: N
! binary diffusivity coefficient
      DOUBLE PRECISION :: Dab
!---------------------------------------------------------------------//

      dab = zero       !cm^2/s
      IF(units == 'SI') dab = dab*0.0001d0   !m^2/s

!!$omp  parallel do private(n,ijk) &
!!$omp& schedule(dynamic,chunk_size)
      DO n = 1, nmax(m)
         DO ijk = ijkstart3, ijkend3
            IF (fluid_at(ijk)) THEN
               dif_s(ijk,m,n) = rop_s(ijk,m)*dab
            ELSE
               dif_s(ijk,m,n) = zero
            ENDIF
         ENDDO
      ENDDO

      RETURN
      END SUBROUTINE calc_default_dif_solids