check_bc_walls.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
! Subroutine: CHECK_BC_WALLS                                           !
! Author: J.Musser                                    Date: 01-Mar-14  !
!                                                                      !
! Purpose: Driver routine to call checks for WALL BCs.                 !
!                                                                      !
!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
      SUBROUTINE check_bc_walls(M_TOT, SKIP, BCV)


! Global Variables:
!---------------------------------------------------------------------//
! Flag: Identifies solids model (TFM,DEM,PIC)
      use run, only: solids_model
! User-input: solids kinetic-theory model.
      use run, only: kt_type_enum, ghd_2007

! Global Parameters:
!---------------------------------------------------------------------//
! Maximum number of solids phases
      use param, only: dim_m

! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager

      IMPLICIT NONE

! Dummy Arguments.
!---------------------------------------------------------------------//
! Index of BC being checked.
      INTEGER, INTENT(in) :: BCV
! Total number of solids phases.
      INTEGER, INTENT(in) :: M_TOT
! Flag. Solids not present at this BC (used for flow BCs).
      LOGICAL, INTENT(in) :: SKIP(dim_m)

! Local Variables:
!---------------------------------------------------------------------//
! Loop/counter variable.
      INTEGER :: M
! Local total number of solids phases
      INTEGER :: MTOT_L
!......................................................................!


! Initialize the error manager.
      CALL init_err_msg("CHECK_BC_WALLS")

! Input checks for gas phase.
      CALL check_bc_walls_gas(bcv)

      mtot_l = merge( m_tot+1, m_tot, kt_type_enum == ghd_2007)

! Input checks for solid phases.
      DO m=1, mtot_l
         SELECT CASE(solids_model(m))
         CASE ('TFM'); CALL check_bc_walls_tfm(bcv, m)
         CASE ('DEM'); CALL check_bc_walls_discrete(bcv, m)
         CASE ('PIC'); CALL check_bc_walls_discrete(bcv, m)
         END SELECT
      ENDDO

! Input checks for user-defined scalar equations.
      CALL check_bc_walls_scalar_eq(bcv)

      CALL finl_err_msg

      RETURN
      END SUBROUTINE check_bc_walls


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
! Subroutine: CHECK_BC_WALLS_GAS                                       !
! Author: J.Musser                                    Date: 01-Mar-14  !
!                                                                      !
! Purpose: Check user-input for gas phase WALL BC parameters.          !
!                                                                      !
!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
      SUBROUTINE check_bc_walls_gas(BCV)

! Global Variables:
!---------------------------------------------------------------------//
! User-input: type of BC
      use bc
! User-Input: gas velocity at wall BCs.
      use bc, only: bc_uw_g, bc_vw_g, bc_ww_g
! User-Input: gas energy eq BCs.
      use bc, only: bc_hw_t_g, bc_tw_g, bc_c_t_g
! User-Input: gas species eq BCs.
      use bc, only: bc_hw_x_g, bc_xw_g, bc_c_x_g
! Total number of speices in each phase.
      use physprop, only: nmax
! Flag: Solve energy equations.
      use run, only: energy_eq
! Flag: Solve species equations.
      use run, only: species_eq
! Flag: Solve K-th direction (3D)
      use geometry, only: do_k

! Global Parameters:
!---------------------------------------------------------------------//
! Parameter constants.
      use param1, only: zero, undefined

! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager

      IMPLICIT NONE

! Dummy Arguments.
!---------------------------------------------------------------------//
      INTEGER, INTENT(in) :: BCV

      INTEGER :: N
!......................................................................!


! Initialize the error manger.
      CALL init_err_msg("CHECK_BC_WALLS_GAS")

