calc_coeff.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      !
!  Subroutine: CALC_COEFF_ALL                                          !
!  Purpose: This routine directs the calculation of all physical and   !
!           transport properties, exchange rates, and reaction rates.  !
!                                                                      !
!  Author: M. Syamlal                                 Date: 25-AUG-05  !
!  Reviewer:                                          Date:            !
!                                                                      !
!  Literature/Document References:                                     !
!                                                                      !
!  Variables referenced:                                               !
!  Variables modified:                                                 !
!  Local variables:                                                    !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE calc_coeff_all(FLAG, IER)

! Global variables:
!-----------------------------------------------------------------------
! Double precision: 1.0d0
      use param1, only: one
! Under relaxation factor for gas-solids drag coefficient
      use ur_facs, only: ur_f_gs
! Under relaxation factor solid conductivity coefficient for IA theory
      use ur_facs, only: ur_kth_sml
! Flag for DES coupled simulation
      use discretelement, only: des_continuum_coupled
! Flag for explcit coupling between the fluid and particles.
      use discretelement, only: des_explicitly_coupled

      implicit none

! Dummy arguments
!-----------------------------------------------------------------------
! FLAG = 0, overwrite the coeff arrays, (e.g. start of a time step)
! FLAG = 1, do not overwrite
      INTEGER, intent(in) :: FLAG
! Error index
      INTEGER, intent(inout) :: IER

! Local variables
!-----------------------------------------------
! Under relaxation factor for gas-solids drag coefficient
      DOUBLE PRECISION :: loc_UR_F_gs ! Local copy
! Under relaxation factor solid conductivity coefficient for IA theory
      DOUBLE PRECISION :: loc_UR_kth_sml ! Local copy

!-----------------------------------------------------------------------

! 1) Backup user-defined coefficient relaxation factors.
! 2) Set user-defined coefficient relaxation factors to 1.
! Note that 'FLAG' is hard coded to 0 in time march and reset_new.
      IF(flag == 0) THEN
        loc_ur_f_gs = ur_f_gs;          ur_f_gs = one
        loc_ur_kth_sml = ur_kth_sml;    ur_kth_sml = one
      ENDIF

! Calculate all physical properties, transport properties, and exchange
! rates.
      CALL calc_coeff(ier, 2)

! Calculate reaction rates and interphase mass transfer.
      CALL calc_rrate(ier)

! Restore all coefficient underrelaxation factors to original values.
      IF(flag == 0) THEN
        ur_f_gs = loc_ur_f_gs
        ur_kth_sml = loc_ur_kth_sml
      ENDIF

! DES interaction for explictly coupled simulations
      IF(des_continuum_coupled .AND. des_explicitly_coupled) &
         CALL calc_des_2fluid

      RETURN
      END SUBROUTINE calc_coeff_all


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: CALC_COEFF                                              !
!  Purpose: This routine directs the calculation of all physical and   !
!           transport properties, and exchange rates.                  !
!                                                                      !
!  Author: M. Syamlal                                 Date: 25-AUG-05  !
!  Reviewer:                                          Date:            !
!                                                                      !
!                                                                      !
!                                                                      !
!  Literature/Document References:                                     !
!                                                                      !
!  Variables referenced:                                               !
!  Variables modified:                                                 !
!  Local variables:                                                    !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE calc_coeff(IER, pLevel)

! Flag for DES coupled simulation
      use discretelement, only: des_continuum_coupled
! Flag for explcit coupling between the fluid and particles.
      use discretelement, only: des_explicitly_coupled

      implicit none

! Dummy arguments
!-----------------------------------------------------------------------
! Error index
      INTEGER, intent(inout) :: IER
! Level to calculate physical properties.
! 0) Only density
! 1) Everything but density
! 2) All physical properties
      INTEGER, intent(in) :: pLevel
!-----------------------------------------------------------------------

! Calculate physical properties: (density, specific heat, diameter)
      CALL physical_prop(ier, plevel)

! Calculate transport properties: (conductivity, diffusivity, ect)
      CALL transport_prop(ier)

