stiff_chem_maps_mod.f

Go to the documentation of this file.

      MODULE stiff_chem_maps

      PRIVATE

! Variable Access:
!---------------------------------------------------------------------//

! Subroutine Access:
!---------------------------------------------------------------------//
      PUBLIC :: mapmfixtoode,   &
                mapodetomfix

      contains



!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Module name: mapMFIXtoODE                                           !
!                                                                      !
!  Purpose: This routine maps MFIX variables into the ODE array.       !
!                                                                      !
!  Author: J.Musser                                   Date: 07-Feb-13  !
!                                                                      !
!  Comments:                                                           !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE mapmfixtoode(lnD, lNEQ, loD, lVars)

! Global Variables:
!---------------------------------------------------------------------//
      use fldvar, only: rop_g
      use fldvar, only: rop_s
      use fldvar, only: t_g
      use fldvar, only: t_s
      use fldvar, only: x_g
      use fldvar, only: x_s

      use physprop, only: nmax
      use physprop, only: mmax


      implicit none


! Passed Variables:
!---------------------------------------------------------------------//
! Passed array dimensions
      INTEGER, intent(in) :: lnD  ! lNEQ
      INTEGER, intent(in) :: loD  ! lVars

! (1) Number of ODEs to be solve
! (2) Fluid cell index
      INTEGER, intent(in) :: lNEQ(lnd)
! Array of dependent variable initial values.
      DOUBLE PRECISION, intent(out)  :: lVars(lod)


! Local Variables:
!---------------------------------------------------------------------//
! Fluid cell index
      INTEGER :: IJK
! Loop indicies:
      INTEGER :: M  ! phase
      INTEGER :: N  ! species
! ODE Equation Counter
      INTEGER :: Node


! Initialize.
      ijk = lneq(2)
      lvars = 0.0d0
      node = 1

! Gas phase density.
      lvars(node) = rop_g(ijk);             node = node + 1
! Gas phase temperature.
      lvars(node) = t_g(ijk);               node = node + 1
! Gas phase species mass fractions.
      DO n=1,nmax(0)
         lvars(node) = x_g(ijk,n);          node = node + 1
      ENDDO

! Solids temperature.
      DO m = 1, mmax
         lvars(node) = t_s(ijk,m);          node = node + 1
      ENDDO

      DO m = 1, mmax
         IF(lneq(2+m) == 1) THEN
! Solids volume fraction.
            lvars(node) = rop_s(ijk,m);     node = node + 1
! Solids phase species mass fractions.
            DO n=1,nmax(m)
               lvars(node) = x_s(ijk,m,n);  node = node + 1
            ENDDO
         ENDIF
      ENDDO

      RETURN
      END SUBROUTINE mapmfixtoode



!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Module name: mapODEtoMFIX                                           !
!                                                                      !
!  Purpose: This is a driver routine for mapping variables stored in   !
!  the ODE array back to MFIX field variables.                         !
!                                                                      !
!  Author: J.Musser                                   Date: 07-Feb-13  !
!                                                                      !
!  Comments:                                                           !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE mapodetomfix(lnD, lNEQ, loD, lVars)

! Global Variables:
!---------------------------------------------------------------------//
! Material density.
      use fldvar, only : ro_g, ro_s
! Bulk density.
      use fldvar, only : rop_g, rop_s
! Gas temperature. (K)
      use fldvar, only : t_g, t_s
! Species Mass frcations.
      use fldvar, only : x_g, x_s
! Number of solids phases.
      use physprop, only : mmax
! Number of species comprising each phase.
      use physprop, only : nmax
! Gas constant (cal/g.K)
      use constant, only : gas_const
! Gas pressure
      use fldvar, only : p_g
! Gas phase volume fraction.
      use fldvar,   only : ep_g
! Species molecular weights
      use physprop, only : mw_g
! Gas phase mixture molecular weight.
      use physprop, only : mw_mix_g
! Baseline/Unreaced solids density.
      use physprop, only: ro_s0
! Initial mass fraction of inert solids species.
      use physprop, only: x_s0
! Index of inert solids phase species.
      use physprop, only: inert_species
! Rank ID and Rank of IO process.
      use compar,   only : mype
! Runtime flag for variable solids density.
      use run, only: solve_ros

! Variable solids density calculation.
      USE eos, ONLY: eoss