! The wall velocities are not needed for no-slip or free-slip
      IF(bc_type_enum(bcv) == par_slip_wall) THEN
         IF(bc_uw_g(bcv) == undefined) THEN
            WRITE(err_msg,1000) trim(ivar('BC_Uw_g',bcv))
            CALL flush_err_msg(abort=.true.)
         ELSEIF(bc_vw_g(bcv) == undefined) THEN
            WRITE(err_msg,1000) trim(ivar('BC_Vw_g',bcv))
            CALL flush_err_msg(abort=.true.)
         ELSEIF(bc_ww_g(bcv) == undefined) THEN
            IF(do_k)THEN
               WRITE(err_msg,1000) trim(ivar('BC_Ww_g',bcv))
               CALL flush_err_msg(abort=.true.)
            ELSE
               bc_ww_g(bcv) = zero
            ENDIF
         ENDIF
      ENDIF

! Check energy equation input.
      IF(energy_eq) THEN
         IF(bc_hw_t_g(bcv) < zero) THEN
            WRITE(err_msg,1001) trim(ivar('BC_HW_T_g',bcv)),           &
               trim(ival(bc_hw_t_g(bcv)))
            CALL flush_err_msg(abort=.true.)
         ENDIF
         IF(bc_hw_t_g(bcv)/=zero .AND.                                 &
            bc_tw_g(bcv)==undefined) THEN
            WRITE(err_msg,1000) trim(ivar('BC_Tw_g',bcv))
            CALL flush_err_msg(abort=.true.)
         ENDIF
         IF(bc_hw_t_g(bcv)/=undefined .AND.                            &
            bc_c_t_g(bcv)==undefined) THEN
            WRITE(err_msg,1000) trim(ivar('BC_C_T_g',bcv))
            CALL flush_err_msg(abort=.true.)
         ENDIF
      ENDIF


! Check species equation input.
      IF(species_eq(0)) THEN
         DO n=1, nmax(0)
            IF(bc_hw_x_g(bcv,n) < zero) THEN
               WRITE(err_msg,1001) trim(ivar('BC_HW_X_g',bcv,n)),      &
                  trim(ival(bc_hw_x_g(bcv,n)))
               CALL flush_err_msg(abort=.true.)
            ENDIF
            IF(bc_hw_x_g(bcv,n)/=zero .AND.                            &
               bc_xw_g(bcv,n)==undefined) THEN
               WRITE(err_msg,1000) trim(ivar('BC_Xw_g',bcv,n))
               CALL flush_err_msg(abort=.true.)
            ENDIF
            IF(bc_hw_x_g(bcv,n)/=undefined .AND.                       &
               bc_c_x_g(bcv,n)==undefined) THEN
               WRITE(err_msg,1000) trim(ivar('BC_C_X_g',bcv,n))
               CALL flush_err_msg(abort=.true.)
            ENDIF
         ENDDO
      ENDIF


! Clear the error manager.
      CALL finl_err_msg

      RETURN

 1000 FORMAT('Error 1000: Required input not specified: ',a,/'Please ',&
            'correct the mfix.dat file.')

 1001 FORMAT('Error 1001: Illegal or unphysical input: ',a,' = ',a,/   &
         'Please correct the mfix.dat file.')

      END SUBROUTINE check_bc_walls_gas


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
! Subroutine: CHECK_BC_WALLS_TFM                                       !
! Author: J.Musser                                    Date: 01-Mar-14  !
!                                                                      !
! Purpose: Check user-input for TFM solids WALL BC parameters.         !
!                                                                      !
!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
      SUBROUTINE check_bc_walls_tfm(BCV,M)


! Global Variables:
!---------------------------------------------------------------------//
! User-input: type of BC
      use bc
! User-Input: solids velocity at wall BCs.
      use bc, only: bc_uw_s, bc_vw_s, bc_ww_s
! User-Input: solids energy eq BCs.
      use bc, only: bc_hw_t_s, bc_tw_s, bc_c_t_s
! User-Input: solids species eq BCs.
      use bc, only: bc_hw_x_s, bc_xw_s, bc_c_x_s
