check_data_20.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Subroutine: CHECK_DATA_20                                           C
!  Purpose:                                                            C
!     - check whether field variables are initialized in all cells     C
!     - check whether the sum of void and volume fractions is 1.0      C
!       in all fluid and mass inflow cells                             C
!     - check whether mu_gmax is specified if k_epsilon or l_scale     C
!                                                                      C
!  Author: M. Syamlal                                 Date: 30-JAN-92  C
!  Reviewer: P. Nicoletti, W. Rogers, S. Venkatesan   Date: 31-JAN-92  C
!                                                                      C
!  Revision Number:                                                    C
!  Purpose:                                                            C
!  Author:                                            Date: dd-mmm-yy  C
!  Reviewer:                                          Date: dd-mmm-yy  C
!                                                                      C
!  Literature/Document References:                                     C
!                                                                      C
!  Variables referenced:                                               C
!  Variables modified:                                                 C
!  Local variables:                                                    C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C

      SUBROUTINE check_data_20

!-----------------------------------------------
! Modules
!-----------------------------------------------
      USE param
      USE param1
      USE toleranc
      USE fldvar
      USE run
      USE geometry
      USE constant
      USE physprop
      USE indices
      USE funits
      USE visc_g
      USE rxns
      USE scalars
      USE compar
      USE sendrecv
      USE discretelement
      USE mfix_pic
      USE functions

      use mpi_utility
      use error_manager

      IMPLICIT NONE

!-----------------------------------------------
! Local variables
!-----------------------------------------------
! Indices
      INTEGER :: I, J, K, IJK, IMJK, IJMK, IJKM
! Solids phase
      INTEGER :: M
! Species index
      INTEGER :: NN
! Logical variable to set, if there is an error
      LOGICAL :: ABORT
! Whether L_scale is nonzero
      LOGICAL :: NONZERO
! 1.0 - sum of all volume fractions
      DOUBLE PRECISION DIF
!-----------------------------------------------

      CALL init_err_msg("CHECK_DATA_20")

      call send_recv(p_g,2)
      call send_recv(ep_g,2)
      call send_recv(w_s,2)
      call send_recv(w_g,2)
      call send_recv(u_s,2)
      call send_recv(u_g,2)
      call send_recv(v_s,2)
      call send_recv(v_g,2)
      call send_recv(ro_s,2)
      call send_recv(rop_s,2)
      call send_recv( p_star, 2 )
      call send_recv( rop_g, 2 )
      call send_recv( ro_g, 2 )
      call send_recv( t_g, 2 )
      call send_recv( t_s, 2 )
      call send_recv( x_g, 2 )
      call send_recv( x_s, 2 )
      IF(granular_energy) call send_recv( theta_m, 2 )

      abort = .false.

! Check whether all field variables are initialized in all fluid cells
! and flow boundary cells
! ---------------------------------------------------------------->>>
      DO k = kstart2, kend2
      DO j = jstart2, jend2
      DO i = istart2, iend2
         ijk = funijk(i,j,k)
         IF (.NOT.wall_at(ijk)) THEN

            imjk = im_of(ijk)
            ijmk = jm_of(ijk)
            ijkm = km_of(ijk)

