calc_thermo_des.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Module name: CALC_THERMO_DES                                        !
!                                                                      !
!  Purpose: This subroutine is called from DES routines. It calls      !
!  functions that calculate heat and mass transfer.                    !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE calc_thermo_des

      USE compar
      USE des_rxns
      USE des_thermo
      USE discretelement
      USE fldvar
      USE functions
      USE geometry
      USE indices
      USE interpolation
      USE param1
      USE run

      IMPLICIT NONE

! Local variables
!---------------------------------------------------------------------//
      INTEGER :: NP
! Functions
!---------------------------------------------------------------------//

! This is a quick work-around to keep the thermo routines from causes
! issues while the "check_data" routines are rewritten. Moving forward
! this routine should be split apart to avoid the particle loops for
! cold-flow, non-reacting cases.
      IF(.NOT.energy_eq .AND. .NOT.any_species_eq) RETURN

! Calculate time dependent physical properties
      FORALL(np=1:max_pip, particle_state(np)==normal_particle) &
         des_c_ps(np) = calc_cp_des(np)

      IF(des_explicitly_coupled) THEN
! Apply the convective heat transfer calculated by the gas phase.
         IF(calc_conv_des) THEN
            WHERE(particle_state == normal_particle) &
               q_source = q_source + conv_qs
         ENDIF
         IF(any_species_eq) THEN
            WHERE(particle_state == normal_particle) &
               q_source = q_source + rxns_qs
         ENDIF
      ELSE
         IF(calc_conv_des)CALL conv_gs_des1
         IF(any(calc_radt_des)) CALL des_radiation
         IF(any_species_eq) CALL rxns_gs_des1
      ENDIF

      END SUBROUTINE calc_thermo_des