check_solids_phases.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!  SUBROUTINE: CHECK_SOLIDS_PHASES                                     !
!                                                                      !
!  Purpose: Driver routine for calls to solids phase checks.           !
!                                                                      !
!  Author: J.Musser                                   Date: 16-Jan-14  !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_solids_phases


! Global Variables:
!---------------------------------------------------------------------//
! Runtime flag specifying TFM solids
      use run, only: tfm_solids
! Runtime flag specifying DEM solids
      use run, only: dem_solids
! Runtime flag specifying MPPIC solids
      use run, only: pic_solids

! Global Module procedures:
!---------------------------------------------------------------------//
      use error_manager

      implicit none

! Local Variables:
!---------------------------------------------------------------------//

!......................................................................!

! Initialize the error manager.
      CALL init_err_msg("CHECK_SOLIDS_PHASES")

! Impose the various model limitations.
      CALL check_solids_model_limitations

! Checks common to all solids models.
      CALL check_solids_common_all

! Checks common to discrete solids phases (DEM, MPPIC).
      IF(dem_solids .OR. pic_solids) &
         CALL check_solids_common_discrete

! Checks specific to the particular solids phase.
      IF(tfm_solids) CALL check_solids_continuum
      IF(dem_solids) CALL check_solids_dem
      IF(pic_solids) CALL check_solids_mppic

      CALL finl_err_msg

      RETURN

      END SUBROUTINE check_solids_phases


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!  SUBROUTINE: CHECK_SOLIDS_MODEL_LIMITATIONS                          !
!                                                                      !
!  Purpose: Impose the limitations of the various solids models. These !
!  checks should be 'high level' in that they only ensure that models  !
!  are only used with phases that support them.                        !
!                                                                      !
!  Author: J.Musser                                   Date: 28-Feb-14  !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_solids_model_limitations

! Global Variables:
!---------------------------------------------------------------------//
! Runtime Flag: TFM solids present.
      use run, only: tfm_solids
! Runtime Flag: DEM solids present.
      use run, only: dem_solids
! Runtime Flag: PIC solids present.
      use run, only: pic_solids
! Runtime Flag: Invoke a cohesion model for DES simulation.
      use discretelement, only: use_cohesion
! Runtime Flag: Sovle energy equations
      use run, only: energy_eq
! Runtime Flag: Sovle species equations
      use run, only: species_eq

! Number of solid phases specified by the user/TFM model.
      use physprop, only: smax
! Number of discrete solids.
      use discretelement, only: des_mmax

! Global Module procedures:
!---------------------------------------------------------------------//
      use error_manager

      implicit none


! Local Variables:
!---------------------------------------------------------------------//
! Total number of solids phases.
      INTEGER :: MMAX_TOT


!......................................................................!


! Initialize the error manager.
      CALL init_err_msg("CHECK_SOLIDS_MODEL_LIMITATIONS")


! Set up the total number of solids.
      mmax_tot = smax + des_mmax


! The cohesion model is only implemented for DEM simulations
      IF(use_cohesion) THEN
         IF(tfm_solids .OR. pic_solids) THEN
            WRITE(err_msg, 2000)
            CALL flush_err_msg(abort=.true.)
         ENDIF

 2000 FORMAT('Error 2000: The solids cohesion model is only available',&
         ' for DEM',/' solids. Please correct the mfix.dat file.')
      ENDIF

! Place holder
      IF(energy_eq .AND. (tfm_solids .OR. pic_solids)) THEN
!         WRITE(ERR_MSG, 2002)
!         CALL FLUSH_ERR_MSG(ABORT=.TRUE.)

 2002 FORMAT('Error 2002: The solids-solids conduction model is only', &
         ' available',/' for DEM only. Please correct the mfix.dat',   &
         ' file.')
      ENDIF


! This is only implemented for pure TFM or pure DEM simulations.
      IF(any(species_eq(1:mmax_tot))) THEN
         IF(tfm_solids .AND. dem_solids) THEN
            WRITE(err_msg, 5000)
            CALL flush_err_msg(abort=.false.)
         ENDIF

 5000 FORMAT('Error 5000: Species equations are not available with',   &
         ' the hybrid',/'solids model. Please correct the mfix.dat',   &
         ' file.')
      ENDIF


      CALL finl_err_msg

      RETURN
      END SUBROUTINE check_solids_model_limitations