! Calculate interphase coeffs: (momentum and energy)
      CALL exchange(ier)

! Calculate DES coupled quantities.
      IF(des_continuum_coupled .AND. .NOT.des_explicitly_coupled) &
         CALL calc_des_2fluid

      RETURN
      END SUBROUTINE calc_coeff

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Subroutine: CALC_RRATE                                              C
!  Purpose: if rrate then calculate reaction rates and interphase      C
!           mass transfer. if present, calculate discrete reactions    C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
      SUBROUTINE calc_rrate(IER)

!-----------------------------------------------
! Modules
!-----------------------------------------------
      USE discretelement, only : discrete_element
      USE rxns,only : rrate, use_rrates
      use run, only: any_species_eq

      use error_manager

      IMPLICIT NONE
!-----------------------------------------------
! Dummy arguments
!-----------------------------------------------
!-----------------------------------------------
! Local variables
!-----------------------------------------------
! Error index
      INTEGER, INTENT(INOUT) :: IER

!-----------------------------------------------

! Calculate reaction rates and interphase mass transfer
      IF(rrate) THEN
! Legacy hook: Calculate reactions from rrates.f.
         IF(use_rrates) THEN
            CALL rrates (ier)
            IF(ier .EQ. 1) THEN
               CALL init_err_msg('CALC_RRATE')
               WRITE(err_msg, 1000)
               CALL flush_err_msg(abort=.true.)
            ENDIF
         ELSE
            CALL rrates0 (ier)
         ENDIF

! DES Chemical reactions
         IF(any_species_eq .AND. discrete_element) &
            CALL des_2fluid_rxns
      ENDIF

      RETURN

 1000 FORMAT('Species balance equations are being solved; but chemical',/, &
         ' reactions are not specified in mfix.dat or in rrates.f.',/,  &
         ' Copy the file mfix/model/rrates.f into the run directory ',/, &
         ' and remove the initial section that returns IER=1.')

      END SUBROUTINE calc_rrate


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: CALC_TRD_AND_TAU                                        !
!  Purpose: Calculate various terms in the gas and solids phase        !
!  stress tensor as indicated below                                    !
!                                                                      !
!  Author: M. Syamlal                                 Date: 25-AUG-05  !
!                                                                      !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE calc_trd_and_tau()

      USE run, only: jackson
! Stress tensor trace.
      USE visc_g, only : trd_g
      USE visc_s, only : trd_s
! Stress tensor cross terms.
      USE tau_g, only : tau_u_g, tau_v_g, tau_w_g
      USE tau_g, only : ctau_u_g, ctau_v_g, ctau_w_g
      USE tau_s, only : tau_u_s, tau_v_s, tau_w_s
! Runtime flag for DEM model.
      USE discretelement, only: discrete_element
! Runtime flag for TFM-DEM hybrid model.
      USE discretelement, only: des_continuum_hybrid

      USE param1, only: zero
      implicit none

!-----------------------------------------------------------------------

! Calculate the trace of the stress tensor (gas phase; m=0)
      CALL calc_trd_g (trd_g)

! Calculate the cross terms of the stress tensor (gas phase; m=0)
      CALL calc_tau_u_g (tau_u_g, ctau_u_g)
      CALL calc_tau_v_g (tau_v_g, ctau_v_g)
      CALL calc_tau_w_g (tau_w_g, ctau_w_g)

      IF (.NOT. jackson) THEN
         ctau_u_g = zero
         ctau_v_g = zero
         ctau_w_g = zero
      ENDIF

! Bypass the following calculations if there are no TFM solids.
      IF (.NOT.discrete_element .OR. des_continuum_hybrid) THEN
! Calculate the cross terms of the stress tensor (solids phases; m>0)
         CALL calc_trd_s (trd_s)
! Calculate the trace of the stress tensor (solids phases; m>0)
         CALL calc_tau_u_s (tau_u_s)
         CALL calc_tau_v_s (tau_v_s)
         CALL calc_tau_w_s (tau_w_s)
      ENDIF

      RETURN
      END SUBROUTINE calc_trd_and_tau