get_is.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  SUBROUTINE: GET_IS                                                  !
!  Author: M. Syamlal                                 Date: 21-OCT-92  !
!                                                                      !
!  Purpose: Find and validate i, j, k locations for IS's               !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE get_is(ISV)

      USE param
      USE param1
      USE geometry
      USE is
      USE indices
      USE funits
      USE compar

! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager

      IMPLICIT NONE

! Dummy Arguments:
!---------------------------------------------------------------------//
! Loop/variable indices
      INTEGER, INTENT(in) :: ISV

! Local Variables:
!---------------------------------------------------------------------//
! Error flag.
      INTEGER :: IER
! Calculated indices of the wall boundary
      INTEGER :: I_w , I_e , J_s , J_n , K_b , K_t
! Surface indictors
      LOGICAL :: X_CONSTANT, Y_CONSTANT, Z_CONSTANT
!......................................................................!

      CALL init_err_msg('GET_IS')

      x_constant = .true.
      y_constant = .true.
      z_constant = .true.

      IF(is_x_w(isv)/=undefined .AND. is_x_e(isv)/=undefined) THEN
         CALL calc_cell(xmin, is_x_w(isv), dx, imax, i_w)
         CALL calc_cell(xmin, is_x_e(isv), dx, imax, i_e)
         IF (is_x_w(isv) /= is_x_e(isv)) THEN
            x_constant = .false.
            i_w = i_w + 1
            IF(is_i_w(isv)/=undefined_i .OR.                           &
               is_i_e(isv)/=undefined_i) THEN
               CALL location_check(is_i_w(isv), i_w, isv, 'IS - west')
               CALL location_check(is_i_e(isv), i_e, isv, 'IS - east')
            ENDIF
         ENDIF
         is_i_w(isv) = i_w
         is_i_e(isv) = i_e
      ELSE
         IF(is_i_w(isv) /= undefined_i)                                &
            CALL calc_loc(xmin, dx, is_i_w(isv), is_x_w(isv))
         IF(is_i_e(isv) /= undefined_i)                                &
            CALL calc_loc(xmin, dx, is_i_e(isv), is_x_e(isv))
         IF (is_x_w(isv) /= is_x_e(isv)) x_constant = .false.
      ENDIF

!  If there is no variation in the I direction set indices to 1
      IF (no_i) THEN
         is_i_w(isv) = 1
         is_i_e(isv) = 1
      ENDIF
!
      IF (is_y_s(isv)/=undefined .AND. is_y_n(isv)/=undefined) THEN
         CALL calc_cell(zero, is_y_s(isv), dy, jmax, j_s)
         CALL calc_cell(zero, is_y_n(isv), dy, jmax, j_n)
         IF (is_y_s(isv) /= is_y_n(isv)) THEN
            y_constant = .false.
            j_s = j_s + 1
            IF(is_j_s(isv)/=undefined_i .OR.                           &
               is_j_n(isv)/=undefined_i) THEN
               CALL location_check(is_j_s(isv), j_s, isv, 'IS - south')
               CALL location_check(is_j_n(isv), j_n, isv, 'IS - north')
            ENDIF
         ENDIF
         is_j_s(isv) = j_s
         is_j_n(isv) = j_n
      ELSE
         IF(is_j_s(isv) /= undefined_i)                                &
            CALL calc_loc(zero, dy, is_j_s(isv), is_y_s(isv))
         IF(is_j_n(isv) /= undefined_i)                                &
            CALL calc_loc(zero, dy, is_j_n(isv), is_y_n(isv))
         IF (is_y_s(isv) /= is_y_n(isv)) y_constant = .false.
      ENDIF