! User-Input: granular energy eq BCs.
      use bc, only: bc_hw_theta_m, bc_thetaw_m, bc_c_theta_m
! Total number of solids phases
      use physprop, only: mmax
! Total number of speices in each phase.
      use physprop, only: nmax
! Flag: Solve energy equations.
      use run, only: energy_eq
! Flag: Solve species equations.
      use run, only: species_eq
! Flag: Solve Granular energy PDE
      use run, only: granular_energy
! User-input: solids kinetic-theory model.
      use run, only: kt_type_enum, ghd_2007
! Flag: Use johnson and jackson bc
      use bc, only: bc_jj_ps
! Flag: use revised phip for JJ BC.
      use run, only: bc_jj_m, phip_out_jj
! Flag: use jenkins small friction bc
      use run, only: jenkins
! User input: particle wall restitution coefficient and
! angle of internal friction at walls (degrees)
      use constant, only: e_w, phi_w
! Used by jenkins or revised phip bcs
      use constant, only: tan_phi_w
! Used by revised phip for jj bc
      use constant, only: k4phi, phip0
! User-Input: number of reactionrates
!      use rxns, only: nrr
! Flag: Solve K-th direction (3D)
      use geometry, only: do_k
! Flag: use cartesian grid
      use cutcell, only: cartesian_grid

! Global Parameters:
!---------------------------------------------------------------------//
! Parameter constants.
      use param1, only: one, zero, undefined, undefined_i
! parameter values
      use constant, only: pi

      use rxns
! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager
      use funits, only: unit_log
      IMPLICIT NONE

! Dummy Arguments.
!---------------------------------------------------------------------//
! Index of BC being checked.
      INTEGER, INTENT(in) :: BCV
! Index of solids phase.
      INTEGER, INTENT(in) :: M

! Local Variables:
!---------------------------------------------------------------------//
! Loop/variable counter.
      INTEGER :: NN
! Flag to check momentum eq input.
      LOGICAL :: CHECK_MOMENTUM
! Flag to check scalar eq input.
      LOGICAL :: CHECK_SCALARS
!......................................................................!


! Initialize the error manager.
      CALL init_err_msg("CHECK_BC_WALLS_TFM")

! Toggle the momentum and scalar input variable checks.
      SELECT CASE(kt_type_enum)
      CASE (ghd_2007)
         check_momentum = (m == mmax)
         check_scalars  = (m /= mmax)
      CASE DEFAULT
         check_momentum = .true.
         check_scalars  = .true.
      END SELECT

! Set the default specification of Johnson-Jackson BC
      IF(bc_jj_ps(bcv) == undefined_i)                                 &
         bc_jj_ps(bcv) = merge(1,0,granular_energy)

! specifying bc_jj_ps=1 without granular_energy would cause problem in
! the momentum bc routines
      IF(.NOT.granular_energy .AND. bc_jj_ps(bcv) == 1) THEN
         WRITE(err_msg, 1101)
         CALL flush_err_msg(abort=.true.)
      ENDIF
 1101 FORMAT('Error 1101: Invoking BC_JJ_PS requires GRANULAR_ENERGY', &
         '=.TRUE.',/ 'Please correct the mfix.dat file.')