! Global Parameters:
!---------------------------------------------------------------------//
      use param1,   only : one
      use param1,   only : large_number
      use param1,   only : small_number


      implicit none


! Passed Variables:
!---------------------------------------------------------------------//
! (1) Number of ODEs to be solve
! (2) Fluid cell index
      INTEGER, intent(in) :: lnD
      INTEGER, intent(in) :: lNEQ(lnd)

! Array of dependent variable initial values.
      INTEGER, intent(in) :: loD
      DOUBLE PRECISION, intent(in)  :: lVars(lod)


! Local Variables:
!---------------------------------------------------------------------//
! Fluid Cell index.
      INTEGER :: IJK
      INTEGER :: L

! Loop indicies:
      INTEGER :: M    ! phase
      INTEGER :: N    ! species
      INTEGER :: Node ! ODE Equation Counter

! Error flags/counters.
      INTEGER :: countNaN
      LOGICAL :: writeMsg

      ijk = lneq(2)

! Check if any NaNs were returned from ODEPACK.  This shouldn't happend
! but errors in the usr_rates file can cause this to occur.
!-----------------------------------------------------------------------
      countnan = 0
      writemsg = .false.
      nan_lp: do l=1, lod
         if(lvars(l).NE.lvars(l)) then
            countnan = countnan + 1
            writemsg = .true.
         endif
      enddo nan_lp

      if(writemsg) then
         write(*,"(3x,'From MapODEtoMFIX: NaNs Found! :: ',3(3x,I4))") &
            mype, ijk, countnan

         if(countnan < lod) then
            do l=1, lod
               if(lvars(l).NE.lvars(l))                                &
                  write(*,"(5x,' NaN in Var ',I2)") l
            enddo
         endif
      endif

! Directly map the ODE values into the field variable names.
!-----------------------------------------------------------------------
! Initialize the loop counter for ODEs.
      node = 1

! Gas phase density.
      rop_g(ijk) = lvars(node);                    node = node + 1
! Gas phase temperature.
      t_g(ijk) = lvars(node);                      node = node + 1
! Gas phase species mass fractions.
      DO n=1,nmax(0)
         x_g(ijk,n) = lvars(node);                 node = node + 1
      ENDDO

! Solids temperature.
      DO m = 1, mmax
         IF(rop_s(ijk,m) > 1.0d-8) &
            t_s(ijk,m) = lvars(node);              node = node + 1
      ENDDO

! Only map back what was calculated.
      DO m = 1, mmax
         IF(lneq(2+m) == 1) THEN
! Solids bulk density.
            rop_s(ijk,m) = lvars(node);            node = node + 1
! Solids phase species mass fractions.
            DO n=1,nmax(m)
               x_s(ijk,m,n) = lvars(node);         node = node + 1
            ENDDO
! Update the solids density from speices composition. This update must
! come after the species data is mapped back into the MFIX variables.
            IF(solve_ros(m)) ro_s(ijk,m) = eoss(ro_s0(m),              &
               x_s0(m,inert_species(m)), x_s(ijk,m,inert_species(m)))
         ENDIF
      ENDDO

! Calculate the gas volume fraction from solids volume fractions. Only
! update it's value if the solids equations are being solved.
      IF(sum(lneq(3:)) > 0) ep_g(ijk) = &
         one - sum(rop_s(ijk,1:mmax)/ro_s(ijk,1:mmax))

! Gas phase bulk density is updated within the stiff solver (lVar(1)).
! Now that the gas phase volume fraction is updated, the gas phase
! density can be backed out. RO_g * EP_g = ROP_g
      IF(ep_g(ijk) > small_number) THEN
         ro_g(ijk) = rop_g(ijk) / ep_g(ijk)
      ELSE
! This case shouldn't happen, however 'LARGE_NUMBER' is used to aid
! in tracking errors should this somehow become and issue.
         ro_g(ijk) = large_number
      ENDIF

! Calculate the mixture molecular weight.
      mw_mix_g(ijk) = sum(x_g(ijk,1:nmax(0))/mw_g(1:nmax(0)))
      mw_mix_g(ijk) = one/mw_mix_g(ijk)

! Calculate the gas phase pressure.
      p_g(ijk) = (ro_g(ijk)*gas_const*t_g(ijk))/mw_mix_g(ijk)

      RETURN
      END SUBROUTINE mapodetomfix

      END MODULE stiff_chem_maps