check_bc_outflow.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
! Subroutine: CHECK_BC_OUTFLOW                                         !
! Author: J.Musser                                    Date: 01-Mar-14  !
!                                                                      !
! Purpose: Provided a detailed error message concerning specification  !
! of bc_ep_g + bc_rop_s at a outflow boundary (and pressure inflow)    !
!                                                                      !
!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
      SUBROUTINE check_bc_outflow(M_TOT, BCV)

! Modules
! --------------------------------------------------------------------//
      use bc, only: bc_ep_g, bc_rop_s
      use param1, only: one, undefined, zero
      use physprop, only: ro_s0
      use run, only: solids_model
      use toleranc, only: compare
      use error_manager

      IMPLICIT NONE

! Dummy arguments
! --------------------------------------------------------------------//
! loop/variable indices
      INTEGER, INTENT(in) :: BCV
      INTEGER, INTENT(in) :: M_TOT

! Local variables
! --------------------------------------------------------------------//
      INTEGER :: M
      DOUBLE PRECISION :: SUM_EP
      LOGICAL :: FLAG_WARNING

      flag_warning = .true.
      CALL init_err_msg("CHECK_BC_OUTFLOW")

! if bc_ep_g is defined at the outflow boundary, then the sum of ep_g
! and ep_s at the boundary may not equal one given the code in the
! subroutine set_outflow (see code for details).
! therefore if bc_ep_g and/or bc_rop_s are defined, perform possible
! data consistency checks and, when appropriate, provide the user with
! a warning about their chosen settings.

      IF (bc_ep_g(bcv) /= undefined) THEN

         sum_ep = bc_ep_g(bcv)
         DO m = 1, m_tot

            IF(solids_model(m) /= 'TFM' .AND. flag_warning) THEN
               WRITE(err_msg, 1101) trim(ivar('BC_EP_g',bcv))
               CALL flush_err_msg
               flag_warning = .false.
            ENDIF

            IF(bc_rop_s(bcv,m) == undefined) THEN

               IF(bc_ep_g(bcv) == one) THEN
! what does it mean to force the bulk density to zero at the
! boundary? (does this value matter anyway?)
                  bc_rop_s(bcv,m) = zero
               ELSEIF(m_tot == 1 ) THEN
                  bc_rop_s(bcv,m) = (one - bc_ep_g(bcv))*ro_s0(m)
               ELSE
! bc_ep_g is defined but some bc_rop_s(m) are undefined.
! in this case, ep_p in the outflow boundary will be based on the user
! defined value of bc_ep_g, while rop_s would become based on the
! value in the adjacent fluid cell. consequently, no check ensures
! the result is consistent with a requirement for ep_g+ep_s=1.
                  WRITE(err_msg, 1102) trim(ivar('BC_EP_g',bcv))
                  CALL flush_err_msg(abort=.true.)
 1102 FORMAT('Warning 1102: Volume fraction may not sum to one when ',/&
         a,' is defined.')
               ENDIF
            ENDIF  ! end if(bc_rop_s(bcv,m) == undefined)

! by this point bc_rop_s should either be defined or mfix exited
! therefore we can check that sum of void fraction and solids volume
! fractions
            sum_ep = sum_ep + bc_rop_s(bcv,m)/ro_s0(m)
        ENDDO

! now verify that the volume fractions sum to one.
        IF(.NOT.compare(sum_ep,one)) THEN
           WRITE(err_msg,1103) bcv, trim(ival(sum_ep))
           CALL flush_err_msg(abort=.true.)
       ENDIF

! bc_ep_g is not defined but check if any bc_rop_s are defined
      ELSE

         sum_ep = zero
         DO m = 1, m_tot
            IF(bc_rop_s(bcv,m) /= undefined) THEN
               IF(solids_model(m) /= 'TFM') THEN
                  WRITE(err_msg, 1101) trim(ivar('BC_ROP_s',bcv,m))
                  CALL flush_err_msg
               ENDIF
               sum_ep = sum_ep + bc_rop_s(bcv,m)/ro_s0(m)
            ENDIF
         ENDDO

