des_thermo_newvalues.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Module name: DES_THERMO_NEWVALUES                                   !
!                                                                      !
!  Purpose:                                                            !
!                                                                      !
!                                                                      !
!  Author: J.Musser                                   Date: 16-Jun-10  !
!                                                                      !
!  Comments:                                                           !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE des_thermo_newvalues

      USE compar
      Use des_thermo
      Use des_rxns
      Use discretelement
      USE geometry
      USE indices
      Use param1
      Use physprop
      use run, only: energy_eq
      use functions
      use funits, only: dmp_log
      use run, only: any_species_eq
      USE des_thermo_cond, only: des_qw_cond
      IMPLICIT NONE

! Passed variables
!-----------------------------------------------
! NONE

! Local variables
!---------------------------------------------------------------------//
! Index of neighbor particle of particle I such that I < J
      INTEGER IJK
! Loop index for particles.
      INTEGER NP, lNP
! Logical for Adams-Bashfort integration.
      LOGICAL,SAVE:: FIRST_PASS = .true.
!---------------------------------------------------------------------//

      IF(.NOT.energy_eq) RETURN

! Second-order Adams-Bashforth scheme defaults to Euler on first pass.
      IF(first_pass .AND. intg_adams_bashforth) THEN
         WHERE(particle_state(:max_pip) == normal_particle) &
            q_source0(:max_pip) = q_source(:max_pip)/       &
            (pmass(:max_pip)*des_c_ps(:max_pip))
      ENDIF
      first_pass = .false.

! First-order method
      IF (intg_euler) THEN
         WHERE(particle_state(:max_pip) == normal_particle)   &
            des_t_s(:max_pip) = des_t_s(:max_pip) +   &
            dtsolid*(q_source(:max_pip)/(pmass(:max_pip)*     &
            des_c_ps(:max_pip)))

! Second-order Adams-Bashforth scheme
      ELSE
         WHERE(particle_state(:max_pip) == normal_particle)
            des_t_s(:max_pip) = des_t_s(:max_pip) + dtsolid *         &
               (1.5d0*q_source(:max_pip) -0.5d0*q_source0(:max_pip))/ &
               (pmass(:max_pip)*des_c_ps(:max_pip))
            q_source0(:max_pip) = q_source(:max_pip)
         ENDWHERE
      ENDIF


      q_source(:) = zero
      IF(ALLOCATED(des_qw_cond)) &
         des_qw_cond(:,:) = zero

! Update particle from reactive chemistry process.
      IF(any_species_eq .AND. .NOT.des_explicitly_coupled)&
         CALL des_reaction_model

      RETURN

      END SUBROUTINE des_thermo_newvalues