coeff_mod.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  MODULE: COEFF                                                       !
!  Purpose: Contains logic flags that tells the code whether to        !
!           perform the indicated type of calculation when the         !
!           value is true                                              !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      MODULE coeff

! Flags used by PHYSICAL_PROP :: (0:DIMENSION_M)
!```````````````````````````````````````````````````````````````````````
      LOGICAL, ALLOCATABLE :: density(:)  ! Density
      LOGICAL, ALLOCATABLE :: sp_heat(:)  ! Specific heat
      LOGICAL, ALLOCATABLE :: psize(:)    ! Particle diameter


! Flags used by TRANSPORT_PROP :: (0:DIMENSION_M)
!```````````````````````````````````````````````````````````````````````
      LOGICAL, ALLOCATABLE :: visc(:)      ! Viscosity
      LOGICAL, ALLOCATABLE :: cond(:)      ! Conductivity
      LOGICAL, ALLOCATABLE :: diff(:)      ! Diffusivity
      LOGICAL, ALLOCATABLE :: gran_diss(:) ! Granular energy dissipation


! Flags used by EXCHANGE :: (0:DIMENSION_M)x(0:DIMENSION_M)
!```````````````````````````````````````````````````````````````````````
      LOGICAL, ALLOCATABLE :: dragcoef(:,:) ! Drag coefficient
      LOGICAL, ALLOCATABLE :: heat_tr(:,:)  ! Heat transfer coeff


      contains

!**********************************************************************!
!  SUBROUTINE: INIT_COEFF                                              !
!                                                                      !
!  Purpose: Initialize logical flags.                                  !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE init_coeff(IER)

! Global Variables:
!-----------------------------------------------------------------------
      use param, only: dimension_m
      use param1, only: undefined
! Kinetic theory model.
      USE run, only: kt_type_enum
      USE run, only: gd_1999, gtsh_2012, ia_2005, ghd_2007
! Run-time flag for invoking DQMOM
      use run, only: call_dqmom
! Real number of solids phases (GHD theory)
      use physprop, only: smax
! Run-time flag for to solve energy equations.
      use run, only: energy_eq
! Run-time flag for to solve species equations.
      use run, only: species_eq
! Flag to recalculate gas viscosity.
      use visc_g, only: recalc_visc_g
! Run-time flag for invoking discrete element model
      use discretelement, only: discrete_element
! Run-time flag for gas/DEM coupling
      use discretelement, only: des_continuum_coupled
! Run-time flag for invoking TFM/DEM hybrid model
      use discretelement, only: des_continuum_hybrid
! Run-time flag invoking QMOM theory
      use qmom_kinetic_equation, only: qmomk
! Specified constant gas phase density (incompressible)
      use physprop, only: ro_g0
! Specified constant specific heat.
      use physprop, only: c_pg0, c_ps0
! Specified constant thermal conductivity.
      use physprop, only: k_g0, k_s0
! specified constant diffusivity
      use physprop, only: dif_g0, dif_s0
! Specified number of solids phases.
      use physprop, only: mmax
! Specified constant viscosity.
      use physprop, only: mu_g0
! Variable solids density flag.
      use run, only: solve_ros
! MMS flag
      use mms, only: use_mms
! user defined flags
      use usr_prop, only: usr_rog, usr_cpg, usr_kg, usr_mug, usr_difg
      use usr_prop, only: usr_ros, usr_cps, usr_ks, usr_mus, usr_difs
      use usr_prop, only: usr_gama, usr_fgs, usr_fss
      implicit none

! Dummy Arguments:
!-----------------------------------------------------------------------
! Error flag.
      INTEGER, intent(inout) :: IER


! Local Variables.
!-----------------------------------------------------------------------
! Invoke debug routine:
      LOGICAL, parameter :: dbg_coeffs = .false.
! Loop counter for solids phases
      INTEGER :: M

! Allocate and initialize:
!```````````````````````````````````````````````````````````````````````
      IF(.NOT.allocated(density)) allocate( density(0:dimension_m))
      IF(.NOT.allocated(sp_heat)) allocate( sp_heat(0:dimension_m))
      IF(.NOT.allocated(psize)) allocate( psize(0:dimension_m))