! check gas phase fields
            IF(ep_g(ijk) == undefined) &
               CALL report_error(abort, i, j, k, 'EP_G')
            IF(p_g(ijk) == undefined) &
               CALL report_error(abort, i, j, k, 'P_G')
            IF(p_star(ijk) == undefined) &
               CALL report_error(abort, i, j, k, 'P_STAR')
            IF(ro_g(ijk) == undefined) &
               CALL report_error(abort, i, j, k, 'RO_G')
            IF(rop_g(ijk) == undefined) &
               CALL report_error(abort, i, j, k, 'ROP_G')

            IF(u_g(ijk) == undefined) &
               CALL report_error(abort, i, j, k, 'U_G')
            IF(v_g(ijk) == undefined) &
               CALL report_error(abort, i, j, k, 'V_G')
            IF(w_g(ijk) == undefined) &
               CALL report_error(abort, i, j, k, 'W_G')

            IF(u_g(imjk) == undefined) &
               CALL report_error(abort, i-1, j, k, 'U_G')
            IF(v_g(ijmk) == undefined) &
               CALL report_error(abort, i, j-1, k, 'V_G')
            IF(w_g(ijkm) == undefined) &
               CALL report_error(abort, i, j, k-1, 'W_G')

            IF(t_g(ijk) == undefined) THEN
               IF(energy_eq .OR. ro_g0==undefined .OR. &
                  mu_g0==undefined) &
                  CALL report_error(abort, i, j, k, 'T_G')
            ENDIF

            IF(species_eq(0) .OR. ro_g0==undefined .AND. &
               mw_avg==undefined) THEN
               DO nn = 1, nmax(0)
                  IF(x_g(ijk,nn) == undefined) &
                     CALL report_error(abort, i, j, k, 'X_G',nn)
               ENDDO
            ENDIF

            DO nn = 1, nscalar
              IF(scalar(ijk,nn) == undefined) &
                 CALL report_error(abort, i, j, k, 'SCALAR',nn)
            ENDDO

! check solids phase fields. these quantities are specified via the
! subroutines set_ic and set_bc0/set_bc1 that employ the initial and
! boundary conditions set in the mfix.dat.
            DO m = 1, smax

              IF (ro_s(ijk,m) == undefined) &
                 CALL report_error(abort, i, j, k, 'RO_S',m)

              IF (rop_s(ijk,m) == undefined) &
                 CALL report_error(abort, i, j, k, 'ROP_S',m)

              IF (u_s(ijk,m)==undefined .AND. i/=imax2) &
                 CALL report_error(abort, i, j, k, 'U_S',m)
              IF (v_s(ijk,m)==undefined .AND. j/=jmax2) &
                 CALL report_error(abort, i, j, k, 'V_S',m)
              IF (w_s(ijk,m)==undefined .AND. k/=kmax2) &
                 CALL report_error(abort, i, j, k, 'W_S',m)

              IF (u_s(imjk,m) == undefined) &
                 CALL report_error(abort, i, j, k, 'U_S',m)
              IF (v_s(ijmk,m) == undefined) &
                 CALL report_error(abort, i, j, k, 'V_S',m)
              IF (w_s(ijkm,m) == undefined) &
                 CALL report_error(abort, i, j, k, 'W_S',m)

              IF (t_s(ijk,m) == undefined) THEN
                 IF (energy_eq) &
                    CALL report_error(abort, i, j, k, 'T_S',m)
              ENDIF

              IF (species_eq(m)) THEN
                 DO nn = 1, nmax(m)
                    IF(x_s(ijk,m,nn) == undefined) &
                       CALL report_error(abort, i, j, k, 'X_S', m, nn)
                 ENDDO
              ENDIF
           ENDDO   ! end do m=1,smax

         ENDIF  ! IF (.NOT.WALL_AT(IJK)) THEN
      ENDDO  ! end do I = istart2, iend2
      ENDDO  ! end do J = jstart2, jend2
      ENDDO  ! end do K = kstart2, kend2


      CALL global_all_or(abort)
      IF(abort) THEN
         WRITE(err_msg, 2000)
         CALL flush_err_msg(header=.false., abort=.true.)
         CALL finl_err_msg
         RETURN
      ENDIF


! Additional check for fluid or mass inflow cells
! --------------------------------------------------------------------//
      nonzero = .false.

      DO k = kstart2, kend2
      DO j = jstart2, jend2
      DO i = istart2, iend2
         ijk = funijk(i,j,k)

         IF (flag(ijk)==1 .OR. flag(ijk)==20) THEN

! Check whether L_scale is non-zero anywhere
            IF (l_scale(ijk) /= zero) nonzero = .true.

