check_solids_common_discrete.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  SUBROUTINE: CHECK_SOLIDS_COMMON_DISCRETE                            !
!  Author: J.Musser                                   Date: 02-FEB-14  !
!                                                                      !
!  Purpose:                                                            !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_solids_common_discrete

! Modules
!---------------------------------------------------------------------//
! Runtime Flag: Generate initial particle configuration.
      USE discretelement, only: gener_part_config
! Runtime Flag: Store DES_*_OLD arrays.
      USE discretelement, only: do_old
! Number of DEM solids phases.
      USE discretelement, only: des_mmax
! User specified integration method.
      USE discretelement, only: des_intg_method
      USE discretelement, only: intg_adams_bashforth
      USE discretelement, only: intg_euler
! User specified neighbor search method.
      USE discretelement, only: des_neighbor_search
! User specified data out format (VTP, TecPlot)
      USE discretelement, only: des_output_type
! Max/Min particle radii
      USE discretelement, only: max_radius, min_radius
! Runtime Flag: Periodic boundaries
      USE discretelement, only: des_periodic_walls
      USE discretelement, only: des_periodic_walls_x
      USE discretelement, only: des_periodic_walls_y
      USE discretelement, only: des_periodic_walls_z
! Use the error manager for posting error messages.
      use error_manager
! Runtime Flag: Invoke MPPIC model.
      USE mfix_pic, only: mppic
      USE mpi_utility

      use param1, only: undefined, undefined_c
      use param, only: dim_m
! number of continuous solids phases and
! solids 'phase' diameters and densities
      USE physprop, only: mmax, d_p0, ro_s0
! Calculated baseline variable solids density.
      USE physprop, only: close_packed
! Runtime Flag: Solve energy equations
      USE run, only: energy_eq
! Runtime Flag: One or more species equations are solved.
      use run, only: any_species_eq
! Flag: Solve variable solids density.
      use run, only: solve_ros
      use run, only: solids_model
      USE run, only: momentum_x_eq
      USE run, only: momentum_y_eq
      USE run, only: momentum_z_eq
      use run, only: run_type
      implicit none

! Local Variables
!---------------------------------------------------------------------//
      INTEGER :: M 
!......................................................................!

! Initialize the error manager.
      CALL init_err_msg("CHECK_SOLIDS_COMMON_DISCRETE")

! Determine the maximum particle size in the system (MAX_RADIUS), which
! in turn is used for various tasks
      max_radius = -undefined
      min_radius =  undefined
! For number of continuous solids phases (use MMAX rather than SMAX to
! accomodate GHD particularity)
      DO m = mmax+1,des_mmax+mmax
         max_radius = max(max_radius, 0.5d0*d_p0(m))
         min_radius = min(min_radius, 0.5d0*d_p0(m))
      ENDDO

! Set close_packed to true to prevent possible issues stemming from the
! pressure correction equation.  Specifically, if closed_packed is false
! then a mixture pressure correction equation is invoked and this is not
! correctly setup for DEM.  To do so would require ensuring that
! 1) the solids phase continuum quantities used in these equations are
!    correctly set based on their DEM counterparts and
! 2) the pressure correction coefficients for such solids phases are
!    also calculated (currently these calculations are turned off
!    when using DEM)
      close_packed((mmax+1):dim_m) = .true.


! Turn off the 'continuum' equations for discrete solids if the user
! specified them.  We could make use of these flags.
      momentum_x_eq((mmax+1):dim_m) = .false.
      momentum_y_eq((mmax+1):dim_m) = .false.
      momentum_z_eq((mmax+1):dim_m) = .false.

! Derive periodicity from cyclic boundary flags.
      des_periodic_walls_x = cyclic_x .OR. cyclic_x_pd
      des_periodic_walls_y = cyclic_y .OR. cyclic_y_pd
      des_periodic_walls_z = cyclic_z .OR. cyclic_z_pd

      des_periodic_walls = (des_periodic_walls_x .OR.                  &
        des_periodic_walls_y .OR. des_periodic_walls_z)


! Overwrite for restart cases.
      IF(trim(run_type) .NE. 'NEW') gener_part_config = .false.

! Check for valid neighbor search option.
      SELECT CASE(des_neighbor_search)
      CASE (1) ! N-Square
      CASE (2)
         WRITE(err_msg,2001) 2, 'QUADTREE'
         CALL flush_err_msg(abort=.true.)
      CASE (3)
         WRITE(err_msg,2001) 3, 'OCTREE'
         CALL flush_err_msg(abort=.true.)
      CASE (4) ! Grid based
      CASE DEFAULT
         WRITE(err_msg,2001) des_neighbor_search,'UNKNOWN'
         CALL flush_err_msg(abort=.true.)

 2001 FORMAT('Error 2001:Invalid DES_NEIGHBOR_SEARCH method: ',i2,1x,  &
         a,/'Please correct the mfix.dat file.')

      END SELECT


