get_ps.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  SUBROUTINE: GET_PS                                                  !
!  Author: J.Musser                                   Date: 19-MAR-14  !
!                                                                      !
!  Purpose: Find and validate i, j, k locations for PS's               !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE get_ps(PSV)

      USE param
      USE param1
      USE geometry
      USE ps
      USE indices
      USE funits
      USE compar

! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager

      IMPLICIT NONE

! Dummy Arguments:
!---------------------------------------------------------------------//
! Loop/variable indices
      INTEGER, INTENT(in) :: PSV

! Local Variables:
!---------------------------------------------------------------------//
! Error flag.
      INTEGER :: IER
! Calculated indices of the wall boundary
      INTEGER :: I_w , I_e , J_s , J_n , K_b , K_t
! Surface indictors
      LOGICAL :: X_CONSTANT, Y_CONSTANT, Z_CONSTANT
!......................................................................!

      CALL init_err_msg('GET_PS')

      x_constant = .true.
      y_constant = .true.
      z_constant = .true.

      IF(ps_x_w(psv)/=undefined .AND. ps_x_e(psv)/=undefined) THEN
         CALL calc_cell(xmin, ps_x_w(psv), dx, imax, i_w)
         CALL calc_cell(xmin, ps_x_e(psv), dx, imax, i_e)
         IF (ps_x_w(psv) /= ps_x_e(psv)) THEN
            x_constant = .false.
            i_w = i_w + 1
            IF(ps_i_w(psv)/=undefined_i .OR.                           &
               ps_i_e(psv)/=undefined_i) THEN
               CALL location_check(ps_i_w(psv), i_w, psv, 'PS - west')
               CALL location_check(ps_i_e(psv), i_e, psv, 'PS - east')
            ENDIF
         ENDIF
         ps_i_w(psv) = i_w
         ps_i_e(psv) = i_e
      ELSE
         IF(ps_i_w(psv) /= undefined_i)                                &
            CALL calc_loc(xmin, dx, ps_i_w(psv), ps_x_w(psv))
         IF(ps_i_e(psv) /= undefined_i)                                &
            CALL calc_loc(xmin, dx, ps_i_e(psv), ps_x_e(psv))
         IF (ps_x_w(psv) /= ps_x_e(psv)) x_constant = .false.
      ENDIF

!  If there is no variation in the I direction set indices to 1
      IF (no_i) THEN
         ps_i_w(psv) = 1
         ps_i_e(psv) = 1
      ENDIF
!
      IF (ps_y_s(psv)/=undefined .AND. ps_y_n(psv)/=undefined) THEN
         CALL calc_cell(zero, ps_y_s(psv), dy, jmax, j_s)
         CALL calc_cell(zero, ps_y_n(psv), dy, jmax, j_n)
         IF (ps_y_s(psv) /= ps_y_n(psv)) THEN
            y_constant = .false.
            j_s = j_s + 1
            IF(ps_j_s(psv)/=undefined_i .OR.                           &
               ps_j_n(psv)/=undefined_i) THEN
               CALL location_check(ps_j_s(psv), j_s, psv, 'PS - south')
               CALL location_check(ps_j_n(psv), j_n, psv, 'PS - north')
            ENDIF
         ENDIF
         ps_j_s(psv) = j_s
         ps_j_n(psv) = j_n
      ELSE
         IF(ps_j_s(psv) /= undefined_i)                                &
            CALL calc_loc(zero, dy, ps_j_s(psv), ps_y_s(psv))
         IF(ps_j_n(psv) /= undefined_i)                                &
            CALL calc_loc(zero, dy, ps_j_n(psv), ps_y_n(psv))
         IF (ps_y_s(psv) /= ps_y_n(psv)) y_constant = .false.
      ENDIF

! If there is no variation in the J direction set indices to 1
      IF (no_j) THEN
         ps_j_s(psv) = 1
         ps_j_n(psv) = 1
      ENDIF

      IF (ps_z_b(psv)/=undefined .AND. ps_z_t(psv)/=undefined) THEN
         CALL calc_cell(zero, ps_z_b(psv), dz, kmax, k_b)
         CALL calc_cell(zero, ps_z_t(psv), dz, kmax, k_t)
         IF (ps_z_b(psv) /= ps_z_t(psv)) THEN
            z_constant = .false.
            k_b = k_b + 1
            IF (ps_k_b(psv)/=undefined_i .OR.                          &
               ps_k_t(psv)/=undefined_i) THEN
               CALL location_check(ps_k_b(psv), k_b, psv, 'PS - bottom')
               CALL location_check(ps_k_t(psv), k_t, psv, 'PS - top')
            ENDIF
         ENDIF
         ps_k_b(psv) = k_b
         ps_k_t(psv) = k_t
      ELSE
         IF(ps_k_b(psv) /= undefined_i)                                &
            CALL calc_loc(zero, dz, ps_k_b(psv), ps_z_b(psv))
         IF(ps_k_t(psv) /= undefined_i)                                &
            CALL calc_loc(zero, dz, ps_k_t(psv), ps_z_t(psv))
         IF (ps_z_b(psv) /= ps_z_t(psv)) z_constant = .false.
      ENDIF

!  If there is no variation in the K direction set indices to 1
      IF (no_k) THEN
         ps_k_b(psv) = 1
         ps_k_t(psv) = 1
      ENDIF

! CHECK FOR VALID VALUES
      ier = 0
      IF(ps_i_w(psv)<1 .OR. ps_i_w(psv)>imax2) ier = 1
      IF(ps_i_e(psv)<1 .OR. ps_i_e(psv)>imax2) ier = 1
      IF(ps_j_s(psv)<1 .OR. ps_j_s(psv)>jmax2) ier = 1
      IF(ps_j_n(psv)<1 .OR. ps_j_n(psv)>jmax2) ier = 1
      IF(ps_k_b(psv)<1 .OR. ps_k_b(psv)>kmax2) ier = 1
      IF(ps_k_t(psv)<1 .OR. ps_k_t(psv)>kmax2) ier = 1
      IF(ps_k_b(psv) > ps_k_t(psv)) ier = 1
      IF(ps_j_s(psv) > ps_j_n(psv)) ier = 1
      IF(ps_i_w(psv) > ps_i_e(psv)) ier = 1

      IF(ier /= 0)THEN
         WRITE(err_msg,1101) psv,                                      &
            'X', ps_x_w(psv), ps_x_e(psv),'I',ps_i_w(psv),ps_i_e(psv), &
            'Y', ps_y_s(psv), ps_y_n(psv),'J',ps_j_s(psv),ps_j_n(psv), &
            'Z', ps_z_b(psv), ps_z_t(psv),'K',ps_k_b(psv),ps_k_t(psv)
         CALL flush_err_msg(abort=.true.)
      ENDIF

 1101 FORMAT('Error 1101: Invalid location specified for PS ',i3,'.',  &
         3(/3x,a1,': ',g12.5,',',g12.5,8x,a1,': ',i8,',',i8),/         &
         'Please correct the mfix.dat file.')

      CALL finl_err_msg

      RETURN
      END SUBROUTINE get_ps