! verify that the sum of any specified volume fractions is not greater
! than one
         IF(sum_ep > one) THEN
            WRITE(err_msg,1103) bcv, trim(ival(sum_ep))
            CALL flush_err_msg(abort=.true.)
         ENDIF

      ENDIF

      CALL finl_err_msg

      RETURN

 1101 FORMAT('Warning 1101: ',a,' should not be specified for ', &
         'outflow BCs',/'with DEM/PIC runs except for a mass outflow ',&
         'boundary with specified ',/ 'flow rate(s). In this case ',&
         'volume fraction data is used for ',/ 'conversion to ',&
         'velocity(s). However, the solids volume fraction data ',/&
         'is effectively disregarded and it is the solids velocity ',&
         'that is ',/'used to direct any solids at the boundary.')

 1103 FORMAT('Error 1103: Illegal boundary condition region: ',i3,'. ',&
         'Sum of volume',/'fractions does NOT equal ONE. (SUM = ',a,   &
         ')',/'Please correct the mfix.dat file.')

      END SUBROUTINE check_bc_outflow


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
! Subroutine: CHECK_BC_P_OUTFLOW                                       !
! Author: J.Musser                                    Date: 01-Mar-14  !
!                                                                      !
! Purpose: Provided a detailed error message on bc                     !
!                                                                      !
!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
      SUBROUTINE check_bc_p_outflow(M_TOT, BCV)

! Modules
! --------------------------------------------------------------------//
      USE param1, only: undefined
      USE param1, only: zero
      use physprop, only: ro_g0
      use bc, only: bc_p_g
      use error_manager
      IMPLICIT NONE

! Dummy arguments
! --------------------------------------------------------------------//
! loop/variable indices
      INTEGER, INTENT(in) :: BCV
      INTEGER, INTENT(in) :: M_TOT
! --------------------------------------------------------------------//

      CALL init_err_msg("CHECK_BC_P_OUTFLOW")

      IF (bc_p_g(bcv) == undefined) THEN
         WRITE(err_msg,1000) trim(ivar('BC_P_g',bcv))
         CALL flush_err_msg(abort=.true.)

      ELSEIF (bc_p_g(bcv)<=zero .AND. ro_g0==undefined) THEN
         WRITE(err_msg, 1100) bcv, trim(ival(bc_p_g(bcv)))
         CALL flush_err_msg(abort=.true.)
      ENDIF

 1100 FORMAT('Error 1100: Pressure must be greater than zero for ',    &
         'compressible flow',/3x,'BC_P_g(',i3,') = ',a,/'Please ',     &
         'correct the mfix.dat file.')

! Clean up and return.
      CALL finl_err_msg

      RETURN

 1000 FORMAT('Error 1000: Required input not specified: ',a,/'Please ',&
         'correct the mfix.dat file.')

      END SUBROUTINE check_bc_p_outflow


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
! Subroutine: CHECK_BC_MASS_OUTFLOW                                    !
! Author: J.Musser                                    Date: 01-Mar-14  !
!                                                                      !
! Purpose: Provided a detailed error message when the sum of volume    !
!                                                                      !
! Comments:                                                            !
!     The velocities at the outflow face are fixed and the momentum    !
!     equations are not solved in the outflow cells. Since the flow    !
!     is out of the domain none of the other scalars should need to    !
!     be specified (e.g., mass fractions, void fraction, etc.,).       !
!     Such values will become defined according to their adjacent      !
!     fluid cell                                                       !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_bc_mass_outflow(M_TOT, BCV)

! Modules
! --------------------------------------------------------------------//
      use bc, only: bc_plane
      use bc, only: bc_dt_0, bc_massflow_g, bc_volflow_g
      use bc, only: bc_massflow_s, bc_volflow_s
      use bc, only: bc_ep_g, bc_rop_s
      use bc, only: bc_p_g, bc_t_g
      use bc, only: bc_u_g, bc_v_g, bc_w_g
      use physprop, only: ro_g0
      use param1, only: undefined, zero
      use error_manager
      IMPLICIT NONE