! The wall velocities are not needed for no-slip or free-slip
! Wall velocities are needed if johnson-jackson bc model is used
      IF(check_momentum) THEN
         IF(bc_type_enum(bcv) == par_slip_wall .OR. &
            bc_jj_ps(bcv) /= zero) THEN
            IF(bc_uw_s(bcv,m) == undefined) THEN
               WRITE(err_msg,1000) trim(ivar('BC_Uw_s',bcv,m))
               CALL flush_err_msg(abort=.true.)
            ELSEIF(bc_vw_s(bcv,m) == undefined) THEN
               WRITE(err_msg,1000) trim(ivar('BC_Vw_s',bcv,m))
               CALL flush_err_msg(abort=.true.)
            ELSEIF(bc_ww_s(bcv,m) == undefined) THEN
               IF(do_k)THEN
                  WRITE(err_msg,1000) trim(ivar('BC_Ww_s',bcv,m))
                  CALL flush_err_msg(abort=.true.)
               ELSE
                  bc_ww_s(bcv,m) = zero
               ENDIF
            ENDIF
         ENDIF

         IF(granular_energy .AND. bc_jj_ps(bcv)==0) THEN
            IF(bc_hw_theta_m(bcv,m) < zero) THEN
               WRITE(err_msg,1001) trim(ivar('BC_HW_Theta_M',bcv,m)),  &
                  trim(ival(bc_hw_theta_m(bcv,m)))
               CALL flush_err_msg(abort=.true.)
            ENDIF
            IF(bc_hw_theta_m(bcv,m)/=zero .AND.                        &
               bc_thetaw_m(bcv,m)==undefined) THEN
               WRITE(err_msg,1000) trim(ivar('BC_ThetaW_M',bcv,m))
               CALL flush_err_msg(abort=.true.)
            ENDIF
            IF(bc_hw_theta_m(bcv,m)/=undefined .AND.                   &
               bc_c_theta_m(bcv,m)==undefined) THEN
               WRITE(err_msg,1000) trim(ivar('BC_C_THETA_M',bcv,m))
               CALL flush_err_msg(abort=.true.)
            ENDIF
         ENDIF
      ELSE
      ENDIF

      IF(check_scalars)THEN
         IF(energy_eq) THEN
            IF(bc_hw_t_s(bcv,m) < zero) THEN
               WRITE(err_msg,1001) trim(ivar('BC_HW_T_s',bcv,m)),      &
                  trim(ival(bc_hw_t_s(bcv,m)))
               CALL flush_err_msg(abort=.true.)
            ENDIF
            IF(bc_hw_t_s(bcv,m)/=zero .AND.                            &
               bc_tw_s(bcv,m)==undefined) THEN
               WRITE(err_msg,1000) trim(ivar('BC_Tw_s',bcv,m))
               CALL flush_err_msg(abort=.true.)
            ENDIF
            IF(bc_hw_t_s(bcv,m)/=undefined .AND.                       &
               bc_c_t_s(bcv,m)==undefined) THEN
               WRITE(err_msg,1000) trim(ivar('BC_C_T_s',bcv,m))
               CALL flush_err_msg(abort=.true.)
            ENDIF
         ENDIF

         IF(species_eq(m)) THEN
            DO nn=1, nmax(m)
               IF(bc_hw_x_s(bcv,m,nn) < zero) THEN
                  WRITE(err_msg,1001) trim(ivar('BC_HW_X_s',bcv,m,nn)), &
                     trim(ival(bc_hw_x_s(bcv,m,nn)))
                  CALL flush_err_msg(abort=.true.)
               ENDIF
               IF(bc_hw_x_s(bcv,m,nn)/=zero .AND.                       &
                  bc_xw_s(bcv,m,nn)==undefined) THEN
                  WRITE(err_msg,1000) trim(ivar('BC_Xw_s',bcv,m,nn))
                  CALL flush_err_msg(abort=.true.)
               ENDIF
               IF(bc_hw_x_s(bcv,m,nn)/=undefined .AND.                  &
                  bc_c_x_s(bcv,m,nn)==undefined) THEN
                  WRITE(err_msg,1000) trim(ivar('BC_C_X_s',bcv,m,nn))
                  CALL flush_err_msg(abort=.true.)
               ENDIF
            ENDDO
         ENDIF ! Species Equation
      ELSE
      ENDIF ! Check Scalars


! might make sense to move these checks out of this routine
! but placed here for now
      IF(granular_energy .AND. bc_jj_ps(bcv) == 1) THEN

         IF(kt_type_enum == ghd_2007) THEN
            WRITE(err_msg, 1201)
            CALL flush_err_msg(abort=.true.)
         ENDIF

         IF(cartesian_grid) THEN