! Interphase heat transfer coefficient (GAMA)

      density = .false.
      sp_heat = .false.
      psize   = .false.

      IF(.NOT.allocated(visc)) allocate( visc(0:dimension_m))
      IF(.NOT.allocated(cond)) allocate( cond(0:dimension_m))
      IF(.NOT.allocated(diff)) allocate( diff(0:dimension_m))
      IF(.NOT.allocated(gran_diss)) allocate( gran_diss(0:dimension_m))

      visc = .false.
      cond = .false.
      diff = .false.
      gran_diss = .false.

      IF(.NOT.allocated(dragcoef)) &
         allocate( dragcoef(0:dimension_m,0:dimension_m))
      IF(.NOT.allocated(heat_tr)) &
         allocate( heat_tr(0:dimension_m,0:dimension_m))

      dragcoef = .false.
      heat_tr = .false.

! Coefficients for gas phase parameters.
!```````````````````````````````````````````````````````````````````````
! Compressible flow.
      if(ro_g0 == undefined .OR. usr_rog) density(0) = .true.

! Gas viscosity:
! Calc_mu_g must be invoked every iteration even if constant viscosity
! (mu_g0 /= undefined) to incorporate ishii form of governing equations
! wherein the viscosity is multiplied by the phase volume fraction.
! Alternatively, we could invoke calc_mu_g only if energy, k_epsilon,
! l_scale0 /= 0, or ishii (use recalc_visc_g)
      visc(0) = .true.

! Specific heat and thermal conductivity.
      if(energy_eq) then
         if(c_pg0 == undefined .or. usr_cpg) sp_heat(0) = .true.
         if(k_g0  == undefined .or. usr_kg) cond(0) = .true.
      endif

! Species diffusivity.
      if(species_eq(0)) then
        if (dif_g0 == undefined .or. usr_difg) diff(0) = .true.
      endif

! Interphase transfer terms.
!```````````````````````````````````````````````````````````````````````
! this needs to be mmax for ghd
       if(.NOT.qmomk .AND. .NOT.use_mms) dragcoef(0:mmax,0:mmax)=.true.

! Interphase heat transfer coefficient (GAMA)
      IF (.NOT.discrete_element .OR. des_continuum_hybrid) THEN
         if(energy_eq .AND. .NOT.use_mms) heat_tr(0:smax,0:smax)=.true.
      ENDIF

