rxn_com_mod.f

Go to the documentation of this file.

MODULE rxn_com

   USE compar
   USE exit, only: mfix_exit
   USE funits
   USE param
   USE param1

! The following data types are used to group chemical reaction data.
!-----------------------------------------------------------------------

! Species belong to PHASE_ associated with a particular reaction.
      TYPE species_
! A link between the reacting species' arbitrary index and the
! associated phase index in MFiX.
         INTEGER pmap
! A link between the reacting species' arbitrary index and the
! associated species index in MFiX.
         INTEGER smap
! Stoichiometric coefficient of the species from chemical equation.
         DOUBLE PRECISION coeff
! Molecular weight
         DOUBLE PRECISION mw
! Fractional mass transfer
         DOUBLE PRECISION xxfr
! Index indicating enthalpy transfer associated with mass transfer.
         INTEGER mxfr
! Molecular weight of speices multiplying the stoichiometric coefficient
         DOUBLE PRECISION mwxstoich
      END TYPE species_

! Grouping of reaction information.
      TYPE reaction_block
! Name of reaction construct from data file.
         CHARACTER(LEN=32) :: name
! User defined chemical equation from data file.
         CHARACTER(LEN=512) :: chemeq
! Reaction classification: Homogeneous, Heterogeneous, Catalytic.
         CHARACTER(LEN=16) :: classification
! Indicates if the automated heat of reaction is to be calculated (T) or
! if the user has supplied a heat of reaction (F).
         LOGICAL calc_dh
! Number of phases associated with the reaction.
         INTEGER nphases
! Number of species associated with the reaction.
         INTEGER nspecies
! User-specified heat of reaction split among phases by fracDH
         DOUBLE PRECISION, DIMENSION(:), ALLOCATABLE :: hor
! Interphase mass transfer.
         DOUBLE PRECISION, DIMENSION(:), ALLOCATABLE :: rphase
! Reactant/Product information
         TYPE(species_), DIMENSION(:), ALLOCATABLE :: species

      END TYPE reaction_block

      CONTAINS

!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~!
!  Subroutine: checkDuplicateAlaises                                   !
!                                                                      !
!  Purpose: Loop through species in all phases and ensure that no two  !
!  entries are the same. ***Warning*** Species aliases that were not   !
!  specified are skipped. Non-specified aliases are treated later in   !
!  parse_mod.f/mapAliases.                                             !
!                                                                      !
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~!
      SUBROUTINE checkduplicatealiases(lNg, SA_g, lMMx, lNs, SA_s)

      use error_manager

      IMPLICIT NONE

! Number of gas speices
      INTEGER, INTENT(IN) :: lNg
! Gas phase species aliases
      CHARACTER(len=32), DIMENSION(DIM_N_g), INTENT(IN) :: SA_g
! Number of solids phases
      INTEGER, INTENT(IN) :: lMMx
! Number of species in each solids phase.
      INTEGER, DIMENSION(DIM_M), INTENT(IN) :: lNs
! Solids phase speices aliases.
      CHARACTER(len=32), DIMENSION(DIM_M, DIM_N_s), INTENT(IN) :: SA_s

! Loop indices.
      INTEGER M1, N1  ! Phase, Species
      INTEGER M2, N2  ! Phase, Species

      CHARACTER(len=32) SA1, SA2

      CALL init_err_msg("RXN_COM --> checkDuplicateAliases")

! Set variables for error messages.
      m1 = 0
      m2 = 0
! Compare gas phase aliases.
      DO n1 = 1, lng
         sa1 =sa_g(n1)
         IF(len_trim(sa1) == 0) cycle
         DO n2=n1+1,lng
            sa2 = sa_g(n2)
            IF(len_trim(sa2) == 0) cycle
            IF(comparealiases(sa1, sa2)) GoTo 100
         ENDDO
! Compare gas and solids phase aliases.
         DO m2 = 1, lmmx
            DO n2 = 1, lns(m2)
               sa2 = sa_s(m2,n2)
               IF(len_trim(sa2) == 0) cycle
               IF(comparealiases(sa1, sa2)) GoTo 100
            ENDDO
         ENDDO
      ENDDO
! Compare aliases between solids phases
      DO m1 = 1, lmmx
         DO n1 = 1, lns(m1)
            sa1 = sa_s(m1,n1)
            IF(len_trim(sa1) == 0) cycle
! Self phase comparison.
            m2 = m1
            DO n2=n1+1, lns(m2)
               sa2 = sa_s(m2,n2)
               IF(len_trim(sa2) == 0) cycle
               IF(comparealiases(sa1, sa2)) GoTo 100
            ENDDO
! Compare with other phases.
            DO m2 = m1+1, lmmx
               DO n2 = 1, lns(m2)
                  sa2 = sa_s(m2,n2)
                  IF(len_trim(sa2) == 0) cycle
                  IF(comparealiases(sa1, sa2)) GoTo 100
               ENDDO
            ENDDO
         ENDDO
      ENDDO

      CALL finl_err_msg
      RETURN

  100 WRITE(err_msg, 1100) m1, n1, sa1, m2, n2, sa2
      CALL flush_err_msg(abort=.true.)

 1100 FORMAT('Error 1100: Non-unique species aliases detected.',/      &
         3x,'Phase: ',i2,', Species: ',i3,' - Alias: ',a,/             &
         3x,'Phase: ',i2,', Species: ',i3,' - Alias: ',a,//            &
         'Please correct the mfix.dat file.')

      END SUBROUTINE checkduplicatealiases

!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~!
!  Function name: checkSpeciesInc()                                    !
!                                                                      !
!  Purpose: Loop through the species.inc file and verify that the      !
!  match those provided in the datafile.                               !
!                                                                      !
!  Variables referenced: None                                          !
!                                                                      !
!  Variables modified: None                                            !
!                                                                      !
!  Local variables: None                                               !
!                                                                      !
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~!
      SUBROUTINE checkspeciesinc(lNg, SA_g, lMMx, lNs, SA_s,           &
         lnrxn,  lrnames, lnrxn_des, lrnames_des)

      use run, only: reinitializing
      use error_manager
      use toleranc
      USE utilities, ONLY: blank_line, seek_comment

      IMPLICIT NONE

! Number of gas speices
      INTEGER, INTENT(IN) :: lNg