! Check the output file format
      IF(des_output_type == undefined_c) des_output_type = 'PARAVIEW'
      SELECT CASE(trim(des_output_type))
      CASE ('PARAVIEW')
      CASE ('TECPLOT')
      CASE DEFAULT
         WRITE(err_msg,2010) trim(des_output_type)
         CALL flush_err_msg(abort=.true.)

 2010 FORMAT('Error 2010:Invalid DES_OUTPUT_TYPE: ',a,/'Please ',       &
         'correct the mfix.dat file.')

      END SELECT


! Check for valid integration method
      SELECT CASE(trim(des_intg_method))
      CASE ('EULER')
         intg_euler = .true.
         intg_adams_bashforth = .false.
         !DES_INTG_METHOD_ENUM = 1
      CASE ('ADAMS_BASHFORTH')
         intg_euler = .false.
         intg_adams_bashforth = .true.
         !DES_INTG_METHOD_ENUM = 2
      CASE DEFAULT
         WRITE(err_msg,2020) trim(des_intg_method)
         CALL flush_err_msg(abort=.true.)

 2020 FORMAT('Error 2020:Invalid DES_INGT_METHOD: ',a,/'Please ',      &
         'correct the mfix.dat file.')

      END SELECT

      do_old = intg_adams_bashforth .OR. mppic

! Check interpolation input.
      CALL check_solids_common_discrete_interp

! Set flags for energy equations
      IF(energy_eq) CALL check_solids_common_discrete_energy

! Check thermodynamic properties of discrete solids.
      IF(any_species_eq) &
         CALL check_solids_common_discrete_thermo

! Check geometry constrains.
      CALL check_solids_common_discrete_geometry

      CALL finl_err_msg


      RETURN

      END SUBROUTINE check_solids_common_discrete


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  SUBROUTINE CHECK_SOLIDS_COMMON_DISCRETE_ENERGY                      !
!  Author: J.Musser                                   Date: 02-FEB-14  !
!                                                                      !
!  Purpose: Check input parameters for solving discrete solids phase   !
!  energy equations.  Only DEM simulations (neither hybrid nor MPPIC)  !
!  can invoke particle-particle heat transfer. Therefore, checks for   !
!  those functions are reseved for later.                              !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_solids_common_discrete_energy

! Modules
!---------------------------------------------------------------------//
      use param1, only: zero, undefined
      use des_thermo, only: des_conv_corr
      use des_thermo, only: des_conv_corr_enum
      use des_thermo, only: ranz_1952
      use des_thermo, only: sb_const
      use des_thermo, only: des_em
      use des_thermo, only: calc_conv_des ! Convection
      use des_thermo, only: calc_cond_des ! Conduction
      use des_thermo, only: calc_radt_des ! Radiation
! Flag to explicitly couple source terms and DES
      use discretelement, only: des_explicitly_coupled
      use discretelement, only: des_mmax
      use discretelement, only: des_continuum_coupled
! Use the error manager for posting error messages.
      use error_manager
! User input for DES interpolation scheme.
      use particle_filter, only: des_interp_scheme
! Enumerated interpolation scheme for faster access
      use particle_filter, only: des_interp_scheme_enum
      use particle_filter, only: des_interp_none

      use physprop, only: mmax
      use physprop, only: k_s0
      use run, only: units
      use run, only: solids_model

      IMPLICIT NONE

! Local Variables:
!---------------------------------------------------------------------//
! Loop counter
      INTEGER :: M

!......................................................................!


! Initialize the error manager.
      CALL init_err_msg("CHECK_SOLIDS_COMMON_DISCRETE_ENERGY")


! Set runtime flags for which modes of heat transfer to calculate.
      calc_conv_des = des_continuum_coupled
      DO m = mmax+1, mmax+des_mmax
! Flag to calculate radiation.
         IF(des_em(m) > zero) calc_radt_des(m) = .true.
! Flag to calculate conduction.
         calc_cond_des(m) = (k_s0(m) > zero .AND. k_s0(m) /= undefined)
      ENDDO

! Gas/Solids convection:
!'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
! Verify the selected convective heat transfer coefficient model
      SELECT CASE(trim(des_conv_corr))