! the user should really be warned this is not implemented as
! opposed to running with it
            WRITE(err_msg, 1202)
            CALL flush_err_msg(abort=.true.)
         ENDIF

! small frictional boundary condition model
         IF(jenkins) THEN
            IF (bc_jj_m) THEN
               WRITE(err_msg, 1203)
               CALL flush_err_msg(abort=.true.)
            ELSEIF (phi_w == undefined) THEN
               WRITE(err_msg, 1204)
               CALL flush_err_msg(abort=.true.)
            ELSEIF (e_w > one .OR. e_w < zero) THEN
               WRITE(err_msg, 1001) 'E_W', e_w
               CALL flush_err_msg(abort=.true.)
            ENDIF
! PHI_W is given in degrees but calculated in radian within
! the fortran codes
            tan_phi_w = tan(phi_w*pi/180.d0)
         ENDIF

! k4phi, phip0 for variable specularity coefficient
         k4phi = undefined
         IF(bc_jj_m) THEN
            IF (jenkins) THEN
               WRITE(err_msg, 1203)
               CALL flush_err_msg(abort=.true.)
            ELSEIF (phi_w == undefined) THEN
               WRITE(err_msg, 1204)
               CALL flush_err_msg(abort=.true.)
            ELSEIF (e_w > one .OR. e_w < zero) THEN
               WRITE(err_msg, 1001) 'E_W', e_w
               CALL flush_err_msg(abort=.true.)
            ENDIF
! PHI_W is given in degrees but calculated in radian within
! the fortran codes
            tan_phi_w = tan(phi_w*pi/180.d0)

            k4phi = 7.d0/2.d0*tan_phi_w*(1.d0+e_w)
            IF (phip0 .eq. undefined) THEN
               phip0 = -0.0012596340709032689 + &
                        0.10645510095633175*k4phi - &
                        0.04281476447854031*k4phi**2 + &
                        0.009759402181229842*k4phi**3 - &
                        0.0012508257938705263*k4phi**4 + &
                        0.00008369829630479206*k4phi**5 - &
                        0.000002269550565981776*k4phi**6
! if k4phi is less than 0.2, the analytical expression for phi is used
! to estimate the phi at r->0
               IF (k4phi .le. 0.2d0) THEN
                  phip0=0.09094568176225006*k4phi
               ENDIF
               WRITE (unit_log, 1207) phip0
            ENDIF
            IF (phip0 < 0) THEN
               WRITE(err_msg, 1208)
               CALL flush_err_msg(abort=.true.)
            ENDIF

            IF (phip_out_jj) THEN
               IF(nrr < 1) THEN
                  WRITE(err_msg, 1209)
                  CALL flush_err_msg(abort=.true.)
               ENDIF
               WRITE (unit_log, 1210) phip0
            ENDIF
         ENDIF
      ENDIF   ! if granular_energy and bc_jj_ps = 1


      CALL finl_err_msg

      RETURN

 1000 FORMAT('Error 1000: Required input not specified: ',a,/'Please ',&
            'correct the mfix.dat file.')

 1001 FORMAT('Error 1001: Illegal or unphysical input: ',a,' = ',a,/   &
         'Please correct the mfix.dat file.')

 1201 FORMAT('Error 1201: KT_TYPE = "GHD" cannot be used with ',&
         ' BC_JJ_PS',/'Please correct the mfix.dat file.')

 1202 FORMAT('Error 1202: CARTESIAN_GRID cannot be used with ',&
         ' BC_JJ_PS',/'Please correct the mfix.dat file.')

 1203 FORMAT('Error 1203: JENKINS and BC_JJ_M cannot be used at the',&
         ' same time',/'Please correct the mfix.dat file.')
 1204 FORMAT('Error 1204: Angle of particle-wall friction (PHI_W) not',&
         ' specified.',/'Please correct the mfix.dat file.')

 1208 FORMAT('Error 1208: phip0 less than zero.')
 1209 FORMAT('Error 1209: nRR should be at least 1 for storing ',&
             'specularity.')

 1207 FORMAT(/1x,70('*')//' From: CHECK_BC_WALLS_TFM',/' Message: ',&
         'No input for phip0 available, working expression is used.',/ &
         'phip0=',g12.5,/1x,70('*')/)
 1210 FORMAT(/1x,70('*')//' From: CHECK_BC_WALLS_TFM',/' Message: ',&
         'Specularity will be stored as the first element of ', &
         'ReactionRates',/1x,'array in WALL CELLS. Please avoid ', &
         'overwriting it when reacting flow',/1x,' is simulated.', &
         /1x,70('*')/)

      END SUBROUTINE check_bc_walls_tfm


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
! Subroutine: CHECK_BC_WALLS_DISCRETE                                  !
! Author: J.Musser                                    Date: 01-Mar-14  !
!                                                                      !
! Purpose: Check user-input for DEM/PIC solids WALL BC parameters.     !
!                                                                      !
!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
      SUBROUTINE check_bc_walls_discrete(BCV,M)


