adjust_eps.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Subroutine: ADJUST_EPS                                              C
!  Purpose: Eliminate the solids phases that occupy only very small    C
!           fractions of the computational cell volume                 C
!                                                                      C
!  Author: M. Syamlal                                 Date: 28-JAN-92  C
!  Reviewer: P. Nicoletti, W. Rogers, S. Venkatesan   Date: 29-JAN-92  C
!                                                                      C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
      SUBROUTINE adjust_eps

!-----------------------------------------------
! Modules
!-----------------------------------------------
      USE param1, only: zero
! minimum value of solids volume fraction tracked
      USE toleranc, only: zero_ep_s
! x,y,z-components of solids velocity
      USE fldvar, only: u_s, v_s, w_s
! gas void fracition, bulk density and density
      USE fldvar, only: ep_g, rop_g, ro_g
! solids phase particle bulk density and material density
      USE fldvar, only: rop_s, ro_s
! kinetic theories
      USE run, only: kt_type_enum
      USE run, only: ghd_2007
! number of solids phases
      USE physprop, only: mmax, smax

! needed for function.inc and other quantities
      USE geometry
      USE indices
      USE compar
! for sendrecv calls
      USE sendrecv
      USE functions
      IMPLICIT NONE
!-----------------------------------------------
! Local variables
!-----------------------------------------------
! Indices
      INTEGER :: I, J, K, IJK
! Solids phase
      INTEGER :: M
! Sum of (very small) solids volume fractions that are set to zero
      DOUBLE PRECISION :: EPSUM
! Sum of solids volume fractions
      DOUBLE PRECISION :: epsMix, epSolid
!-----------------------------------------------


      DO k = kstart1, kend1
         DO j = jstart1, jend1
            DO i = istart1, iend1

               IF (dead_cell_at(i,j,k)) cycle  ! skip dead cells

               ijk = funijk(i,j,k)
               IF (fluid_at(ijk)) THEN
! initialize
                  epsum = zero
                  epsmix = zero
                  DO m = 1, smax
! why not use function ep_s?
                     epsolid = rop_s(ijk,m)/ro_s(ijk,m)
                     epsmix = epsmix +  epsolid

                     IF (epsolid < zero_ep_s) THEN
! Remove solids in very small quantities and set solids velocity to zero
! if there is outflow from the present cell.
                        epsum = epsum + epsolid

                        IF(kt_type_enum == ghd_2007) &
                           rop_s(ijk,mmax) = rop_s(ijk,mmax) - rop_s(ijk,m)

                        rop_s(ijk,m) = zero
                        u_s(ijk,m) = min(u_s(ijk,m),zero)
                        v_s(ijk,m) = min(v_s(ijk,m),zero)
                        w_s(ijk,m) = min(w_s(ijk,m),zero)
                        u_s(im_of(ijk),m) = max(u_s(im_of(ijk),m),zero)
                        v_s(jm_of(ijk),m) = max(v_s(jm_of(ijk),m),zero)
                        w_s(km_of(ijk),m) = max(w_s(km_of(ijk),m),zero)
                     ENDIF
                  ENDDO

                  epsmix = epsmix - epsum
                  IF(kt_type_enum == ghd_2007 .AND. epsmix < zero_ep_s) THEN
                    u_s(ijk,mmax) = min(u_s(ijk,mmax),zero)
                    v_s(ijk,mmax) = min(v_s(ijk,mmax),zero)
                    w_s(ijk,mmax) = min(w_s(ijk,mmax),zero)
                    u_s(im_of(ijk),mmax) = max(u_s(im_of(ijk),mmax),zero)
                    v_s(jm_of(ijk),mmax) = max(v_s(jm_of(ijk),mmax),zero)
                    w_s(km_of(ijk),mmax) = max(w_s(km_of(ijk),mmax),zero)
                  ENDIF

                  ep_g(ijk) = ep_g(ijk) + epsum
                  rop_g(ijk) = ro_g(ijk)*ep_g(ijk)
               ENDIF
            ENDDO
         ENDDO
      ENDDO

! Communicate field variables calculated in the do i,j,k loop
      call send_recv(rop_s,2)
      call send_recv(u_s,2)
      call send_recv(v_s,2)
      call send_recv(w_s,2)
      call send_recv(ep_g,2)
      call send_recv(rop_g,2)

      RETURN
      END SUBROUTINE adjust_eps