! Gas phase species aliases
      CHARACTER(len=32), DIMENSION(DIM_N_g), INTENT(IN) :: SA_g
! Number of solids phases
      INTEGER, INTENT(IN) :: lMMx
! Number of species in each solids phase.
      INTEGER, DIMENSION(DIM_M), INTENT(IN) :: lNs
! Solids phase speices aliases.
      CHARACTER(len=32), DIMENSION(DIM_M, DIM_N_s), INTENT(IN) :: SA_s
! Number of reactions
      INTEGER, INTENT(IN) :: lNRxn
! Reaction Names (aliases)
      CHARACTER(len=32), INTENT(IN) ::  lRNames(dimension_rxn)
! Number of discrete reactions
      INTEGER, INTENT(IN) :: lNRxn_DES
! Reaction Names for discrete solids (aliases)
      CHARACTER(len=32), INTENT(IN) ::  lRNames_DES(dimension_rxn)

! Input/Output status.
      INTEGER :: IOS
! File unit.
      INTEGER, PARAMETER :: FUNIT = 167
! Full path to Burcat and Ruscic database
      CHARACTER(len=255) :: FILENAME
      CHARACTER(len=128) :: INPUT
! Loop counters
      INTEGER :: SRC, M
! Position of interest in string.
      INTEGER :: POS
! Index from species.inc file.
      INTEGER :: lIndex
      CHARACTER(len=64) :: lName
      CHARACTER(len=32) :: tName
! Length of noncomment string
      INTEGER :: LINE_LEN

      CALL init_err_msg("RXN_COM --> checkDuplicateAliases")

      src = 0

! Loop over possible locations .
      src_lp: DO
         src = src + 1
         SELECT CASE(src)

! Check the local run directory.
         CASE(1); filename = 'species.inc'
            OPEN(convert='BIG_ENDIAN',unit=funit,file=trim(filename),status='OLD',iostat=ios)
            IF(ios /= 0) cycle src_lp
            IF(.NOT.reinitializing)THEN
               WRITE(err_msg, 1000)'species.inc'
               CALL flush_err_msg(header=.false., footer=.false.)
            ENDIF

 1000 FORMAT(/2x,'Verifying reaction aliases in ',a)

! No species.inc file was located.
         CASE DEFAULT
            IF(.NOT.reinitializing)THEN
               WRITE(err_msg, 1004)
               CALL flush_err_msg
            ENDIF
            EXIT src_lp
         END SELECT

 1004 FORMAT('Warning 1004: Unable to locate the species.inc file. No ',&
         'verification',/'of mfix.dat species aliases or reaction ',    &
         'names can be preformed.')

         rewind(funit)
         read_lp: DO
            READ(funit,"(A)",iostat=ios) input

! This is a sanity check because the species.inc file is generated by
! make_mfix and therefore should be the correct format.
            IF(ios > 0) THEN
               WRITE(err_msg,1200) trim(adjustl(filename))
               CALL flush_err_msg(abort=.true.)
 1200 FORMAT('Error 1200: There was a problem reading file: ',a)

! All entries have been processed.
            ELSEIF(ios<0)THEN
               EXIT src_lp
            ENDIF

! Clean up the input.
            line_len = seek_comment(input,len(input)) - 1
            CALL remove_comment(input, line_len + 1, len(input))
            CALL make_upper_case(input, line_len)
            CALL replace_tab(input, line_len)

! Skip empty entires.
            IF(line_len <= 0) cycle read_lp
            IF(blank_line(input)) cycle read_lp

            pos = index(input,"INTEGER, PARAMETER ::")
            IF(pos /= 0) THEN
               input = input((pos + 21):)
            ELSE
               cycle read_lp
            ENDIF

! We only want to process lines that have = as the other are coments.
            pos = index(input,"=")
            IF(pos == 0) cycle read_lp

! Store the species alias.
            WRITE(lname,"(A)") trim(adjustl(input(:(pos-1))))

