eos_mod.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Module name: EOS                                                    C
!  Purpose: Equation of state for gas and initial solids density       C
!                                                                      C
!  Author: M. Syamlal                                 Date: 29-JAN-92  C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C

      MODULE eos

      CONTAINS


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Function: EOSG                                                      C
!  Purpose: Equation of state for gas                                  C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
      DOUBLE PRECISION FUNCTION eosg (MW, PG, TG)

! Global Variables:
!---------------------------------------------------------------------//
      USE constant, only: gas_const
      USE scales, only: unscale_pressure
      IMPLICIT NONE

! Dummy arguments
!---------------------------------------------------------------------//
      DOUBLE PRECISION, INTENT(IN) :: MW, PG, TG

      eosg = unscale_pressure(pg)*mw/(gas_const*tg)
      RETURN
      END FUNCTION eosg


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Function: dROodP_g                                                  C
!  Purpose: derivative of gas density w.r.t pressure                   C
!                                                                      C
!  Author: M. Syamlal                                 Date: 14-AUG-96  C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
      DOUBLE PRECISION FUNCTION droodp_g (ROG, PG)

! Global Variables:
!---------------------------------------------------------------------//
      USE scales, only: p_ref
      IMPLICIT NONE

! Dummy arguments
!---------------------------------------------------------------------//
! gas density and pressure
      DOUBLE PRECISION, INTENT(IN) :: ROG, PG

      droodp_g = rog/(pg + p_ref)
      RETURN
      END FUNCTION droodp_g


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Function: EOSS0                                                     !
!  Author: J.Musser                                   Date: 02-Dec-13  !
!                                                                      !
!  Purpose: Calculate the initial solids density. This calculation is  !
!  only valid at time zero. Thus, this routine should only be invoked  !
!  by the initialization routines.                                     !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      DOUBLE PRECISION FUNCTION eoss0(M)

! Global Variables:
!---------------------------------------------------------------------//
! Baseline/initial solids density
      use physprop, only: ro_xs0
! Baseline/initial solids mass fractions.
      use physprop, only: x_s0
! Number of species comprising each phase.
      use physprop, only: nmax
! Process Rank
      use compar, only: mype
! Unit number for RUN_NAME.LOG file
      use funits, only: unit_log
! Logical for who writes error messages
      use funits, only: dmp_log

! Global parameters
!---------------------------------------------------------------------/
      use param1, only: one
      use param1, only: zero
      use param1, only: small_number
      use exit, only: mfix_exit

      implicit none

! Passed Arguments:
!---------------------------------------------------------------------/
! Solids phase index.
      INTEGER, intent(in) :: M

! Local Variables:
!---------------------------------------------------------------------/
! Alias for inert species index.
      DOUBLE PRECISION :: OoRO_s0
! Character string for error messages
      CHARACTER(len=64) :: MSG

! Evaluate the first part of the calculation.
      ooro_s0 = sum(x_s0(m,:nmax(m))/ro_xs0(m,:nmax(m)))
! If the value is physical (positive) finish the calculation and return.
      IF(ooro_s0 > zero) THEN
         eoss0 = one/ooro_s0
         return
      ENDIF

! This is an extra sanity check that should be caught be one ore more
! of the data checks.
      msg=''
      IF(abs(ooro_s0) <= small_number) THEN
         WRITE(msg,"('Infinity')")
      ELSE
         WRITE(msg,*) one/ooro_s0
      ENDIF

      IF(dmp_log) THEN
         WRITE(*,1000) m, trim(msg)
         WRITE(unit_log,1000) m, trim(msg)
      ENDIF

      CALL mfix_exit(mype)

 1000 FORMAT(//1x,70('*')/' From: EOSS',/,' Error 1300:',               &
         ' Unphysical baseline density calculated:',/' RO_s(',i2,') = ' &
         ,a,/' Please refer to the Readme file on the required input',  &
         ' and make',/' the necessary corrections to the data file.',   &
         /1x,70('*')//)

      END FUNCTION eoss0



!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Function: EOSS                                                      !
!  Author: J.Musser                                   Date: 09-Oct-13  !
!                                                                      !
!  Purpose: Calculate solid density - runtime.                         !
!                                                                      !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      DOUBLE PRECISION FUNCTION eoss(pBase, Xs0_INERT, Xs_INERT)

      implicit none

! Passed Arguments:
!---------------------------------------------------------------------/
! Baseline phase density (unreacted)
      DOUBLE PRECISION, intent(in) :: pBase
! Baseline inert mass fraction
      DOUBLE PRECISION, intent(in) :: Xs0_INERT
! Current mass fraction of inert
      DOUBLE PRECISION, intent(in) :: Xs_INERT

! Evaluate the solids EOS.
      eoss = pbase * xs0_inert / max(xs_inert, 1.0d-8)

      RETURN
      END FUNCTION eoss

      END MODULE eos