! Ranz, W.E. and Marshall, W.R., "Friction and transfer coefficients
! for single particles and packed beds,"  Chemical Engineering Science,
! Vol. 48, No. 5, pp 247-253, 1952.
      CASE ('RANZ_1952')
         des_conv_corr_enum = ranz_1952
! If the heat transfer coefficient correlation provided by the user does
! not match one of the models outlined above, flag the error and exit.
      CASE DEFAULT
         WRITE(err_msg,1001)'DES_CONV_CORR', trim(des_conv_corr)
         CALL flush_err_msg(abort=.true.)
      END SELECT


! Radiation Equation:
!'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
! Verify that a emmisivity value is specified for each solids phase
      DO m = mmax+1, mmax+des_mmax
         IF(des_em(m) == undefined) THEN
            WRITE(err_msg,1000) trim(ivar('DES_Em',m))
            CALL flush_err_msg(abort=.true.)
         ENDIF
      ENDDO

! Set the value of the Stefan-Boltzman Constant based on the units
      IF(units == 'SI')THEN
         sb_const = 5.6704d0*(10.0d0**(-8)) ! W/((m^2).K^4)
      ELSE
         sb_const = 1.355282d0*(10.0d0**(-12)) ! cal/((cm^2).sec.K^4)
      ENDIF


! Notify that interpolation is not support for thermo variables
      SELECT CASE(des_interp_scheme_enum)
      CASE(des_interp_none)
      CASE DEFAULT
         WRITE(err_msg,2000) trim(adjustl(des_interp_scheme))
         CALL flush_err_msg()
      END SELECT

 2000 FORMAT('WARNING 2000: The selected interpolation scheme (',a,    &
         ') is not',/'supported by the DES energy equation implemen',  &
         'tation. All energy',/'equation variables will use the ',     &
         'centroid method for interphase',/'data exchange.')

      IF(des_explicitly_coupled)THEN
         WRITE(err_msg, 2100)
         CALL flush_err_msg!(ABORT=.TRUE.)
      ENDIF

 2100 FORMAT('Error 2100: The DES Energy equation implementation ',    &
         'does not',/'currently support explicit coupling (DES_',      &
         'EXPLICITLY_COUPLED).',/'Please correct the mfix.dat file.')

      CALL finl_err_msg


      RETURN

 1000 FORMAT('Error 1000: Required input not specified: ',a,/'Please ',&
         'correct the mfix.dat file.')

 1001 FORMAT('Error 1001: Illegal or unknown input: ',a,' = ',a,/   &
         'Please correct the mfix.dat file.')

      END SUBROUTINE check_solids_common_discrete_energy




!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: CHECK_SOLIDS_COMMON_DISCRETE_THERMO                     !
!  Author: J.Musser                                   Date: 17-Jun-10  !
!                                                                      !
!  Purpose:                                                            !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_solids_common_discrete_thermo

! Modules
!---------------------------------------------------------------------//
      use discretelement, only: des_explicitly_coupled
      use error_manager
! User input for DES interpolation scheme.
      use particle_filter, only: des_interp_scheme
! Enumerated interpolation scheme for faster access
      use particle_filter, only: des_interp_scheme_enum
      use particle_filter, only: des_interp_none
      use stiff_chem, only: stiff_chemistry
      IMPLICIT NONE

!......................................................................!


! Initialize the error manager.
      CALL init_err_msg("CHECK_SOLIDS_COMMON_DISCRETE_THERMO")

! Stiff chemistry solver is a TFM reaction model not for DES.
      IF(stiff_chemistry) THEN
         WRITE(err_msg,9003)
         CALL flush_err_msg(abort=.false.)
      ENDIF

 9003 FORMAT('Error 9003: The stiff chemistry solver is not ',         &
      'available in DES',/'simulations. Please correct the input file.')

! Notify that interpolation is not support for thermo variables
      SELECT CASE(des_interp_scheme_enum)
      CASE(des_interp_none)
      CASE DEFAULT
         WRITE(err_msg,2000) trim(adjustl(des_interp_scheme))
         CALL flush_err_msg()
      END SELECT

 2000 FORMAT('WARNING 2000: The selected interpolation scheme (',a,    &
         ') is not',/'supported by the DES Species equation implemen', &
         'tation. All energy',/'equation variables will use the ',     &
         'centroid method for interphase',/'data exchange.')

      IF(des_explicitly_coupled)THEN
         WRITE(err_msg, 2100)
         CALL flush_err_msg!(ABORT=.TRUE.)
      ENDIF

 2100 FORMAT('Error 2100: The DES Species equation implementation ',   &
         'does not',/'currently support explicit coupling (DES_',      &
         'EXPLICITLY_COUPLED).',/'Please correct the mfix.dat file.')

      CALL finl_err_msg

      RETURN
      END SUBROUTINE check_solids_common_discrete_thermo


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: CHECK_SOLIDS_COMMON_DISCRETE_GEOMETRY                   !
!  Author: J.Musser                                   Date: 11-DEC-13  !
!                                                                      !
!  Purpose: Check user input data                                      !
!                                                                      !
!  Comments: Geometry checks were moved here from CHECK_DES_DATA.      !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_solids_common_discrete_geometry

