calc_k_s.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Subroutine: CALC_K_s                                                C
!  Purpose: Calculate the effective conductivity of solids phases      C
!                                                                      C
!                                                                      C
!  Comments:                                                           C
!  This routine will not be called if k_s0(M) is defined               C
!                                                                      C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
      SUBROUTINE calc_k_s(M)

! Modules
!---------------------------------------------------------------------//
      USE param1, only: undefined
      USE physprop, only: k_s0, k_s
      USE sendrecv, only: send_recv
! invoke user defined quantity
      USE usr_prop, only: usr_ks, calc_usr_prop
      USE usr_prop, only: solids_conductivity
      IMPLICIT NONE

! Dummy arguments
!---------------------------------------------------------------------//
! solids phase index
      INTEGER, INTENT(IN) :: M

!---------------------------------------------------------------------//


      IF (usr_ks(m)) THEN
         CALL calc_usr_prop(solids_conductivity,lm=m)
      ELSEIF (k_s0(m) == undefined) THEN
! unncessary check but included for clarity
         CALL calc_default_ks(m)
      ENDIF

      CALL send_recv(k_s, 2)

      RETURN
      END SUBROUTINE calc_k_s


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Subroutine: CALC_DEFAULT_Ks                                         C
!  Purpose: Compute the default value for each solids phases           C
!  conductivity where a solids phase is considered to be comprised of  C
!  discrete ash particles                                              C
!                                                                      C
!  Author:M. Syamlal                                  Date: 24-APR-96  C
!                                                                      C
!  Literature/Document References:                                     C
!  Bauer & Schlunder's (1978) theory                                   C
!                                                                      C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
      SUBROUTINE calc_default_ks(M)

! Modules
!---------------------------------------------------------------------//
      USE compar, only: ijkstart3, ijkend3
      USE functions, only: fluid_at
      USE fldvar, only: ep_g, ep_s
      USE param1, only: one, zero
      USE physprop, only: k_g, k_s
      USE toleranc, only: dil_ep_s
      USE run, only: units
      IMPLICIT NONE

! Dummy arguments
!---------------------------------------------------------------------//
! solids index
      INTEGER, INTENT(IN) :: M

! Local parameters
!---------------------------------------------------------------------//
! microscopic conductivity of ash in cal/s.cm.K
! (not modified by the gas phase)
      DOUBLE PRECISION :: Ks_micro
      parameter(ks_micro = 0.5258d-2)    !(2.2 J/s.m.K)
! constant in conductivity equation
      DOUBLE PRECISION :: PHI_k
      parameter(phi_k = 7.26d-3)

! Local variables
!---------------------------------------------------------------------//
! Indices
      INTEGER :: IJK
! Quantities in solids conductivity formula
      DOUBLE PRECISION :: BB, R_km, BoR, L_rm
!  Transform K_g(IJK) into the CGS if we work with SI
      DOUBLE PRECISION :: Kg_micro
!---------------------------------------------------------------------//

!!$omp parallel do private(IJK,B,R_km,BoR,L_rm,Kg_micro) &
!!$omp& schedule(dynamic,chunk_size)
      DO ijk = ijkstart3, ijkend3
         IF (fluid_at(ijk)) THEN

! All calculations are in CGS (1 cal = 4.183925J) and then converted
! to SI if needed
            IF (units == 'SI') THEN
!convert k_g to CGS units (cal/s.cm.K)
               kg_micro = k_g(ijk)/418.3925d0
            ELSE
! k_g already in CGS units (cal/s.cm.K)
               kg_micro = k_g(ijk)
            ENDIF

            IF( ep_s(ijk,m) >  dil_ep_s) THEN
               bb = 1.25d0 * ((one - ep_g(ijk))/ep_g(ijk))**(10.d0/9.d0)
               r_km = ks_micro/kg_micro
               bor  = bb/r_km
               l_rm = -(2.d0/(one-bor)) * &
                      ( ((r_km-one)/(one-bor)**2)*bor*log(bor) + &
                        (bb-one)/(one-bor) + (bb+one)/2.d0 )
! K_s is the macroscopic conductivity that has been modified by the
! presence of the gas phase (cal/s.cm.K)
               k_s(ijk,m) = (phi_k*r_km + (one-phi_k)*l_rm)*&
                             kg_micro/sqrt(one - ep_g(ijk))
            ELSE
               k_s(ijk, m) = zero
            ENDIF

! An approximate average value for the solids conductivity is 2.5*K_g
!            K_S(IJK,M) = 2.5*Kg_micro            !in CGS system

         ELSE   ! else branch if(fluid_at(ijk))
            k_s(ijk,m) = zero
         ENDIF   ! end if/else (fluid_at(ijk))

         IF (units == 'SI') k_s(ijk, m) = 418.3925d0*k_s(ijk, m)   !J/s.m.K

      ENDDO   ! end do (ijk=ijkstart3,ijkend3)

      RETURN
      END SUBROUTINE calc_default_ks