des_thermo_rad.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Module name: DES_RADIATION                                          !
!                                                                      !
!  Purpose:                                                            !
!                                                                      !
!  Author: J.Musser                                   Date: 25-Jun-10  !
!                                                                      !
!  Commen:                                                             !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE des_radiation

      USE constant
      USE des_thermo
      USE discretelement
      USE fldvar
      USE param1
      USE physprop, only: smax
      USE toleranc
      use functions, only: fluid_at
      use functions, only: is_normal
      IMPLICIT NONE

! Passed variables
!---------------------------------------------------------------------//
! Global index of particle
      INTEGER :: NP
! Solid phase of particle I
      INTEGER :: lM
! Fluid cell index containing particle I
      INTEGER :: IJK

! Local variables
!---------------------------------------------------------------------//
! Environment temperature
      DOUBLE PRECISION :: Tenv
! SB constant TIMES particle surface area
      DOUBLE PRECISION :: SBx4Pi
      INTEGER, PARAMETER :: lUpdateFreq=5
      INTEGER, SAVE :: lUpdate_avgTs=0
!......................................................................!


! Coupled simulations update the average solids temperature at the start
! of the DEM time march. Granular flow (no gas) simulations update the
! average solids temperature every "lUpdateFreq" time steps.
      IF(.NOT.des_continuum_coupled) THEN
         IF(mod(lupdate_avgts,lupdatefreq) == 0) THEN
            CALL particles_in_cell
            CALL calc_avgts
            lupdate_avgts = 0
         ELSE
            lupdate_avgts = lupdate_avgts + 1
         ENDIF
      ENDIF

      sbx4pi = sb_const*4.0d0*pi

      DO np=1,max_pip
         IF(is_normal(np)) THEN
            lm = pijk(np,5)
            IF(calc_radt_des(lm)) THEN

               ijk = pijk(np,4)
               IF(fluid_at(ijk)) THEN
                  tenv = ep_g(ijk)*t_g(ijk) + &
                     (one-ep_g(ijk))*avgdes_t_s(ijk)
               ELSE
                  tenv = avgdes_t_s(ijk)
               ENDIF
! Calculate the heat source.
               q_source(np) = q_source(np) + des_em(lm)* sbx4pi * &
                  (des_radius(np)**2)*(tenv**4 - des_t_s(np)**4)
! Update the thermal source term.
            ENDIF
         ENDIF
      ENDDO

      RETURN
      END SUBROUTINE des_radiation

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Module name: CALC_avgTs                                             !
!  Author: J.Musser                                   Date: 06-NOV-12  !
!                                                                      !
!  Purpose:                                                            !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE calc_avgts

      USE compar
      USE derived_types, only: pic
      USE des_rxns
      USE des_thermo
      USE discretelement
      USE functions
      USE geometry
      USE indices
      USE param1
      USE physprop
      USE run, only: energy_eq

      IMPLICIT NONE

! Passed variables
!-----------------------------------------------
! NONE

! Local variables
!---------------------------------------------------------------------//
! Index of neighbor particle of particle I such that I < J
      INTEGER :: IJK
! Loop index for particles.
      INTEGER :: NP, lNP
! Sum of particle temperatures in fluid cell.
      DOUBLE PRECISION :: SUM_T_s
      INTEGER, SAVE :: PASS=0
!---------------------------------------------------------------------//

      IF(.NOT.energy_eq) RETURN

! Loop over fluid cells.
      ijk_lp: DO ijk = ijkstart3, ijkend3

         avgdes_t_s(ijk) = zero
         IF(.NOT.fluid_at(ijk)) cycle ijk_lp

         IF(pinc(ijk) > 0) THEN
! Initialize local solids temperature.
            sum_t_s = zero
! Loop over all particles in cell IJK.
            lnp_lp: DO lnp = 1, pinc(ijk)
               np = pic(ijk)%p(lnp)
! Update the sum of particle temperatures in fluid cell IJK.
               IF(is_normal(np)) sum_t_s = sum_t_s + des_t_s(np)
            ENDDO lnp_lp

! Average solids temperature in fluid cell IJK. The average method
! (over particles) will need changed for Hybrid model (mass? volume?).
            avgdes_t_s(ijk) = sum_t_s/pinc(ijk)
         ENDIF
      ENDDO ijk_lp

      RETURN
      END SUBROUTINE calc_avgts