! Coefficients for solids phase parameters.
!```````````````````````````````````````````````````````````````````````
      IF (.NOT.discrete_element .OR. des_continuum_hybrid) THEN
         DO m=1,smax
! Variable solids density or user solids density
            if(solve_ros(m) .or. usr_ros(m)) density(m) = .true.
         ENDDO

! Solids viscosity.
! Calc_mu_s must be invoked every iteration even if constant viscosity
! (mu_s0 /= undefined) to incorporate ishii form of governing equations
! wherein the viscosity is multiplied by the phase volume fraction
         visc(1:smax) = .true.
! mu_s only needs to be called for ghd_2007 when m=mmax
         IF (kt_type_enum == ghd_2007) THEN
            visc(1:smax) = .false.
            visc(mmax) = .true.
         ENDIF

         do m=1,smax
! Specific heat and thermal conductivity.
            if(energy_eq) THEN
               if(c_ps0(m) == undefined .or. usr_cps(m)) sp_heat(m) = .true.
               if(k_s0(m)  == undefined .or. usr_ks(m)) cond(m) = .true.
            endif
! Species diffusivity. Generally no need to invoke this routine since
! by default solids diffusivisty is zero, however, now it is invoked
! for user options
            IF(species_eq(m)) THEN
               IF (dif_s0(m) == undefined .or. usr_difs(m)) diff(m) = .true.
            ENDIF
         enddo

! Particle-Particle Energy Dissipation
         IF (kt_type_enum == ia_2005 .OR. &
             kt_type_enum == gd_1999 .OR. &
             kt_type_enum == gtsh_2012) THEN
            gran_diss(:smax) = .true.
         ENDIF

! Particle diameter.
         if(call_dqmom) psize(1:smax)=.true.

      ENDIF   ! end if (.not.discrete_element .or des_continuum_hybrid)

      if(dbg_coeffs) CALL debug_coeff

! Invoke calc_coeff.
      IF(.NOT.discrete_element .OR. des_continuum_coupled) THEN
         CALL calc_coeff(ier, 2)

! If gas viscosity is undefined and the flag for calculating gas
! viscosity is turned off: Turn it on and make the call to calc_coeff.
! Once viscosity values have been calculated (i.e., an initial value
! is calculated), turn the flag off again so it isn't recalculated.
!         IF(MU_g0 == UNDEFINED .AND. .NOT.VISC(0)) THEN
!            VISC(0) = .TRUE.; CALL CALC_COEFF(IER, 2)
!            VISC(0) = .FALSE.
!         ELSE
!            CALL CALC_COEFF(IER, 2)
!         ENDIF
      ENDIF

      END SUBROUTINE init_coeff

!**********************************************************************!
!  SUBROUTINE: DEBUG_COEFF                                             !
!                                                                      !
!  Purpose: Dump the coefficient arrays for debugging.                 !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE debug_coeff

      use compar
      use physprop, only: mmax

      implicit none

      INTEGER :: M, MM

      if(mype /= pe_io) return

      write(*,"(/3x,'From DEBUG_COEFF:')")

      write(*,"(/3x,'Gas phase coefficients:')")
      write(*,"( 5x,'Density (RO_g):',1x,1L1)") density(0)
      write(*,"( 5x,'Specific heat (C_pg):',1x,1L1)") sp_heat(0)
      write(*,"( 5x,'Viscosity: (MU_g)',1x,1L1)") visc(0)
      write(*,"( 5x,'Thermal conductivity (K_g):',1x,1L1)") cond(0)
      write(*,"( 5x,'Species diffusivity: (DIF_G)',1x,1L1)") diff(0)


      DO m=1, mmax
         write(*,"(/3x,'Solids ',I1,' phase coefficients:')") m
         write(*,"( 5x,'Density: (RO_s)',1x,1L1)") density(m)
         write(*,"( 5x,'Specific heat (C_ps):',1x,1L1)") sp_heat(m)
         write(*,"( 5x,'Viscosity (MU_s):',1x,1L1)") visc(m)
         write(*,"( 5x,'Thermal conductivity (K_s):',1x,1L1)") cond(m)
         write(*,"( 5x,'Species diffusivity (DIF_s):',1x,1L1)") diff(m)
         write(*,"( 5x,'Gran. Dissipation (D_p):',1x,1L1)") gran_diss(m)
         write(*,"( 5x,'Diameter (D_p):',1x,1L1)") psize(m)
      ENDDO


      write(*,"(/3x,'Interphase drag:')")
      write(*,"( 5x,'ref')",advance="NO")
      DO m=0, mmax
         write(*,"(2x,I3)",advance="NO")m
      ENDDO
      write(*,"('')")

      DO m=0, mmax
         write(*,"( 5x,I3)",advance="NO") m
         DO mm=0, mmax
            write(*,"(2x,L3)",advance="NO")dragcoef(m, mm)
         ENDDO
         write(*,"('')")
      ENDDO

      write(*,"(/3x,'Interphase heat transfer:')")
      write(*,"( 5x,'ref')",advance="NO")
      DO m=0, mmax
         write(*,"(2x,I3)",advance="NO")m
      ENDDO
      write(*,"('')")
      DO m=0, mmax
         write(*,"( 5x,I3)",advance="NO") m
         DO mm=0, mmax
            write(*,"(2x,L3)",advance="NO")heat_tr(m, mm)
         ENDDO
         write(*,"('')")
      ENDDO

      write(*,"(/3x,'DEBUG_COEFF - Exit',3/)")

      END SUBROUTINE debug_coeff

      END MODULE coeff