! Modules
!---------------------------------------------------------------------//
! Flag: Use Cartesian grid cut-cell implementation
      USE cutcell, only: cartesian_grid
! Flag: Use STL representation in CG
      USE cutcell, only: use_stl
! Flag: Use DES E-L model
      USE discretelement, only: des_continuum_coupled
      USE discretelement, only: max_radius
      use error_manager
      USE geometry, only: coordinates
      USE geometry, only: no_i, no_j
      USE geometry, only: zlength
      IMPLICIT NONE

! Local Variables
!---------------------------------------------------------------------//
      DOUBLE PRECISION :: MIN_DEPTH

!......................................................................!


! Initialize the error manager.
      CALL init_err_msg("CHECK_SOLIDS_COMMON_DISCRETE_GEOMETRY")


! DEM/MPPIC is restricted to CARTESIAN coordinates.
      IF(coordinates == 'CYLINDRICAL') THEN
         WRITE (err_msg, 1100)
         CALL flush_err_msg(abort=.true.)
      ENDIF

 1100 FORMAT('Error: 1100: DES and MPPIC models only support ',        &
         'CARTESIAN coordinates.')


! Check dimension. This is redundant with check_data_03.
      IF(no_i .OR. no_j) THEN
         WRITE(err_msg, 1200)
         CALL flush_err_msg(abort=.true.)
      ENDIF

 1200 FORMAT('Error 1200: Illegal geometry for DEM/MPPIC. 2D ',        &
         'simulations are',/'restricted to the XY plane. Please ',     &
         'correct the mfix.dat file.')


      IF(des_continuum_coupled)THEN
! Check that the depth of the simulation exceeds the largest particle
! to ensure correct calculation of volume fraction. This is important
! for coupled simulations.
         min_depth = 2.0d0*max_radius
         IF(zlength < min_depth)THEN
            WRITE(err_msg, 1300)
            CALL flush_err_msg(abort=.false.)
         ENDIF
      ENDIF

 1300 FORMAT('Error 1300: The maximum particle diameter exceeds the ', &
         'simulation',/'depth (ZLENGTH). Please correct the mfix.dat ',&
         'file.')


      IF(cartesian_grid .AND. .NOT.use_stl) THEN
         WRITE(err_msg,1400)
         CALL flush_err_msg(abort =.true.)
      ENDIF

 1400 FORMAT('Error 1400: Cartesian grid and discrete models (DEM or ',&
         'PIC) only',/'support STL wall representations. Quadrics ',   &
         'and polygons are not',/'supported.')


      CALL finl_err_msg

      RETURN

      END SUBROUTINE check_solids_common_discrete_geometry

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: CHECK_SOLIDS_COMMON_DISCRETE_INTERP                     !
!  Author: J.Musser                                   Date: 25-Nov-14  !
!                                                                      !
!  Purpose:                                                            !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_solids_common_discrete_interp

! Modules
!---------------------------------------------------------------------//
! Runtime Flag: Invoke gas/solids coupled simulation.
      use discretelement, only: des_continuum_coupled
      use error_manager
! Runtime FLag: 3D simulation
      use geometry, only: do_k
! Runtime Flag: Invoke MPPIC model.
      USE mfix_pic, only: mppic
      use param1, only: undefined
! User input for DES interpolation scheme.
      use particle_filter, only: des_interp_scheme
! Enumerated interpolation scheme for faster access
      use particle_filter, only: des_interp_scheme_enum
      use particle_filter, only: des_interp_none
      use particle_filter, only: des_interp_garg
      use particle_filter, only: des_interp_dpvm
      use particle_filter, only: des_interp_gauss
      use particle_filter, only: des_interp_lhat
! User specified filter width
      use particle_filter, only: des_interp_width
! Flag: Diffuse DES field variables.
      use particle_filter, only: des_diffuse_mean_fields
! Diffusion filter width
      use particle_filter, only: des_diffuse_width
! Flag: Interpolate continuum fields
      use particle_filter, only: des_interp_mean_fields
! Flag: Interplate variables for drag calculation.
      use particle_filter, only: des_interp_on