! Global Variables:
!---------------------------------------------------------------------//
! User-Input: solids velocity at wall BCs.
      use bc, only: bc_uw_s, bc_vw_s, bc_ww_s
! User-Input: solids energy eq BCs.
      use bc, only: bc_hw_t_s, bc_tw_s, bc_c_t_s
! User-Input: solids species eq BCs.
      use bc, only: bc_hw_x_s, bc_xw_s, bc_c_x_s

! Global Parameters:
!---------------------------------------------------------------------//
! Maximum number of possible species.
      use param, only: dim_n_s
! Parameter constants.
      use param1, only: undefined, zero

! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager

      IMPLICIT NONE

! Dummy Arguments.
!---------------------------------------------------------------------//
! Index of BC getting checked.
      INTEGER, INTENT(in) :: BCV
! Index of solid phase getting checked.
      INTEGER, INTENT(in) :: M

! Local Variables:
!---------------------------------------------------------------------//
! Loop/variable counter.
      INTEGER :: NN
!......................................................................!


! Initialize the error manager.
      CALL init_err_msg("CHECK_BC_WALLS_DISCRETE")

! DEM and PIC are restricted to adiabatic walls.
      IF((bc_hw_t_s(bcv,m) /= undefined) .and. &
      &  (bc_hw_t_s(bcv,m) /= zero)) THEN
         WRITE(err_msg,1100) trim(ivar('BC_HW_T_s',bcv,m))
         CALL flush_err_msg(abort=.true.)
      ELSEIF((bc_c_t_s(bcv,m) /= undefined) .and. &
         &   (bc_c_t_s(bcv,m) /= zero))THEN
         WRITE(err_msg,1100) trim(ivar('BC_C_T_s',bcv,m))
         CALL flush_err_msg(abort=.true.)
      ENDIF

 1100 FORMAT('Error 1100: ',a,' should not specified for DEM/PIC',/    &
         'to be non-zero as they are currently limited to constant',/  &
         'constant temperature BCs.',&
         /'Please correct the mfix.dat file.')


! The following checks verify that TFM solids parameters are not
! specified for discrete solids.


! The wall velocities are not needed DEM/PIC solids
      IF(bc_uw_s(bcv,m) /= undefined) THEN
         WRITE(err_msg,1101) bcv, trim(ivar('BC_Uw_s',bcv,m))
         CALL flush_err_msg(abort=.true.)
      ELSEIF(bc_vw_s(bcv,m) /= undefined) THEN
         WRITE(err_msg,1101) bcv, trim(ivar('BC_Vw_s',bcv,m))
         CALL flush_err_msg(abort=.true.)
      ELSEIF(bc_ww_s(bcv,m) /= undefined) THEN
         WRITE(err_msg,1101) bcv, trim(ivar('BC_Ww_s',bcv,m))
         CALL flush_err_msg(abort=.true.)
      ENDIF