! Ep_g must have a value > 0 and < 1
            IF(ep_g(ijk) < small_number .OR. ep_g(ijk) > one) &
               CALL report_unphysical(abort, i, j, k, 'EP_G', ep_g(ijk))

! Check the sum of volume fractions. This is skipped for DES as the
! solids volume fractions may not yet be calculated.
            IF(.NOT.discrete_element .AND. smax>0) THEN
               dif = one - ep_g(ijk)
               dif = dif - sum(rop_s(ijk,:mmax)/ro_s(ijk,:mmax))
               IF (abs(dif) > small_number) CALL report_unphysical( &
                  abort, i, j, k, 'Volume Fraction SUM', 1.0-dif)
            ENDIF
         ENDIF   ! IF (FLAG(IJK)==1 .OR. FLAG(IJK)==20) THEN
      ENDDO   ! I = istart2, iend2
      ENDDO   ! J = jstart2, jend2
      ENDDO   ! K = kstart2, kend2


      CALL global_all_or(abort)
      IF(abort) THEN
         WRITE(err_msg, 2000)
         CALL flush_err_msg(header=.false., abort=.true.)
         CALL finl_err_msg
         RETURN
      ENDIF

!  Check whether MU_gmax is specified
      CALL global_all_or(nonzero)
      IF (nonzero .AND. mu_gmax==undefined) THEN
         WRITE(err_msg, 1300)
         CALL flush_err_msg(abort=.true.)
         CALL finl_err_msg
      ENDIF

 1300 FORMAT('Error 1300: Message: Turbulent length scale is nonzero.',&
         /'Specify MU_gmax in the mfix.dat file.')

      CALL finl_err_msg
      RETURN

 2000 FORMAT('Please correct the mfix.dat file.')



      CONTAINS


      SUBROUTINE report_error(ABORT, pI, pJ, pK, VAR, LC1, LC2)

      LOGICAL, INTENT(INOUT) :: ABORT
      INTEGER, INTENT(IN) :: pI, pJ, pK
      CHARACTER(LEN=*), INTENT(IN) :: VAR
      INTEGER, INTENT(IN), OPTIONAL :: LC1, LC2
      CHARACTER(LEN=32) :: VAR_FULL

      var_full=''
      IF(PRESENT(lc2)) THEN
         var_full = ivar(var,lc1,lc2)
      ELSEIF(PRESENT(lc1)) THEN
         var_full = ivar(var,lc1)
      ELSE
         var_full = var
      ENDIF

      IF(.NOT.abort) THEN
         WRITE(err_msg,1000)
         CALL flush_err_msg(footer=.false.)
         abort = .true.
      ENDIF

 1000 FORMAT('Error 1000: The following field variables are undefined')


      WRITE(err_msg, 1010) i, j, k, trim(var_full)
      CALL flush_err_msg(header=.false., footer=.false.)

 1010 FORMAT(1x,'I = ',i6,' J = ',i6,' K = ',i6,5x,a)



      END SUBROUTINE report_error

      SUBROUTINE report_unphysical(ABORT, pI, pJ, pK, VAR, VALUE)

      LOGICAL, INTENT(INOUT) :: ABORT
      INTEGER, INTENT(IN) :: pI, pJ, pK
      CHARACTER(LEN=*), INTENT(IN) :: VAR
      DOUBLE PRECISION, INTENT(IN) :: VALUE

      IF(.NOT.abort) THEN
         WRITE(err_msg,1100)
         CALL flush_err_msg(footer=.false.)
         abort = .true.
      ENDIF

 1100 FORMAT('Error 1100: The following field variables are ',&
         'out of range')

      WRITE(err_msg, 1110) i, j, k, trim(var), VALUE
      CALL flush_err_msg(header=.false., footer=.false.)

 1110 FORMAT(1x,'I = ',i6,' J = ',i6,' K = ',i6,2x,a,'Value:',g11.4)


      END SUBROUTINE report_unphysical


      END SUBROUTINE check_data_20