exchange.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  SUBROUTINE: EXCHANGE                                                C
!  Purpose: Calls routines to drive calculations of the interphase     C
!           momentum, and energy exchange coefficients/terms           C
!           if directed to do so by the corresponding flags            C
!                                                                      C
!  Author: M. Syamlal                                 Date: 25-APR-96  C
!                                                                      C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
      SUBROUTINE exchange(IER)

! Global Variables
!---------------------------------------------------------------------//
! Flags for calculating drag coefficient.
      use coeff, only: dragcoef
! Flags for calculating heat transfer coefficient.
      use coeff, only: heat_tr

      use param1, only: zero
      use physprop, only: smax, ro_g0
      use run, only: granular_energy
      use run, only: kt_type_enum, ia_2005

      use discretelement, only: des_explicitly_coupled
      use discretelement, only: des_continuum_coupled
      use discretelement, only: des_continuum_hybrid


      implicit none

! Dummy arguments
!---------------------------------------------------------------------//
      INTEGER, INTENT(INOUT) :: IER ! Error index

! Local variables
!---------------------------------------------------------------------//
! loop counter
      INTEGER :: M, L
!---------------------------------------------------------------------//

! calculate gas-solids drag based on relatively velocity differences
      IF (.NOT.des_continuum_coupled .OR. des_continuum_hybrid) THEN
         DO m = 1, smax
            IF (dragcoef(0,m) .AND. ro_g0/=zero) CALL drag_gs(m, ier)
         ENDDO

! calculate solilds-solids drag based on relative velocity differences
         DO m = 1, smax
            DO l = 1, m - 1
               IF (dragcoef(l,m)) CALL drag_ss (l, m, ier)
            ENDDO
         ENDDO
      ENDIF

! Calculate additional interphase interaction coefficients (between
! continuum solids phases)
      IF (granular_energy) THEN
         SELECT CASE(kt_type_enum)
            CASE(ia_2005)
               DO m=1,smax
                  DO l=1,smax
                     CALL coll_momentum_coeff_ia(l, m)
                  ENDDO
               ENDDO
            CASE DEFAULT
         END SELECT
      ENDIF

! Calculate interphase heat transfer coefficients
      DO m=1,smax
         IF(heat_tr(0,m)) CALL calc_gama(m)
      ENDDO

      return
      END SUBROUTINE exchange