! DEM cannot have a species flux at the walls.
      DO nn=1, dim_n_s
         IF(bc_hw_x_s(bcv,m,nn) /= undefined) THEN
            WRITE(err_msg,1101) bcv, trim(ivar('BC_HW_X_s',bcv,m,nn))
            CALL flush_err_msg(abort=.true.)
         ELSEIF(bc_xw_s(bcv,m,nn) /= undefined) THEN
            WRITE(err_msg,1101) bcv, trim(ivar('BC_Xw_s',bcv,m,nn))
            CALL flush_err_msg(abort=.true.)
         ELSEIF(bc_c_x_s(bcv,m,nn) /= undefined) THEN
            WRITE(err_msg,1101) bcv, trim(ivar('BC_C_X_s',bcv,m,nn))
            CALL flush_err_msg(abort=.true.)
         ENDIF
      ENDDO

 1101 FORMAT('Error 1101: Illegal input for boundary condition: ',i3,/ &
         a,' should not be specified for DEM/PIC simulations.',/       &
         'Please correct the mfix.dat file.')

      CALL finl_err_msg

      RETURN

      END SUBROUTINE check_bc_walls_discrete




!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
! Subroutine: CHECK_BC_WALLS_SCALAR_EQ                                 !
! Author: J.Musser                                    Date: 01-Mar-14  !
!                                                                      !
! Purpose: Check user-input for generic scalar eq WALL BC parameters.  !
!                                                                      !
!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
      SUBROUTINE check_bc_walls_scalar_eq(BCV)


! Global Variables:
!---------------------------------------------------------------------//
! User-input: number of generic scalar equations to solve.
      use scalars, only: nscalar
! User-Input: generic scalar eq at wall BCs.
      use bc, only: bc_hw_scalar, bc_scalarw, bc_c_scalar

! Global Parameters:
!---------------------------------------------------------------------//
! Parameter constants
      use param1, only: zero, undefined

! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager

      IMPLICIT NONE

! Dummy Arguments.
!---------------------------------------------------------------------//
! Index of BC getting checked.
      INTEGER, INTENT(in) :: BCV

! Local Variables:
!---------------------------------------------------------------------//
! Loop/counter variable.
      INTEGER :: NN
!......................................................................!


! Initialize the error manager.
      CALL init_err_msg("CHECK_BC_WALLS_SCALAR_EQ")

      DO nn=1, nscalar
         IF(bc_hw_scalar(bcv,nn) < zero) THEN
            WRITE(err_msg,1001) trim(ivar('BC_HW_SCALAR',bcv,nn)),      &
               trim(ival(bc_hw_scalar(bcv,nn)))
            CALL flush_err_msg(abort=.true.)
         ENDIF
         IF(bc_hw_scalar(bcv,nn) /= zero .AND.                          &
            bc_scalarw(bcv,nn) == undefined) THEN
            WRITE(err_msg,1000) trim(ivar('BC_SCALARw',bcv,nn))
            CALL flush_err_msg(abort=.true.)
         ENDIF
         IF(bc_hw_scalar(bcv,nn) /= undefined .AND.                     &
            bc_c_scalar(bcv,nn) == undefined) THEN
            WRITE(err_msg,1000) trim(ivar('BC_C_SCALAR',bcv,nn))
         ENDIF
      ENDDO

      CALL finl_err_msg

      RETURN

 1000 FORMAT('Error 1000: Required input not specified: ',a,/'Please ',&
            'correct the mfix.dat file.')

 1001 FORMAT('Error 1001: Illegal or unphysical input: ',a,' = ',a,/   &
         'Please correct the mfix.dat file.')

      END SUBROUTINE check_bc_walls_scalar_eq