check_chemical_rxns.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Module name: CHECK_CHEMICAL_RXNS                                    !
!  Author: J.Musser                                   Date: 21-MAR-14  !
!                                                                      !
!  Purpose: Check chemical reactions specifications                    !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_chemical_rxns

! User defined reaction names from reaction blocks @(RXNS)
      use parse, only: rxn_name, des_rxn_name

      use parse, only: rxn_chem_eq, des_rxn_chem_eq
      use parse, only: usrdh, des_usrdh
      use parse, only: usrfdh, des_usrfdh


! Number of continuum reactions and data object
      use rxns, only: no_of_rxns, reaction
! Number of discrete reactions and data object
      use des_rxns, only: no_of_des_rxns, des_reaction
! User specified species names and aliases:
      use rxns, only: species_g, species_alias_g
      use rxns, only: species_s, species_alias_s

! Number of continuum solids
      use physprop, only: smax
! Number of discrete solids
      use discretelement, only: des_mmax
! Number of species comprising each phase
      use physprop, only: nmax

!
      use param1, only: undefined_i

      use rxn_com, only: checkspeciesinc
      use rxn_com, only: checkduplicatealiases


      use error_manager

      IMPLICIT NONE

! Error flag
      INTEGER :: IER

! Local representation of the number of solids phases.
      INTEGER :: lMMAX

! Undefined indicates that no reaction block was found in the deck file.
      IF(no_of_rxns == undefined_i) no_of_rxns = 0
      IF(no_of_des_rxns == undefined_i) no_of_des_rxns = 0

! If there are no chemical reactions, then skip this routine.
      IF(no_of_rxns + no_of_des_rxns == 0) RETURN

      CALL init_err_msg('CHECK_CHEMICAL_RXNS')

! Allocate the arrays as a work-around for Intel compiler with debug.
      IF(no_of_rxns == 0) allocate(rxn_name(1))
      IF(no_of_des_rxns == 0) allocate(des_rxn_name(1))

! Initialize the number of solids phases.
      lmmax = smax + des_mmax

! Verify that the species aliases are unique.
      CALL checkduplicatealiases(nmax(0), species_alias_g(:), &
         lmmax, nmax(1:lmmax), species_alias_s(:,:))

! Verify that species aliases in the datafile match those in the
! species.inc file.
      CALL checkspeciesinc(nmax(0), species_alias_g(:), lmmax,         &
         nmax(1:lmmax), species_alias_s(:,:), no_of_rxns, rxn_name(:), &
         no_of_des_rxns, des_rxn_name)


      IF(no_of_rxns > 0) THEN
         CALL check_chemical_rxns_common(no_of_rxns, rxn_name,         &
            rxn_chem_eq, usrdh, usrfdh, reaction)
      ENDIF

      IF(no_of_des_rxns > 0) THEN
         CALL check_chemical_rxns_common(no_of_des_rxns, des_rxn_name, &
            des_rxn_chem_eq, des_usrdh, des_usrfdh, des_reaction)
      ENDIF

      CALL finl_err_msg

      RETURN

      CONTAINS

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Module name: CHECK_CHEMICAL_RXNS_COMMON                             !
!  Author: J.Musser                                   Date: 21-MAR-14  !
!                                                                      !
!  Purpose: Check chemical reactions specifications                    !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_chemical_rxns_common(COUNT, NAME, CHEM_EQ, DH,  &
         fdh, rxn_array)

! Runtime flags for solving energy and species equations.
      use run, only: energy_eq, species_eq
! Definition of derived data type
      use rxn_com, only: reaction_block
! User specified constant specific heats:
      use physprop, only: c_pg0, c_ps0
! Molecular weights:
      use physprop, only: mw_g, mw_s
! Flag marking when the thermochemical database is read.
      use rxns, only: rdatabase

      use param, only: dim_m, dimension_rxn


      use parse, only: setreaction
      use rxn_com, only: checkthermoreqs
      use rxn_com, only: checkmassbalance
      use rxn_com, only: calcinterphasetxfr
      use rxn_com, only: write_rxn_summary



      use error_manager

      IMPLICIT NONE

      INTEGER, INTENT(IN) :: COUNT

! Reaction Names from mfix.dat file:
      CHARACTER(len=32), INTENT(IN) ::  NAME(dimension_rxn)
! Chemical equations:
      CHARACTER(len=512), INTENT(IN) :: CHEM_EQ(dimension_rxn)
! User defined heat of reaction:
      DOUBLE PRECISION, INTENT(IN) :: DH(dimension_rxn)