! Size of interpolation filter
      use particle_filter, only: filter_size
      IMPLICIT NONE

!......................................................................!


! Initialize the error manager.
      CALL init_err_msg("CHECK_SOLIDS_COMMON_DISCRETE_INTERP")

! Set the runtime flag for diffusing mean fields
      des_diffuse_mean_fields = (des_diffuse_width /= undefined)

! Set the interpolation ENUM value.
      SELECT CASE(trim(adjustl(des_interp_scheme)))
      CASE ('NONE')
         des_interp_scheme_enum = des_interp_none
! Cannot use interpolation when no scheme is selected.
         IF(des_interp_on)THEN
            WRITE(err_msg,2001) 'DES_INTERP_ON'
            CALL flush_err_msg(abort=.true.)
         ELSEIF(des_interp_mean_fields)THEN
            WRITE(err_msg,2001) 'DES_INTERP_MEAN_FIELDS'
            CALL flush_err_msg(abort=.true.)

         ELSEIF(des_continuum_coupled) THEN
            IF(mppic) THEN
               WRITE(err_msg,2002) 'MPPIC solids'
               CALL flush_err_msg(abort=.false.)
            ELSEIF(mppic) THEN
               WRITE(err_msg,2002) 'Cartesian grid cut-cells'
               CALL flush_err_msg(abort=.true.)
            ENDIF
         ENDIF

      CASE ('GARG_2012')
         des_interp_scheme_enum = des_interp_garg

      CASE ('SQUARE_DPVM')
         des_interp_scheme_enum = des_interp_dpvm

      CASE ('GAUSS_DPVM')
         des_interp_scheme_enum = des_interp_gauss

      CASE ('LINEAR_HAT')
         des_interp_scheme_enum = des_interp_lhat

      CASE DEFAULT
         WRITE(err_msg,2000) trim(adjustl(des_interp_scheme))
         CALL flush_err_msg(abort=.true.)
      END SELECT

 2000 FORMAT('Error 2000: Invalid DES_INTERP_SCHEME: ',a,/'Please ',   &
         'correct the mfix.dat file.')

 2001 FORMAT('Error 2001: No interpolation scheme specified when ',a,/ &
         'is enabled. Please correct the mfix.dat file.')

 2002 FORMAT('Error 2002: DES simulations utilizing ',a,' require',/   &
         'interpolation (DES_INTERP_ON and DES_INTERP_MEANFIELDS). ',/ &
         'Please correct the mfix.dat file.')


      SELECT CASE(des_interp_scheme_enum)

      CASE(des_interp_none)

         IF(des_interp_width /= undefined) THEN
            WRITE(err_msg,2100) trim(adjustl(des_interp_scheme))
            CALL flush_err_msg(abort=.true.)
         ENDIF

 2100 FORMAT('Error 2100: The selected interpolation scheme (',a,') ', &
         'does',/'not support an adjustable interpolation width.',/    &
         'Please correct the input file.')


      CASE(des_interp_garg)
         des_interp_mean_fields= .true.

         IF(des_interp_width /= undefined) THEN
            WRITE(err_msg,2100) trim(adjustl(des_interp_scheme))
            CALL flush_err_msg(abort=.true.)
         ENDIF

         IF(des_diffuse_mean_fields) THEN
            WRITE(err_msg,2110) trim(adjustl(des_interp_scheme))
            CALL flush_err_msg(abort=.true.)
         ENDIF

 2110 FORMAT('Error 2110: The selected interpolation scheme (',a,') ', &
         'does not',/'support diffusive filtering of mean field ',     &
          'quantities. Please correct',/'the input file.')

      CASE(des_interp_dpvm, des_interp_gauss)

! Set the size of the interpolation filter.
         filter_size = merge(27, 9, do_k)

         IF(des_interp_width == undefined) THEN
            WRITE(err_msg,2120) trim(adjustl(des_interp_scheme))
            CALL flush_err_msg(abort=.true.)
         ENDIF

 2120 FORMAT('Error 2120: The selected interpolation scheme (',a,') ', &
         'requires',/'a DES_INTERP_WIDTH. Please correct the ',        &
         'input file.')


      CASE(des_interp_lhat)

! Set the size of the interpolation filter.
         filter_size = merge(27, 9, do_k)

         IF(des_interp_width /= undefined) THEN
            WRITE(err_msg,2100) trim(adjustl(des_interp_scheme))
            CALL flush_err_msg(abort=.true.)
         ENDIF

      END SELECT

      CALL finl_err_msg

      RETURN
      END SUBROUTINE check_solids_common_discrete_interp