calc_des_2fluid.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: CALC_DES_2FLUID                                         !
!                                                                      !
!  Purpose: This subroutine is only called from the CONTINUUM side. It !
!  is only called at the start of each time step for explicitly coupled!
!  cases. Otherwise, it called every iteration.                        !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE calc_des_2fluid

      use discretelement, only: des_continuum_coupled
      use discretelement, only: des_continuum_hybrid
      use discretelement, only: des_explicitly_coupled

      use particle_filter, only: des_interp_scheme_enum
      use particle_filter, only: des_interp_garg

      use discretelement, only: des_continuum_coupled
      use particle_filter, only: des_diffuse_mean_fields

! Contribution to gas momentum equation due to drag
      use discretelement, only: drag_bm
! Scalar cell center total drag force
      use discretelement, only: f_gds
! Flag for 3D simulatoins.
      use geometry, only: do_k
      use run, only: any_species_eq

      use des_thermo, only: calc_conv_des
      use rxns, only: rrate

      IMPLICIT NONE

      IF(.NOT.des_continuum_coupled) RETURN

      IF(des_explicitly_coupled) THEN
! Bin particles to the fluid grid.
         CALL particles_in_cell
! Calculate interpolation weights
         CALL calc_interp_weights
! Calculate mean fields (EPg).
         CALL comp_mean_fields

! Calculate gas phase source terms: gas-solids heat transfer
         IF(calc_conv_des) CALL conv_gs_gas1
! Calculate gas phase source terms: gas-solids mass transfer
         IF(rrate) CALL rxns_gs_gas1
      ENDIF

! Calculate gas phase source terms: gas-solids drag force.
      SELECT CASE(des_interp_scheme_enum)
      CASE(des_interp_garg) ; CALL drag_gs_gas0
      CASE DEFAULT; CALL drag_gs_gas1
      END SELECT

! Calculate solids phase source terms: solids-solids drag force.
      IF(des_continuum_hybrid) THEN
         SELECT CASE(des_interp_scheme_enum)
         CASE DEFAULT; CALL drag_ss_tfm_noninterp
         END SELECT
      ENDIF

! Apply the diffusion filter.
      IF(des_diffuse_mean_fields) THEN
         CALL diffuse_mean_field(f_gds,'F_GDS')
         CALL diffuse_mean_field(drag_bm(:,1),'DRAG_BM(1)')
         CALL diffuse_mean_field(drag_bm(:,2),'DRAG_BM(2)')
         IF(do_k) CALL diffuse_mean_field(drag_bm(:,3),'DRAG_BM(3)')
!         IF(ENERGY_EQ) THEN
!            CALL DIFFUSE_MEAN_FIELD(CONV_Sc,'CONV_Sc')
!            CALL DIFFUSE_MEAN_FIELD(CONV_Sp,'CONV_Sp')
!         ENDIF
      ENDIF

      RETURN
      END SUBROUTINE calc_des_2fluid


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!  Subroutine: DES_2FLUID_CONV                                         !
!  Author: J.Musser                                   Date: 15-Jan-11  !
!                                                                      !
!  Purpose: This routine is called from the continuum phase and        !
!  calculates the source term from the particles to the fluid.         !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE  des_2fluid_conv(S_P, S_C)

      Use discretelement, only: des_explicitly_coupled
      Use des_thermo, only: conv_sp, conv_sc
      USE geometry, only: flag
      Use param, only: dimension_3

      use run, only: odt
! Flag: Gas sees the effect of particles in gas/solids flows.
      use discretelement, only: des_oneway_coupled

      IMPLICIT NONE

! Passed Variables
!---------------------------------------------------------------------//
! Source term on LHS
      DOUBLE PRECISION, INTENT(INOUT) :: S_P(dimension_3)
! Source term on RHS
      DOUBLE PRECISION, INTENT(INOUT) :: S_C(dimension_3)

! Local variables
!---------------------------------------------------------------------//
      IF(des_oneway_coupled) RETURN

      IF(des_explicitly_coupled) THEN
         WHERE(flag==1)
            s_p = s_p + conv_sp ! GAMMA
            s_c = s_c + conv_sc ! GAMMA*Tp
         END WHERE

! Redistribute the energy over the fluid time step. Note that by the
! time this routine is called, S_C and S_P have already been multiplied
! by the fluid cell volume. Thus, the mapping should result in units
! of energy per time.
      ELSE
         WHERE(flag==1) &
            s_c = s_c + odt*conv_sc ! GAMMA*(Tg-Ts)
      ENDIF

      RETURN
      END SUBROUTINE  des_2fluid_conv


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!  Subroutine: DES_2FLUID_RXNS                                         !
!  Author: J.Musser                                   Date: 15-Jan-11  !
!                                                                      !
!  Purpose: This routine is called from the continuum phase and        !
!  calculates the source term from the particles to the fluid.         !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE  des_2fluid_rxns

      Use discretelement, only: des_explicitly_coupled
      Use des_thermo, only: conv_sp, conv_sc
      USE geometry, only: flag
      Use param, only: dimension_3
      USE rxns, only : rrate
      USE rxns
      USE des_rxns
      USE energy, only: hor_g
      use fldvar, only: x_g
      use run, only: dt
      use param1, only: zero, small_number, one
      use stiff_chem, only: stiff_chemistry
      use compar, only: ijkstart3, ijkend3
      use geometry, only: vol
      use functions, only: fluid_at
      use toleranc, only: zero_x_gs
! Flag: Gas sees the effect of particles in gas/solids flows.
      use discretelement, only: des_oneway_coupled
! Flag to use stiff chemistry solver
      use stiff_chem, only: stiff_chemistry

      IMPLICIT NONE

! Passed Variables
!---------------------------------------------------------------------//
! Source term on LHS
!      DOUBLE PRECISION, INTENT(INOUT) :: S_P(DIMENSION_3)
! Source term on RHS
!      DOUBLE PRECISION, INTENT(INOUT) :: S_C(DIMENSION_3)

! Local variables
!---------------------------------------------------------------------//
      INTEGER :: IJK
      DOUBLE PRECISION :: toTFM, lDT

      IF(des_oneway_coupled) RETURN
      IF(stiff_chemistry) RETURN

! For DEM simulations that do not have a homogeneous gas phase reaction,
! the gas phase arrays need to be cleared.
      IF(.NOT.rrate .OR. stiff_chemistry) THEN
         sum_r_g = zero
         hor_g = zero
         r_gp = zero
         rox_gc = zero
         r_phase = zero
      ENDIF

! Redistribute the energy over the fluid time step. Note that by the
! time this routine is called, S_C and S_P have already been multiplied
! by the fluid cell volume. Thus, the mapping should result in units
! of energy per time.
      ldt = merge(one, dt, des_explicitly_coupled)

      DO ijk=ijkstart3,ijkend3
      IF(.NOT.fluid_at(ijk)) cycle
         totfm = one/(ldt * vol(ijk))
         r_gp(ijk,:) = r_gp(ijk,:) + des_r_gp(ijk,:)*totfm
         r_phase(ijk,:) = r_phase(ijk,:) + des_r_phase(ijk,:)*totfm
         sum_r_g(ijk) = sum_r_g(ijk) + des_sum_r_g(ijk)*totfm
         hor_g(ijk) = hor_g(ijk) + des_hor_g(ijk)*totfm
         WHERE(x_g(ijk,:) > zero_x_gs) rox_gc(ijk,:) = &
            rox_gc(ijk,:)+des_r_gc(ijk,:)*totfm/x_g(ijk,:)
      ENDDO

      RETURN
      END SUBROUTINE  des_2fluid_rxns