! Dummy arguments
! --------------------------------------------------------------------//
! loop/variable indices
      INTEGER, intent(in) :: BCV
      INTEGER, intent(in) :: M_TOT
! Local variables
! --------------------------------------------------------------------//
      INTEGER :: M


      CALL init_err_msg("CHECK_BC_MASS_OUTFLOW")

      IF(bc_dt_0(bcv) == undefined) THEN
         WRITE(err_msg, 1000) trim(ivar('BC_DT_0',bcv))
         CALL flush_err_msg(abort=.true.)
      ENDIF

      IF(bc_massflow_g(bcv) /= undefined .OR. &
         bc_volflow_g(bcv) /= undefined) THEN
         IF (bc_ep_g(bcv) == undefined) THEN
            WRITE(err_msg,1101) trim(ivar('BC_EP_G',bcv))
            CALL flush_err_msg(abort=.true.)
         ENDIF
 1101 FORMAT('Error 1101: Invalid mass outflow boundary condition: ', /&
         'BC_MASSFLOW_G and/or BC_VOLFLOW_G are DEFINED but ',&
         a,' is not ',/'Please correct the mfix.dat file.')
      ENDIF

      DO m = 1, m_tot
         IF(bc_massflow_s(bcv,m) /= undefined .OR. &
            bc_volflow_s(bcv,m) /= undefined) THEN
            WRITE(err_msg,1102) trim(ivar('BC_MASSFLOW_S',bcv,m)), &
               trim(ivar('BC_VOLFLOW_S',bcv,m))
 1102 FORMAT('Warning 1102: ', a,' and/or ', a,' have been defined',/&
         'at a mass outflow boundary. A specified solids flow ',&
         'rate may not be ',/'physically achievable depending on the ',&
         'system and simulation ',/'setup.')

             IF (bc_rop_s(bcv,m) == undefined) THEN
                WRITE(err_msg,1103) trim(ivar('BC_ROP_S',bcv,m))
                CALL flush_err_msg(abort=.true.)
             ENDIF
 1103 FORMAT('Error 1103: Invalid mass outflow boundary condition: ', /&
         'BC_MASSFLOW_S and/or BC_VOLFLOW_S are DEFINED but ',&
         a,' is not ',/'Please correct the mfix.dat file.')

         ENDIF
      ENDDO

! This check probably needs changed.
      IF(ro_g0 == undefined .AND. (bc_p_g(bcv) == undefined .OR.       &
         bc_t_g(bcv) == undefined) .AND.bc_massflow_g(bcv) /= zero) THEN

         IF(bc_plane(bcv)=='W' .OR. bc_plane(bcv)=='E') THEN
            IF(bc_u_g(bcv) /= zero) THEN
               WRITE(err_msg, 1100) bcv, 'BC_U_g'
               CALL flush_err_msg(abort=.true.)
            ENDIF
         ELSEIF(bc_plane(bcv)=='N' .OR. bc_plane(bcv)=='S') THEN
            IF(bc_v_g(bcv) /= zero) THEN
               WRITE(err_msg, 1100) bcv, 'BC_V_g'
               CALL flush_err_msg(abort=.true.)
            ENDIF
         ELSEIF (bc_plane(bcv)=='T' .OR. bc_plane(bcv)=='B') THEN
            IF(bc_w_g(bcv) /= zero) THEN
               WRITE(err_msg, 1100)  bcv, 'BC_W_g'
               CALL flush_err_msg(abort=.true.)
            ENDIF
         ENDIF
      ENDIF   ! end if/else (ro_g0 /=undefined)

 1100 FORMAT('Error 1100: Invalid mass outflow boundary condition: ',  &
         i3,/'RO_g0, BC_P_g, and BC_T_g are UNDEFINED and ',a,' is ',  &
         'non-zero',/'Please correct the mfix.dat file.')


      CALL finl_err_msg

      RETURN

 1000 FORMAT('Error 1000: Required input not specified: ',a,/'Please ',&
         'correct the mfix.dat file.')

      END SUBROUTINE check_bc_mass_outflow