! If there is no variation in the J direction set indices to 1
      IF (no_j) THEN
         is_j_s(isv) = 1
         is_j_n(isv) = 1
      ENDIF

      IF (is_z_b(isv)/=undefined .AND. is_z_t(isv)/=undefined) THEN
         CALL calc_cell(zero, is_z_b(isv), dz, kmax, k_b)
         CALL calc_cell(zero, is_z_t(isv), dz, kmax, k_t)
         IF (is_z_b(isv) /= is_z_t(isv)) THEN
            z_constant = .false.
            k_b = k_b + 1
            IF (is_k_b(isv)/=undefined_i .OR.                          &
               is_k_t(isv)/=undefined_i) THEN
               CALL location_check(is_k_b(isv), k_b, isv, 'IS - bottom')
               CALL location_check(is_k_t(isv), k_t, isv, 'IS - top')
            ENDIF
         ENDIF
         is_k_b(isv) = k_b
         is_k_t(isv) = k_t
      ELSE
         IF(is_k_b(isv) /= undefined_i)                                &
            CALL calc_loc(zero, dz, is_k_b(isv), is_z_b(isv))
         IF(is_k_t(isv) /= undefined_i)                                &
            CALL calc_loc(zero, dz, is_k_t(isv), is_z_t(isv))
         IF (is_z_b(isv) /= is_z_t(isv)) z_constant = .false.
      ENDIF

!  If there is no variation in the K direction set indices to 1
      IF (no_k) THEN
         is_k_b(isv) = 1
         is_k_t(isv) = 1
      ENDIF

!  Check whether the boundary is a plane parallel to one of the three
!  coordinate planes, else check whether a direction is specified by IS_TYPE
      IF(x_constant .OR. y_constant .OR. z_constant) THEN
         IF(is_x_w(isv)/=undefined .AND. is_y_s(isv)/=undefined .AND.  &
            is_z_b(isv)/=undefined) CALL check_plane(x_constant,       &
            y_constant, z_constant,isv, 'IS')
      ELSE
         SELECT CASE(is_type(isv)(1:1))
         CASE('X','Y','Z') ! Do Nothing
         CASE DEFAULT
            WRITE(err_msg, 1100) trim(ivar('IS_TYPE',isv)),            &
               trim(is_type(isv))
            CALL flush_err_msg(abort=.true.)
         END SELECT
      ENDIF

 1100 FORMAT('Error 1100: ',a,' = ',a,' is specified as a volume',/    &
         'and therefore should have should have a directional prefix;',&
         /'Valid prefix values: X_, Y_, Z_',/'Please correct the ',/   &
         'mfix.dat file.')

! CHECK FOR VALID VALUES
      ier = 0
      IF(is_i_w(isv)<1 .OR. is_i_w(isv)>imax2) ier = 1
      IF(is_i_e(isv)<1 .OR. is_i_e(isv)>imax2) ier = 1
      IF(is_j_s(isv)<1 .OR. is_j_s(isv)>jmax2) ier = 1
      IF(is_j_n(isv)<1 .OR. is_j_n(isv)>jmax2) ier = 1
      IF(is_k_b(isv)<1 .OR. is_k_b(isv)>kmax2) ier = 1
      IF(is_k_t(isv)<1 .OR. is_k_t(isv)>kmax2) ier = 1
      IF(is_k_b(isv) > is_k_t(isv)) ier = 1
      IF(is_j_s(isv) > is_j_n(isv)) ier = 1
      IF(is_i_w(isv) > is_i_e(isv)) ier = 1

      IF(ier /= 0)THEN
         WRITE(err_msg,1101) isv,                                      &
            'X', is_x_w(isv), is_x_e(isv),'I',is_i_w(isv),is_i_e(isv), &
            'Y', is_y_s(isv), is_y_n(isv),'J',is_j_s(isv),is_j_n(isv), &
            'Z', is_z_b(isv), is_z_t(isv),'K',is_k_b(isv),is_k_t(isv)
         CALL flush_err_msg(abort=.true.)
      ENDIF

 1101 FORMAT('Error 1101: Invalid location specified for IS ',i3,'.',  &
         3(/3x,a1,': ',g12.5,',',g12.5,8x,a1,': ',i8,',',i8),/         &
         'Please correct the mfix.dat file.')

      CALL finl_err_msg

      RETURN
      END SUBROUTINE get_is