! Convert the read index from string to integer. Report any errors.
            READ(input((pos+1):),*,iostat=ios) lindex
            IF(ios /= 0) THEN
               WRITE(err_msg,1205) 'index', trim(input)
               CALL flush_err_msg(abort=.true.)
            ENDIF

 1205 FORMAT('Error 1205: Unable to obtain alias index from species.', &
         'inc file.',//' INPUT: ',a)

! Match against what was provided in the datafile:
! Gas phase species aliases.
            IF(lindex <= lng) THEN
               tname = sa_g(lindex)
               IF(comparealiases(tname, lname)) cycle read_lp
            ENDIF

! Solids phase species aliases.
            DO m = 1, lmmx
               IF(lindex <= lns(m))THEN
                  tname = sa_s(m, lindex)
                  IF(comparealiases(tname, lname)) cycle read_lp
               ENDIF
            ENDDO

! Reaction Names
            IF(lindex <= lnrxn)THEN
               tname =  lrnames(lindex)
               IF(comparealiases(tname, lname)) cycle read_lp
            ENDIF

! Reaction Names for discrete solids
            IF(lindex <= lnrxn_des)THEN
               tname =  lrnames_des(lindex)
               IF(comparealiases(tname, lname)) cycle read_lp
            ENDIF

            WRITE(err_msg,1300) trim(lname), lindex
            CALL flush_err_msg

 1300 FORMAT('Error 1300: An entry in the species.inc file does not ', &
         'match any inputs',/'in the mfix.dat file.'/3x,'Name: ',a,4x, &
         'Index: ',i3,/'If the quantity or order of gas species, ',    &
         'solids species, or chemical',/'reactions has changed, then ',&
         'the executable must be re-build. Please',/'see the document',&
         'ation for specifying chemical reactions.')

         ENDDO read_lp
      ENDDO src_lp

      CLOSE(funit)
      CALL finl_err_msg
      RETURN

      END SUBROUTINE checkspeciesinc


!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~!
!  Function name: compareAlaises()                                     !
!                                                                      !
!  Purpose:                                                            !
!                                                                      !
!  Variables referenced: None                                          !
!                                                                      !
!  Variables modified: None                                            !
!                                                                      !
!  Local variables: None                                               !
!                                                                      !
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~!
      LOGICAL FUNCTION comparealiases(lS1, lS2, N1, N2)

      IMPLICIT NONE

      CHARACTER(len=*), INTENT(IN) :: lS1, lS2

      INTEGER, OPTIONAL, INTENT(IN) :: N1, N2

      CALL make_upper_case (ls1, len(ls1))
      CALL make_upper_case (ls2, len(ls2))

      comparealiases = .false.
      IF(trim(ls1) == trim(ls2)) comparealiases = .true.

      IF(.NOT.comparealiases) RETURN

      IF(PRESENT(n1) .AND. PRESENT(n2)) THEN
         IF(n1 == n2) THEN
            comparealiases = .true.
         ELSE
            comparealiases = .false.
         ENDIF
      ENDIF

      RETURN
      END FUNCTION comparealiases



!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~!
!  Subroutine: WRITE_RXN_SUMMARY                                       !
!                                                                      !
!  Purpose:                                                            !
!                                                                      !
!  Variables referenced: None                                          !
!                                                                      !
!  Variables modified: None                                            !
!                                                                      !
!  Local variables: None                                               !
!                                                                      !
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~!
      SUBROUTINE write_rxn_summary(RxN, lSAg, lSAs, ABORT, fUNIT)

      USE toleranc

      IMPLICIT NONE

! Data structure for storing reaction data.
      TYPE(reaction_block), POINTER, INTENT(IN) :: RxN

! Gas phase species aliases
      CHARACTER(len=32), DIMENSION(DIM_N_g), INTENT(IN) :: lSAg
! Solids phase speices aliases.
      CHARACTER(len=32), DIMENSION(DIM_M, DIM_N_s), INTENT(IN) :: lSAs
! Flag to abort the run.
      LOGICAL, INTENT(IN) :: ABORT

! Optional file unit.
      INTEGER, OPTIONAL :: fUNIT

      CHARACTER(LEN=72) :: OUTPUT, full, divided, empty

      CHARACTER(LEN=32) :: lSP

      INTEGER lN, M, N
      INTEGER lS, lE

      INTEGER UNIT_FLAG

      IF(present(funit)) THEN
         unit_flag = funit
      ELSE
         unit_flag = -1
      ENDIF

      empty = '  '
      CALL write_rs0(empty, unit_flag)

      full = ''
      WRITE(full,2000)

      divided = ''
      WRITE(divided,2005)

! Lead bar
      CALL write_rs0(full, unit_flag)
! Reaction Nmae
      output = ''
      WRITE(output, 2001)trim(rxn%Name)
      output(72:72) = '|'
      CALL write_rs0(output, unit_flag)

! Row Divider
      CALL write_rs0(full, unit_flag)

      output = ''
      WRITE(output, 2002)trim(rxn%ChemEq(1:54))
      output(72:72) = '|'
      CALL write_rs0(output, unit_flag)

      CALL write_rs0(full, unit_flag)

      IF(rxn%nSpecies > 0) THEN

         output = ''
         WRITE(output, 2007)trim(rxn%Classification)
         output(72:72) = '|'
         CALL write_rs0(output, unit_flag)
! Row Divider
         CALL write_rs0(full, unit_flag)

         WRITE(output,2003); CALL write_rs0(output, unit_flag)
         WRITE(output,2004); CALL write_rs0(output, unit_flag)
         CALL write_rs0(divided, unit_flag)
      ENDIF


      DO ln = 1, rxn%nSpecies

         m = rxn%Species(ln)%pMap
         n = rxn%Species(ln)%sMap

         WRITE(output,2006)

         IF(m == 0) THEN
            IF(len_trim(lsag(n)) > 8) THEN
               lsp = lsag(n)
               output(5:13) = lsp(1:8)
            ELSE
              ls = (9-int(len_trim(lsag(n))/2))
              le = ls + len_trim(lsag(n))
               output(ls:le) = trim(lsag(n))
            ENDIF
            WRITE(output(32:35),"(A)") 'Gas'
         ELSE
            IF(len_trim(lsas(m,n)) > 8) THEN
               lsp = lsas(m,n)
               output(5:13) = lsp(1:8)
            ELSE
               ls = (9-int(len_trim(lsas(m,n))/2))
               le = ls + len_trim(lsas(m,n))
               output(ls:le) = trim(lsas(m,n))
            ENDIF
            WRITE(output(30:36),"(A,I2)") 'Solid',m
         ENDIF
         WRITE(output(43:44),"(I2)") n
         WRITE(output(51:60),"(F9.4)") rxn%Species(ln)%MW

         IF(compare(rxn%Species(ln)%Coeff, zero)) THEN
            WRITE(output(17:26),"(F9.4)") zero
            WRITE(output(63:71),"(A)") 'Catalyst'
         ELSEIF(rxn%Species(ln)%Coeff < zero) THEN
            WRITE(output(17:26),"(F9.4)") -rxn%Species(ln)%Coeff
            WRITE(output(63:71),"(A)") 'Reactant'
         ELSE
            WRITE(output(17:26),"(F9.4)")  rxn%Species(ln)%Coeff
            WRITE(output(63:70),"(A)") 'Product'
         ENDIF
         CALL write_rs0(output, unit_flag)
         CALL write_rs0(divided, unit_flag)

      ENDDO

      CALL write_rs0(empty, unit_flag)

      IF(abort) CALL mfix_exit(mype)
      RETURN


 2000 FORMAT(2x,'|',68('-'),'|')

 2001 FORMAT(2x,'| Name: ',a)
 2002 FORMAT(2x,'| Chemical Eq: ',a)

 2003 FORMAT('  | Species  |   Stoich    |         | Species |',       &
              ' Molecular  |          |')

 2004 FORMAT('  |  Alias   |   Coeff.    |  Phase  |  Index  |',       &
              '   Weight   |   Type   |')


 2005 FORMAT(2x,'|',10('-'),'|',13('-'),'|',9('-'),'|',9('-'),'|',     &
             12('-'),'|',10('-'),'|')

 2006 FORMAT(2x,'|',10(' '),'|',13(' '),'|',9(' '),'|',9(' '),'|',     &
             12(' '),'|',10(' '),'|')


 2007 FORMAT(2x,'| Classification: ',a)

      contains

!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~!
!  Subroutine: WRITE_RS0                                               !
!                                                                      !
!  Purpose:                                                            !
!                                                                      !
!  Variables referenced: None                                          !
!                                                                      !
!  Variables modified: None                                            !
!                                                                      !
!  Local variables: None                                               !
!                                                                      !
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~!
      SUBROUTINE write_rs0(LINE, UFLAG)

      use run, only: reinitializing
      use error_manager

      IMPLICIT NONE

      CHARACTER(len=*), INTENT(IN) :: LINE
      INTEGER, INTENT(IN) :: UFLAG

      CALL init_err_msg("WRITE_RXN_SUMMARY --> WRITE_RS0")

      IF(uflag == -1)THEN
         IF(.NOT.reinitializing) THEN
            WRITE(err_msg,*) line
            CALL flush_err_msg(header=.false., footer=.false.)
         ENDIF
      ELSE
         WRITE(uflag,*) line
      ENDIF
      CALL finl_err_msg

      RETURN
      END SUBROUTINE write_rs0
      END SUBROUTINE write_rxn_summary


!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~!
!  Subroutine: checkThermoReqs                                         !
!                                                                      !
!  Purpose:                                                            !
!                                                                      !
!  Variables referenced: None                                          !
!                                                                      !
!  Variables modified: None                                            !
!                                                                      !
!  Local variables: None                                               !
!                                                                      !
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~!
      SUBROUTINE checkthermoreqs(RxN, S_g, S_s, rDB, MWg, MWs, Cpg0, Cps0)

      use error_manager
      use toleranc

      IMPLICIT NONE

! Data structure for storing reaction data.
      TYPE(reaction_block), POINTER, INTENT(INOUT) :: RxN

      CHARACTER(len=18), INTENT(IN) :: S_g(dim_n_g)
      CHARACTER(len=18), INTENT(in) :: S_s(dim_m, dim_n_s)
      LOGICAL, INTENT(inout) :: rDB(0:dim_m, dim_n_g)
      DOUBLE PRECISION, INTENT(in) :: Cpg0
      DOUBLE PRECISION, INTENT(in) :: Cps0(dim_m)
      DOUBLE PRECISION, INTENT(inout) :: MWg(dim_n_g)
      DOUBLE PRECISION, INTENT(inout) :: MWs(dim_m, dim_n_s)

      LOGICAL :: CP_FATAL
      LOGICAL :: CHECK_DATABASE

      INTEGER :: M, N, lN


      CALL init_err_msg("RXN_COM --> checkThermoReqs")

      check_database = .false.
      cp_fatal = .false.

! Verify that the molecular weights and stoichiometry are consistent and
! determine interphase mass exchanges.
      DO ln = 1, rxn%nSpecies
         m = rxn%Species(ln)%pMap
         n = rxn%Species(ln)%sMap
         IF(m == 0) THEN
            IF(cpg0 /= undefined) THEN
               cp_fatal = .true.
            ELSEIF((rxn%Calc_DH .AND. .NOT.rdb(m,n)) .OR.        &
               (mwg(n) == undefined)) THEN
               check_database = .true.
            ENDIF
         ELSE
            IF(cps0(m) /= undefined) THEN
               cp_fatal = .true.
            ELSEIF((rxn%Calc_DH .AND. .NOT.rdb(m,n)) .OR.        &
               (mws(m,n) == undefined)) THEN
               check_database = .true.
            ENDIF
         ENDIF
      ENDDO

! Report errors and messages.
      IF(cp_fatal) THEN

         WRITE(err_msg, 1100) trim(rxn%Name)
         CALL flush_err_msg(abort=.true.)

 1100 FORMAT('Error 1100: One or more phases associated with ',        &
         'reaction ',a,/'has specified constant specific heat (C_PG0/',&
         'Cps0). This is',/'not permitted for reacting phases. ',     &
         'Please correct the mfix.dat file.')

      ELSEIF(check_database) THEN

         WRITE(err_msg, 1101) trim(rxn%Name)
         CALL flush_err_msg

 1101 FORMAT('Message 1101: One or more molecular weights and/or ',    &
         'thermochemical data',/'is needed for reaction ',a,'. The ',  &
         'thermochemical database',/'will be used to gather the ',     &
         'necessary data.')

      ENDIF

      IF(check_database) THEN
         WRITE(err_msg, 1200)
         CALL flush_err_msg(footer=.false.)
      ENDIF

 1200 FORMAT('Message 1200: Searching thermochemical databases for ',&
         'species data.',/'  ')

      DO ln = 1, rxn%nSpecies
         m = rxn%Species(ln)%pMap
         n = rxn%Species(ln)%sMap
         IF(m == 0) THEN
            IF((rxn%Calc_DH .AND. .NOT.rdb(m,n)) .OR.         &
               (mwg(n) == undefined)) THEN
! Notify the user of the reason the thermochemical database is used.
! Flag that the species name is not provided.
               IF(s_g(n) == undefined_c) THEN
                  WRITE(err_msg,1000) trim(ivar('SPECIES_g',n))
                  CALL flush_err_msg(abort=.true.)
               ENDIF

! Update the log files.
               WRITE(err_msg, 3001) n, trim(s_g(n))
               CALL flush_err_msg(header=.false., footer=.false.)
! Read the database.
               CALL read_database(0, n, s_g(n), mwg(n))
! Flag variable to stating that the database was read.
               rdb(0,n) = .true.
            ENDIF
            rxn%Species(ln)%MW = mwg(n)
         ELSE
            IF((rxn%Calc_DH .AND. .NOT.rdb(m,n)) .OR.        &
               (mws(m,n) == undefined)) THEN

! Flag that the species name is not provided.
               IF(s_s(m,n) == undefined_c) THEN
                  WRITE(err_msg,1000) trim(ivar('SPECIES_s',m,n))
                  CALL flush_err_msg(abort=.true.)
               ENDIF
! Update the log files.
               WRITE(err_msg, 3001) n, trim(s_s(m,n))
               CALL flush_err_msg(header=.false., footer=.false.)
               CALL read_database(m,n,s_s(m,n),mws(m,n))
! Flag variable to stating that the database was read.
               rdb(m,n) = .true.
            ENDIF
            rxn%Species(ln)%MW = mws(m,n)
         ENDIF
      ENDDO
! Finalize the error message.
      IF(check_database) CALL flush_err_msg(header=.false.)

 3001 FORMAT(/2x,'>',i3,': Species: ',a)

      CALL finl_err_msg

      RETURN

 1000 FORMAT('Error 1000: Required input not specified: ',a,/'Please ',&
            'correct the mfix.dat file.')

      END SUBROUTINE checkthermoreqs

!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~!
!  Subroutine: checkMassBalance                                        !
!                                                                      !
!  Purpose:                                                            !
!                                                                      !
!  Variables referenced: None                                          !
!                                                                      !
!  Variables modified: None                                            !
!                                                                      !
!  Local variables: None                                               !
!                                                                      !
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~!
      SUBROUTINE checkmassbalance(CALLER, RxN, lnMT, IER)

      USE toleranc

      IMPLICIT NONE

      CHARACTER(len=*), INTENT(IN) :: CALLER

! Data structure for storing reaction data.
      TYPE(reaction_block), POINTER, INTENT(INOUT) :: RxN

      DOUBLE PRECISION, INTENT(OUT) :: lnMT(0:dim_m)
      INTEGER, INTENT(OUT) :: IER

      INTEGER M, N, lN ! Phase, Species
      DOUBLE PRECISION rSUM, pSUM
      DOUBLE PRECISION MWxStoich

      INTEGER sprCount, sprIndex

      DOUBLE PRECISION, PARAMETER :: massBalanceTol = 1.0d-3

! Initialize variables
      ier = 0
      rsum = zero
      psum = zero
      lnmt(:) = zero
      sprcount = 0

! Verify that the molecular weights and stoichiometry are consistent and
! determine interphase mass exchanges.
      DO ln = 1, rxn%nSpecies
         m = rxn%Species(ln)%pMap
         n = rxn%Species(ln)%sMap

! Multiply the molecular weight and stoichiometric coefficient.
         mwxstoich = rxn%Species(ln)%MW * rxn%Species(ln)%Coeff
         rxn%Species(ln)%MWxStoich = mwxstoich
! Calculate the net mass transfer for phase M.
!  0 : no interphase mass transfder
! >0 : gains mass from anther phase
! <0 : transfers mass to anther phase
         lnmt(m) = lnmt(m) + mwxstoich
! Calculate mass of reactants and products. Used to ensure mass balance.
         IF(mwxstoich < zero) THEN
            rsum = rsum - mwxstoich
            IF(m /= 0) THEN
               sprcount = sprcount + 1
               IF(sprcount == 1) THEN
                  sprindex = m
! Verify that there is at most one solids phase fule (reactant).
               ELSEIF( m /= sprindex) THEN
                  IF(dmp_log) THEN
                     WRITE(*,1002) trim(caller), trim(rxn%Name)
                     WRITE(unit_log,1002) trim(caller), trim(rxn%Name)
                     ier = 1
                  ENDIF
               ENDIF
            ENDIF
         ELSE
            psum = psum + mwxstoich
         ENDIF
      ENDDO
! Verify that the mass of products equals reactants: (Mass Balance)
      IF (.NOT.compare(rsum,psum)) THEN
         IF(dmp_log) THEN
            WRITE(*,1001) trim(caller), trim(rxn%Name), rsum, psum
            WRITE(unit_log,1001) trim(caller), trim(rxn%Name), rsum,psum
            ier = 1
         ENDIF
      ENDIF

      RETURN

! Error Messages
!---------------------------------------------------------------------//

 1001 FORMAT(/1x,70('*')/' From: ',a,' --> RXN_COM -->',               &
         ' checkMassBalance',/' Error 1001: Stoichiometry is not',     &
         ' consistent with molecular weights',/' for reaction ',a,'.',/&
         ' Mass of reactants: ',f12.4,/' Mass of products:  ',f12.4,/  &
         1x,70('*')/)

 1002 FORMAT(/1x,70('*')/' From: ',a,' --> RXN_COM -->',               &
         ' checkMassBalance',/' Error 1002: More than one solids',     &
         ' phase fules was detected. Unable to',/' determine solids/', &
         'solids heat of reaction unambiguously for',/' reaction ',a,  &
         '.',/1x,70('*')/)

      END SUBROUTINE checkmassbalance

!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~!
!  Subroutine: calcInterphaseTxfr                                      !
!                                                                      !
!  Purpose:                                                            !
!                                                                      !
!  Variables referenced: None                                          !
!                                                                      !
!  Variables modified: None                                            !
!                                                                      !
!  Local variables: None                                               !
!                                                                      !
!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~!
      SUBROUTINE calcinterphasetxfr(CALLER, RxN, lnMT, lEEq, lSEq, &
         lsag, lmmx, lsas)

         USE exit, only: mfix_exit
         USE toleranc

      IMPLICIT NONE

      CHARACTER(len=*), INTENT(IN) :: CALLER

! Data structure for storing reaction data.
      TYPE(reaction_block), POINTER, INTENT(INOUT) :: RxN

      DOUBLE PRECISION, INTENT(IN) :: lnMT(0:dim_m)
! Energy equation flag
      LOGICAL, INTENT(IN) :: lEEq
! Gas/Solids Species Eq Flag
      LOGICAL, INTENT(IN) :: lSEq(0:dim_m)
! Gas phase species aliases
      CHARACTER(len=32), DIMENSION(DIM_N_g), INTENT(IN) :: lSAg
! Number of solids phases
      INTEGER, INTENT(IN) :: lMMx
! Solids phase speices aliases.
      CHARACTER(len=32), DIMENSION(DIM_M, DIM_N_s), INTENT(IN) :: lSAs

      INTEGER toPhase, toPhaseCount, mCount
      INTEGER fromPhase, fromPhaseCount
      INTEGER catPhase

      INTEGER M, MM, LL
      INTEGER lM, lN

      DOUBLE PRECISION, PARAMETER :: massBalanceTol = 1.0d-3

! Initialize interphase exchange terms.
      IF(Allocated(rxn%rPhase)) rxn%rPhase(:) = zero

! If there is only one phase referenced by the reaction, there there
! should be no interphase mass transfer.
      IF(rxn%nPhases == 1) THEN
! Interphase mass transfer is set to zero. Small inconsistencies with
! molecular weights can result in a non-zero value for homogeneous
! reactions. Presumably, the mass balance check caught any major errors.
         rxn%rPhase(:) = zero
! Void interphase transfer flags.
         DO ln = 1, rxn%nSpecies
            m = rxn%Species(ln)%pMap
            rxn%Species(ln)%mXfr = m
         ENDDO
         rxn%Classification = "Homogeneous"
! This is a multiphase reaction.
      ELSE
! Initialize.
         tophasecount = 0
         fromphasecount = 0
         DO m = 0, lmmx
! Determine the number of phases with a net mass gain. Record the index
! of the last phase with a net mass gain.
            IF (lnmt(m) > massbalancetol) THEN
               tophasecount = tophasecount + 1
               tophase = m
! Determine the number of phases with a net mass loss. Record the index
! index of the last phase with a net mass loss.
            ELSEIF(lnmt(m) < -massbalancetol) THEN
               fromphasecount = fromphasecount + 1
               fromphase = m
            ENDIF
         ENDDO

! Only one phase has a net mass gain.
         IF(tophasecount == 1) THEN
! Interphase mass transfer flag.
            rxn%Classification = "Heterogeneous"
            DO m = 0, lmmx
               IF(m /= tophase) THEN
                  IF (tophase < m) THEN
                     lm = 1 + tophase + ((m-1)*m)/2
                     rxn%rPhase(lm) = -lnmt(m)
                  ELSE
                     lm = 1 + m + ((tophase-1)*tophase)/2
                     rxn%rPhase(lm) = lnmt(m)
                  ENDIF

! Verify that if one phase's species equations are solved, that the
! other phase's species equations are solved.

                  IF(abs(rxn%rPhase(lm)) > small_number) THEN
                     IF((lseq(tophase) .AND. .NOT.lseq(m)) .OR. &
                        (.NOT.lseq(tophase) .AND. lseq(m))) THEN
                        IF(dmp_log) THEN
                           WRITE(*,1001) trim(caller)
                           WRITE(unit_log,1001) trim(caller)
                           IF(lseq(m)) THEN
                              WRITE(*,1101) m, 'Solving'
                              WRITE(*,1101) tophase, 'Not Solving'
                              WRITE(unit_log,1101) m, 'Solving'
                              WRITE(unit_log,1101) tophase, &
                                 'Not Solving'
                           ELSE
                              WRITE(*,1101) tophase, 'Solving'
                              WRITE(*,1101) m, 'Not Solving'
                              WRITE(unit_log,1101) m, 'Solving'
                              WRITE(unit_log,1101) tophase, &
                                 'Not Solving'
                           ENDIF
                           WRITE(*,1000)
                           WRITE(unit_log,1000)
                        ENDIF
                        CALL write_rxn_summary(rxn, lsag(:),           &
                           lsas(:,:), .true.)
                     ENDIF
                  ENDIF
               ENDIF
            ENDDO

! Set flags for enthalpy transfer associated with mass transfer.
            IF(leeq .AND. rxn%Calc_DH) THEN
               DO ln = 1, rxn%nSpecies
                  m = rxn%Species(ln)%pMap
! The gas phase is referenced by the reaction.
                  IF(m == 0) THEN
! The gas phase is the destination phase.
                     IF(tophase == 0) THEN
! Counter for the number of solids phases transfering mass to the
! gas phase.
                        mcount = 0
! Check to see if phase M transfer mass to another solids phase.
                        DO mm = 1, lmmx
                           lm = 1 + (mm-1)*mm/2
! Mass transfer occurs between the gas and solids phase MM.
                           IF(rxn%rPhase(lm) > 0) THEN
! Indicate that phase MM receives mass from phase M.
                              rxn%Species(ln)%mXfr = mm
! The fraction of material transfered from phase 0 to phase MM.
! This variable is not currently used for gas/solids reactions.
                              rxn%Species(ln)%xXfr = zero
! Increment the number of phases the gas receives mass from.
                              mcount = mcount + 1
                           ENDIF
                        ENDDO
                        IF(mcount /= 1) THEN
                           IF(dmp_log) THEN
                              WRITE(*,1002) trim(caller), &
                                 trim(rxn%ChemEq)
                              WRITE(*,1000)
                              WRITE(unit_log,1002) trim(caller), &
                                 trim(rxn%ChemEq)
                              WRITE(unit_log,1000)
                           ENDIF
                           CALL write_rxn_summary(rxn, lsag(:), &
                              lsas(:,:), .true.)
                        ENDIF

! A solids phase is the destination phase.
                     ELSE
! Since only one phase was detected with a net mass gain and the gas
! phase was detected as a source phase, then all the gas is assigned
! to the destination phase.
                        rxn%Species(ln)%mXfr = tophase
! This variable is not used for gas/solids reactions.
                        rxn%Species(ln)%xXfr = zero
                     ENDIF
! Solids/Solids mass transfer: Enthalpy transfer from mass transfer is
! only calculated from source phase reactants.
                  ELSE
! Check to see if phase M transfer mass to another solids phase.
                     DO ll = 1, lmmx-1
                        DO mm = ll + 1, lmmx
                           IF(m /= ll .AND. m /= mm) cycle
                           lm = ll + 1 + (mm-1)*mm/2
                           IF(rxn%rPhase(lm) == zero) cycle
! Mass transfer occurs between solids phases M and MM, and phase M
! is the source phase.
                           IF( m == ll .AND. &
                              rxn%rPhase(lm) < zero) THEN
! Indicate that phase MM receives mass from phase M.
                              rxn%Species(ln)%mXfr = mm
! Calculate the fraction of material consumed from phase M is transfered
! to phase MM.
                              rxn%Species(ln)%xXfr =  &
                                 abs(lnmt(mm) / lnmt(ll))
! Mass transfer occurs between solids phases M and LL, and phase M
! is the source phase.
                           ELSEIF( m == mm .AND. &
                              rxn%rPhase(lm) > zero) THEN
! Indicate that phase LL receives mass from phase M.
                              rxn%Species(ln)%mXfr = ll
! Calculate the fraction of material consumed from phase M is transfered
! to phase LL.
                              rxn%Species(ln)%xXfr = &
                                 abs(lnmt(ll) / lnmt(mm))
                           ENDIF
                        ENDDO
                     ENDDO
                  ENDIF ! Gas or Solids phase.
               ENDDO ! Species Loop
            ENDIF ! Energy Equation
! If there is only one phase with a net mass loss, setup the array for
! interphase mass transfer.
         ELSEIF(fromphasecount == 1) THEN
            rxn%Classification = "Heterogeneous"
            DO m = 0, lmmx
               IF (m /= fromphase) THEN
                  IF(m < fromphase) THEN
                     lm = 1 + m + ((fromphase-1)*fromphase)/2
                     rxn%rPhase(lm) =  lnmt(m)
                  ELSE
                     lm = 1 + fromphase + ((m-1)*m)/2
                     rxn%rPhase(lm) = -lnmt(m)
                  ENDIF

! Verify that if one phase's species equations are solved, that the
! other phase's species equations are solved.
                  IF(abs(rxn%rPhase(lm)) > small_number) THEN
                     IF((lseq(fromphase) .AND. .NOT.lseq(m)) .OR.   &
                        (.NOT.lseq(fromphase) .AND. lseq(m))) THEN
                        IF(dmp_log) THEN
                           WRITE(*,1001) trim(caller)
                           WRITE(unit_log,1001) trim(caller)
                           IF(lseq(m)) THEN
                              WRITE(*,1101) m, 'Solving'
                              WRITE(*,1101) fromphase, 'Not Solving'
                              WRITE(unit_log,1101) m, 'Solving'
                              WRITE(unit_log,1101) fromphase, &
                                 'Not Solving'
                           ELSE
                              WRITE(*,1101) tophase, 'Solving'
                              WRITE(*,1101) m, 'Not Solving'
                              WRITE(unit_log,1101) fromphase, 'Solving'
                              WRITE(unit_log,1101) m, 'Not Solving'
                           ENDIF
                           WRITE(*,1000)
                           WRITE(unit_log,1000)
                        ENDIF
                        CALL write_rxn_summary(rxn, lsag(:),           &
                           lsas(:,:), .true.)
                     ENDIF
                  ENDIF
               ENDIF
            END DO

! Set flags for enthalpy transfer associated with mass transfer.
            IF(leeq .AND. rxn%Calc_DH) THEN
               DO ln = 1, rxn%nSpecies
                  m = rxn%Species(ln)%pMap
! Gas/solids reaction: Enthalpy transfer from mass transfer is only
! calculated from gas phase species.
                  IF(m == 0) THEN
! Gas phase is the source phase.
                     IF(fromphase == 0) THEN
! Counter for the number of solids phases transfering mass to the
! gas phase.
                        mcount = 0
! Check to see if phase M transfer mass to another solids phase.
                        DO mm = 1, lmmx
                           lm = 1 + (mm-1)*mm/2
! Mass transfer occurs between the gas and solids phases MM.
                           IF(rxn%rPhase(lm) < 0) THEN
! Indicate that phase MM receives mass from phase M.
                              rxn%Species(ln)%mXfr = mm
! The fraction of material transfered from phase 0 to phase MM.
! This variable is not currently used for gas/solids reactions.
                              rxn%Species(ln)%xXfr = zero
! Increment the number of phases the gas receives mass from.
                              mcount = mcount + 1
                           ENDIF
                        ENDDO
                        IF(mcount /=1 ) THEN
                           IF(dmp_log) THEN
                              WRITE(*,1002) trim(caller), &
                                 trim(rxn%ChemEq)
                              WRITE(*,1000)
                              WRITE(unit_log,1002) trim(caller), &
                                 trim(rxn%ChemEq)
                              WRITE(unit_log,1000)
                           ENDIF
                           CALL write_rxn_summary(rxn, lsag(:),  &
                              lsas(:,:), .true.)
                        ENDIF
                     ELSE
! There can be only one solids phase fuel. Store the phase of the
! solids phase reactant.
                        rxn%Species(ln)%mXfr = fromphase
! Mass fraction of transfered material.
! This variable is not currently used for gas/solids reactions.
                        rxn%Species(ln)%xXfr = zero
                     ENDIF
! Solids/Solids mass transfer: Enthalpy transfer from mass transfer is
! only calculated from source phase reactants.
                  ELSE
! Check to see if phase M transfer mass to another solids phase.
                     DO ll = 1, lmmx-1
                        DO mm = ll + 1, lmmx
                           IF(m /= ll .AND. m /= mm) cycle
                           lm = ll + 1 + (mm-1)*mm/2
                           IF(rxn%rPhase(lm) == zero) cycle
! Mass transfer occurs between solids phases M and MM, and phase M
! is the source phase.
                           IF( m == ll .AND. &
                              rxn%rPhase(lm) < zero) THEN
! Indicate that phase MM receives mass from phase M.
                              rxn%Species(ln)%mXfr = mm
! Calculate the fraction of material consumed from phase M is transfered
! to phase MM.
                              rxn%Species(ln)%xXfr = &
                                 abs(lnmt(mm) / lnmt(ll))
! Mass transfer occurs between solids phases M and LL, and phase M
! is the source phase.
                           ELSEIF( m == mm .AND. &
                              rxn%rPhase(lm) > zero) THEN
! Indicate that phase LL receives mass from phase M.
                              rxn%Species(ln)%mXfr = ll
! Calculate the fraction of material consumed from phase M is transfered
! to phase LL.
                              rxn%Species(ln)%xXfr = &
                                 abs(lnmt(ll) / lnmt(mm))
                           ENDIF
                        ENDDO
                     ENDDO
                  ENDIF ! Gas or Solids phase.
               ENDDO ! Species Loop
            ENDIF ! Energy Equation

! If there are no phases with a net mass gain/loss, check to see if
! the reaction is turned off.
         ELSEIF(tophasecount == 0 .AND. fromphasecount == 0) THEN
! If the reaction is active, and there is no interphase mass transfer,
! classify the reaction as catalytic.
            IF(rxn%nPhases > 0) rxn%Classification = "Catalytic"
            rxn%rPhase(:)  = zero
! Set flags for enthalpy transfer associated with mass transfer.
            IF(leeq .AND. rxn%Calc_DH) THEN

! Identify the catalyst phase.
               catphase = -1
               DO ln= 1, rxn%nSpecies
                  IF(compare(rxn%Species(ln)%Coeff,zero)) THEN
                     IF(catphase /= -1) THEN
                        IF(catphase /= rxn%Species(ln)%pMap) THEN
                           IF(dmp_log) THEN
                              WRITE(*,1002) trim(caller), &
                                 trim(rxn%Name)
                              WRITE(*,1000)
                              WRITE(unit_log,1002) trim(caller), &
                                 trim(rxn%Name)
                              WRITE(unit_log,1000)
                           ENDIF
                           CALL write_rxn_summary(rxn, lsag(:),    &
                              lsas(:,:), .true.)
                        ENDIF
                     ELSE
                        catphase = rxn%Species(ln)%pMap
                     ENDIF
                  ENDIF
               ENDDO
! Verify that a catalyst phase was found.
               IF(catphase == -1) THEN
                  IF(dmp_log) THEN
                     WRITE(*,1003) trim(caller), 'catalyst', &
                        trim(rxn%Name)
                     WRITE(*,1000)
                     WRITE(unit_log,1003) trim(caller), &
                        'catalyst', trim(rxn%Name)
                     WRITE(unit_log,1000)
                  ENDIF
                  CALL write_rxn_summary(rxn, lsag(:),                 &
                     lsas(:,:), .true.)
               ENDIF

! Identify the reactant phase.
               tophase = -1
               DO ln = 1, rxn%nSpecies
                  IF(.NOT.compare(rxn%Species(ln)%Coeff,zero)) THEN
                     IF(tophase /= -1) THEN
                        IF(tophase /= rxn%Species(ln)%pMap) THEN
                           IF(dmp_log) THEN
                              WRITE(*,1002) trim(caller), &
                                 trim(rxn%Name)
                              WRITE(*,1000)
                              WRITE(unit_log,1002) trim(caller), &
                                 trim(rxn%Name)
                              WRITE(unit_log,1000)
                           ENDIF
                           CALL write_rxn_summary(rxn, lsag(:), &
                              lsas(:,:), .true.)
                        ENDIF
                     ELSE
                        tophase = rxn%Species(ln)%pMap
                     ENDIF
                  ENDIF
               ENDDO
! Verify that a reacting phase was found.
               IF(tophase == -1) THEN
                  IF(dmp_log) THEN
                     WRITE(*,1003) trim(caller), 'reacting', &
                        trim(rxn%Name)
                     WRITE(*,1000)
                     WRITE(unit_log,1003) trim(caller), 'reacting', &
                        trim(rxn%Name)
                     WRITE(unit_log,1000)
                  ENDIF
                  CALL write_rxn_summary(rxn, lsag(:), lsas(:,:),.true.)
               ENDIF

! Something when wrong.
               IF(catphase == tophase) THEN
                  IF(dmp_log) THEN
                     WRITE(*,1004) trim(caller), trim(rxn%Name)
                     WRITE(*,1000)
                     WRITE(unit_log,1004) trim(caller),trim(rxn%Name)
                     WRITE(unit_log,1000)
                  ENDIF
                  CALL write_rxn_summary(rxn, lsag(:), lsas(:,:),.true.)
!Gas/solid catalytic reaction:
               ELSEIF(tophase == 0) THEN
                  DO ln = 1, rxn%nSpecies
                     IF(rxn%Species(ln)%pMap == 0) THEN
! Indicate that phase MM receives mass from phase M.
                        rxn%Species(ln)%mXfr = catphase
! The fraction of material transfered from phase 0 to phase MM.
! This variable is not currently used for gas/solids reactions.
                        rxn%Species(ln)%xXfr = zero
                     ENDIF
                  ENDDO
               ELSEIF(catphase == 0) THEN
                  DO ln = 1, rxn%nSpecies
                     IF(rxn%Species(ln)%pMap == 0) THEN
! Indicate that phase MM receives mass from phase M.
                        rxn%Species(ln)%mXfr = tophase
! The fraction of material transfered from phase 0 to phase MM.
! This variable is not currently used for gas/solids reactions.
                        rxn%Species(ln)%xXfr = zero
                     ENDIF
                  ENDDO
               ENDIF
            ENDIF ! Energy Equation
         ELSE
! Two or more phases have a net mass loss and two or more phases have
! a net mass gain. Therefore, the interphase mass transfer cannot be
! concluded.
            CALL write_rxn_summary(rxn, lsag(:), lsas(:,:),.false.)
            WRITE(*,1002) trim(caller), trim(rxn%ChemEq)
            WRITE(*,1000)
            WRITE(unit_log,1002) trim(caller), trim(rxn%ChemEq)
            WRITE(unit_log,1000)
            CALL mfix_exit(mype)
         ENDIF
      ENDIF

      RETURN

! Error Messages
!---------------------------------------------------------------------//

 1000 FORMAT(/' Please refer to the Readme file on the required input',&
         ' format and make',/' the necessary corrections to the data', &
         ' file.',/1x,70('*')//)

 1001 FORMAT(//1x,70('*')/' From: ',a,' --> RXN_COM -->',              &
         ' calcInterphaseTxfr',/' Error 1001: A chemical reaction or', &
         ' phase change was detected between',/' a phases solving',    &
         ' species equations and another phase not solving',/          &
         ' species equations.',/)

 1101 FORMAT(' Phase ',i2,': ',a,' species equations.')

 1002 FORMAT(//1x,70('*')/' From: ',a,' --> RXN_COM -->',              &
         ' calcInterphaseTxfr',/' Error 1002: Reaction complexity',    &
         ' exceeds implementation capabilities.',/' Unable to',        &
         ' determine unambiguously interphase heat or mass transfer.', &
         //' Reaction: ',a,//' Consider splitting the chemical',       &
         ' reaction equation into two or more',/' separate equations.',&
         ' The same reaction rate calculated in usr_rates',/' can be', &
         ' used for the multiple reactions to ensure mass')

 1003 FORMAT(//1x,70('*')/' From: ',a,' --> RXN_COM -->',              &
         ' calcInterphaseTxfr',/' Error 1003: Unable to determine ',a, &
         ' phase for catalytic reaction'/1x,a,'.')

 1004 FORMAT(//1x,70('*')/' From: ',a,' --> RXN_COM -->',              &
         ' calcInterphaseTxfr',/' Error 1004: Unable to distinguish',  &
         ' catalyst phase from reacting phase',/' for catalytic',      &
         ' reaction ',a,'.')

      END SUBROUTINE calcinterphasetxfr


END MODULE rxn_com