! User defined heat of reaction partitions.
      DOUBLE PRECISION, INTENT(IN) :: fDH(dimension_rxn,0:dim_m)

! Array of reaction data objects.
      TYPE(reaction_block), TARGET, ALLOCATABLE :: RXN_ARRAY(:)



! loop/variable indices1
      INTEGER :: L

      TYPE(reaction_block), POINTER :: This

      DOUBLE PRECISION netMassTransfer(0:dim_m)




      CALL init_err_msg('CHECK_CHEMICAL_RXNS_COMMON')


! Allocate reaction blocks.
      allocate(rxn_array(count))





! Loop over reaction data pulled from data file.
      DO l=1, count

         this => rxn_array(l)

! Store the reaction name.
         this%Name = trim(name(l))

! This check should not be necessary. Pre-processing by make_mfix and
! reading the data file (PARSE_RXN) should have already caught any
! issues.
         IF(len_trim(this%Name) == 0) THEN
            WRITE(err_msg, 1100) l
            CALL flush_err_msg(abort=.true.)
         ENDIF

 1100 FORMAT('Error 1100: No reaction name identified for reaction ',  &
         i3,'.',/'This should have been caught during the parsing ',   &
         'routines.')

! Store the chemical equation.
         this%ChemEq = trim(chem_eq(l))

! Verify that a chemical equation was given in the data file.
         IF(len_trim(this%ChemEq) == 0) THEN
            WRITE(*,1101) trim(this%Name)
            CALL flush_err_msg(abort=.true.)
         ENDIF

 1101 FORMAT('Error 1101: No chemical equation identified for ',       &
         'reaction ',a,'.',/'Please correct the mfix.dat file.')

! Take the data read from the data file and populate the reaction block.
         CALL setreaction(this, nmax(0), species_alias_g(:),lmmax,     &
            nmax(1:lmmax), species_alias_s(:,:), dh(l), fdh(l,:))

! If the energy equations are not being solved and a user provided
! heat of reaction is given, flag error and exit.
         IF(.NOT.energy_eq .AND. .NOT.this%Calc_DH) THEN
            WRITE(err_msg,1200) trim(this%Name)
            CALL flush_err_msg(abort=.true.)
         ENDIF

 1200 FORMAT('Error 1200: Inconsistent user input. Energy equations ', &
         'are NOT being',/'solved and a user defined heat of reaction',&
         ' was detected',' for chemical',/' reaction ',a,'.',/'Please',&
         ' correct the mfix.dat file.')

! Skip empty reactions.
         IF(this%nSpecies == 0 .AND. this%nPhases == 0) THEN
            cycle

! Something went wrong while parsing the reaction. This is a sanity
! check and should never be true.
         ELSEIF((this%nPhases == 0 .AND. this%nSpecies /= 0) .OR.      &
            (this%nPhases /= 0 .AND. this%nSpecies == 0)) THEN

            WRITE(err_msg,1201) trim(this%Name), this%nPhases,         &
               this%nSpecies
            CALL flush_err_msg(abort=.true.)
         ENDIF

 1201 FORMAT('Error 1201: Illogical data returned from setReaction ',  &
         'for chemical',/'reaction',1x,a,'.',//' Number of phases ',   &
         'identified: ',i3,/'Number of species identified: ',i3,//,    &
         'Please check the mfix.dat file.')

! Verify that the necessary information for each species in the reaction
! was defined.
         CALL checkthermoreqs(this, species_g, species_s, rdatabase,   &
            mw_g, mw_s, c_pg0, c_ps0)


! Verify Mass Balance (Mass of Reactants = Mass of Products)
!---------------------------------------------------------------------//
         ier = 0
         CALL checkmassbalance('CHECK_CHEMICAL_RXNS', this, &
            netmasstransfer(:), ier)
         IF(ier /= 0) THEN
            CALL write_rxn_summary(this, species_alias_g(:), &
               species_alias_s(:,:), .true.)
         ENDIF

! Determine interphase exchanges
!---------------------------------------------------------------------//
         CALL calcinterphasetxfr('CHECK_CHEMICAL_RXNS', this,   &
            netmasstransfer(:), energy_eq, species_eq(:), &
            species_alias_g(:), lmmax, species_alias_s(:,:))
      ENDDO

! Write a summary of the chemical reactions
!---------------------------------------------------------------------//
      DO l=1, count
         this => rxn_array(l)
         CALL write_rxn_summary(this, species_alias_g(:), &
            species_alias_s(:,:), .false.)
      ENDDO

      CALL finl_err_msg

      RETURN
      END SUBROUTINE check_chemical_rxns_common




      END SUBROUTINE check_chemical_rxns