des_init_arrays.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                         !
!  Subrourtine: DES_INIT_ARRAYS                                           !
!  Author: Jay Boyalakuntla                              Date: 12-Jun-04  !
!                                                                         !
!  Purpose: Initialize arrays at the start of the simulation. Note that   !
!  arrays based on the number of particles (MAX_PIP) should be added to   !
!  the DES_INIT_PARTICLE_ARRAYS as they need to be reinitialized after    !
!  particle arrays are grown (see PARTICLE_GROW).                         !
!                                                                         !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE des_init_arrays

      USE param
      USE param1
      USE discretelement
      USE indices
      USE geometry
      USE compar
      USE physprop
      USE des_bc
      USE run
      use desgrid
      use desmpi
      USE des_thermo
      USE des_rxns

      IMPLICIT NONE

!-----------------------------------------------

      pinc(:) = zero

      p_force(:,:) = zero

      IF(allocated(drag_am)) drag_am = zero
      IF(allocated(drag_bm)) drag_bm = zero

      f_gds = zero
      vxf_gds = zero

      IF (des_continuum_hybrid) THEN
         f_sds = zero
         vxf_sds = zero
         sdrag_am = zero
         sdrag_bm = zero
      ENDIF

      grav(:) = zero

      IF(allocated(avgdes_t_s)) avgdes_t_s = zero
      IF(allocated(conv_sp))   conv_sp = zero
      IF(allocated(conv_sc))   conv_sc = zero

      CALL des_init_particle_arrays(1,max_pip)

      RETURN
      END SUBROUTINE des_init_arrays

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                         !
!  Subrourtine: DES_INIT_PARTICLE_ARRAYS                                  !
!  Author: Jay Boyalakuntla                              Date: 12-Jun-04  !
!                                                                         !
!  Purpose: Initialize particle arrays. The upper and lower bounds are    !
!  passed so that after resizing particle arrays (see GROW_PARTICLE) the  !
!  new portions of the arrays can be initialized.                         !
!                                                                         !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE des_init_particle_arrays(LB,UB)

!-----------------------------------------------
! Modules
!-----------------------------------------------
      use des_rxns
      use des_thermo
      use desgrid
      use desmpi
      use discretelement
      use functions
      use mfix_pic, only: avgsolvel_p, epg_p
      use mfix_pic, only: mppic, des_stat_wt, ps_grad
      use param1, only: zero
      use particle_filter, only: filter_cell, filter_weight
      use particle_filter, only: filter_size
      use run, only: any_species_eq
      use run, only: energy_eq
      use des_thermo_cond, only: des_qw_cond

      IMPLICIT NONE

      INTEGER, INTENT(IN) :: LB, UB
      INTEGER :: II

      iglobal_id(lb:ub) = 0

! Physical properties:
      des_radius(lb:ub) = zero
      ro_sol(lb:ub) = zero
      pvol(lb:ub) = huge(0.0)
      pmass(lb:ub) = huge(0.0)
      omoi(lb:ub) = zero

      ! Particle position, velocity, etc
      des_pos_new(lb:ub,:) = zero
      des_vel_new(lb:ub,:) = zero
      omega_new(lb:ub,:) = zero
      ppos(lb:ub,:) = zero
      IF(particle_orientation) THEN
         orientation(1,:) = init_orientation(1)
         orientation(2,:) = init_orientation(2)
         orientation(3,:) = init_orientation(3)
      ENDIF

! Particle state flag
      DO ii = lb, ub
         call set_nonexistent(ii)
      ENDDO
      neighbor_index(:) = 0

! DES grid bin information
      dg_pijk(lb:ub) = -1
      dg_pijkprv(lb:ub) = -1
      ighost_updated(lb:ub) = .false.

! Fluid cell bin information
      pijk(lb:ub,:) = 0

! Translation and rotational forces
      fc(lb:ub,:) = zero
      tow(lb:ub,:) = zero

! Collision data
      wall_collision_facet_id(:,lb:ub) = -1
      wall_collision_pft(:,:,lb:ub) = zero

! Initializing user defined array
      IF(des_usr_var_size > 0) &
         des_usr_var(:,lb:ub) = zero

! Particle center drag coefficient and explicit drag force
      f_gp(lb:ub) = zero
      drag_fc(lb:ub,:) = zero

! Interpolation variables.
      IF(filter_size > 0)THEN
         filter_cell(:,lb:ub) = -1
         filter_weight(:,lb:ub) = zero
      ENDIF

! MPPIC variables
      IF(mppic) THEN
         des_stat_wt(lb:ub) = zero
         ps_grad(:,lb:ub) = zero
         avgsolvel_p(:,lb:ub) = zero
         epg_p(lb:ub) = zero
      ENDIF

! Higher order time integration variables.
      IF (do_old) THEN
         des_pos_old(lb:ub,:) = zero
         des_vel_old(lb:ub,:) = zero
         des_acc_old(lb:ub,:) = zero
         omega_old(lb:ub,:) = zero
         rot_acc_old(lb:ub,:) = zero
      ENDIF

! Energy equation variables.
      IF(energy_eq)THEN
         des_t_s(lb:ub) = zero
         des_c_ps(lb:ub) = zero
         des_x_s(lb:ub,:) = zero

         IF(ALLOCATED(q_source)) q_source(lb:ub) = zero
         IF(ALLOCATED(conv_qs)) conv_qs(lb:ub) = zero
         IF(ALLOCATED(gammaxsa)) gammaxsa(lb:ub) = zero
         IF (intg_adams_bashforth) &
            q_source0(lb:ub) = zero
         IF (ALLOCATED(des_qw_cond)) &
            des_qw_cond(:,:) = zero
      ENDIF

! Chemical reaction variables.
      IF(any_species_eq)THEN
         des_r_s(lb:ub,:) = zero
         IF (intg_adams_bashforth) THEN
            dmdt_old(lb:ub) = zero
            dxdt_old(lb:ub,:) = zero
         ENDIF
         rxns_qs(lb:ub) = zero
      ENDIF


! Cohesion VDW forces
      IF(use_cohesion) THEN
         postcohesive(lb:ub) = zero
      ENDIF


      RETURN
      END SUBROUTINE des_init_particle_arrays