check_bc_inflow.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
! Subroutine: CHECK_BC_INFLOW                                          !
! Author: J.Musser                                    Date: 01-Mar-14  !
!                                                                      !
! Purpose: Provided a detailed error message on common inflow BC       !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_bc_inflow(M_TOT, SKIP, BCV)

! Modules
!---------------------------------------------------------------------//
      use bc, only: bc_x_g, bc_x_s
      use bc, only: bc_t_g, bc_t_s, bc_theta_m
      use bc, only: bc_k_turb_g, bc_e_turb_g
      use bc, only: bc_scalar
      use param, only: dim_m
      use param1, only: undefined, one, zero
      use physprop, only: inert_species
      use physprop, only: mu_g0
      use physprop, only: mw_avg, nmax
      use physprop, only: ro_g0
      use run, only: energy_eq, granular_energy, k_epsilon
      use run, only: solids_model, solve_ros, species_eq
      use scalars, only: nscalar
      use toleranc, only: compare

      use error_manager
      IMPLICIT NONE

! Dummy arguments
!---------------------------------------------------------------------//
      INTEGER, INTENT(in) :: BCV
      INTEGER, INTENT(in) :: M_TOT
      LOGICAL, INTENT(in) :: SKIP(dim_m)

! Local variables
!---------------------------------------------------------------------//
! loop/variable indices
      INTEGER :: M, N
      DOUBLE PRECISION SUM_X
! Index of inert species
      INTEGER :: INERT
!---------------------------------------------------------------------//

      CALL init_err_msg("CHECK_BC_INFLOW")

! Check temperature dependency.
      IF((energy_eq .OR. ro_g0==undefined .OR.mu_g0==undefined) .AND. &
         bc_t_g(bcv)==undefined) THEN
         WRITE(err_msg, 1000) trim(ivar('BC_T_g',bcv))
         CALL flush_err_msg(abort=.true.)
      ENDIF

! Sum together defined gas phase species mass fractions.
      sum_x = zero
      DO n = 1, nmax(0)
         IF(bc_x_g(bcv,n) /= undefined) THEN
            sum_x = sum_x + bc_x_g(bcv,n)
         ELSE
            bc_x_g(bcv,n) = zero
         ENDIF
      ENDDO

! Enforce that the species mass fractions must sum to one.
      IF(.NOT.compare(one,sum_x)) THEN

         IF(species_eq(0)) THEN
            WRITE(err_msg, 1110) bcv
            CALL flush_err_msg(abort=.true.)
 1110 FORMAT('Error 1110: BC_X_g(',i3,',:) do NOT sum to ONE and the ',&
         'gas phase',/'species equations are solved. Please correct ', &
         'the mfix.dat file.')

         ELSEIF(ro_g0 == undefined .AND. mw_avg == undefined) THEN
            WRITE(err_msg, 1111) bcv
            CALL flush_err_msg(abort=.true.)
 1111 FORMAT('Error 1111: BC_X_g(',i3,',:) do NOT sum to ONE and the ',&
         'gas phase',/'is compressible and MW_AVG is UNDEFINED.',/     &
         'Please correct the mfix.dat the mfix.dat file.')

         ELSEIF(.NOT.compare(sum_x,zero)) THEN
            WRITE(err_msg, 1112) bcv
            CALL flush_err_msg(abort=.true.)
 1112 FORMAT('Error 1112: BC_X_g(',i3,',:) do not sum to ONE or ZERO ',&
         'and they',/'are not needed. Please correct the mfix.dat ',   &
         'the mfix.dat file.')

         ELSE
            bc_x_g(bcv,:) = zero
            bc_x_g(bcv,1) = one
         ENDIF
      ENDIF


! Verify that species mass fractions are defined for mass flow BCs when
! using variable solids density. Needed to calculation RO_s
      DO m = 1, m_tot

! If this phase is not present, clear out x_s for the BC and
! cycle the solids loop. No need to continue checks.
         IF(skip(m)) THEN
           IF(species_eq(m))THEN
               bc_x_s(bcv,m,:) = zero
               bc_x_s(bcv,m,1) = one
            ENDIF
            cycle
         ENDIF

! Sum together defined species mass fractions.
         sum_x = zero
         DO n = 1, nmax(m)
            IF(bc_x_s(bcv,m,n) /= undefined) THEN
               sum_x = sum_x + bc_x_s(bcv,m,n)
            ELSE
               bc_x_s(bcv,m,n) = zero
            ENDIF
         ENDDO

! Enforce that the species mass fractions must sum to one.
         IF(.NOT.compare(one,sum_x)) THEN
            IF(species_eq(m)) THEN
               WRITE(err_msg, 1210) bcv, m
               CALL flush_err_msg(abort=.true.)
 1210 FORMAT('Error 1210: BC_X_s(',i3,',',i2,':) do NOT sum to ONE ',  &
         'and the solids phase',/'species equations are solved. ',     &
         'Please correct the mfix.dat file.')

            ELSEIF(solve_ros(m)) THEN
               WRITE(err_msg, 1211) bcv, m
               CALL flush_err_msg(abort=.true.)
 1211 FORMAT('Error 1211: BC_X_s(',i3,',',i2,':) do NOT sum to ONE ',  &
         'and the solids phase',/'density is calculated. Please ',     &
         'correct the mfix.dat file.')

            ELSEIF(.NOT.compare(sum_x,zero)) THEN
               WRITE(err_msg, 1212) bcv, m
               CALL flush_err_msg(abort=.true.)
 1212 FORMAT('Error 1212: BC_X_s(',i3,',',i2,':) do NOT sum to ONE ',  &
         'or ZERO and',/'they are not needed. Please correct the ',    &
         'mfix.dat file.')

            ELSE
               bc_x_s(bcv,m,:) = zero
               bc_x_s(bcv,m,1) = one
            ENDIF
         ENDIF

! Set the solids density for the BC region.
         IF(solve_ros(m)) THEN
! Verify that the species mass fraction for the inert material is not
! zero in the IC region when the solids is present.
            inert = inert_species(m)
            IF(bc_x_s(bcv,m,inert) == zero) THEN
               WRITE(err_msg,1213) m, bcv
               CALL flush_err_msg(abort=.true.)
 1213 FORMAT('Error 1213: No inert species for phase ',i2,' in BC ',   &
         'region',i3,'.',/'Unable to calculate solids phase density. ',&
         'Please refer to the Readme',/' file for required variable ', &
         'solids density model input parameters and',/' make the ',   &
         'necessary corrections to the mfix.dat file.')

            ENDIF
         ENDIF
      ENDDO


      DO m = 1, m_tot
! Check solids phase temperature dependency.
         IF(energy_eq .AND. bc_t_s(bcv,m)==undefined) THEN
            IF(skip(m)) THEN
               bc_t_s(bcv,m) = bc_t_g(bcv)
            ELSE
               WRITE(err_msg, 1000) trim(ivar('BC_T_s',bcv,m))
               CALL flush_err_msg(abort=.true.)
            ENDIF
         ENDIF

! Check granular energy dependency
         IF(granular_energy) THEN
            IF(bc_theta_m(bcv,m) == undefined) THEN
               IF(skip(m) .OR. solids_model(m) /= 'TFM') THEN
                  bc_theta_m(bcv,m) = zero
               ELSE
                  WRITE(err_msg,1000) trim(ivar('BC_Theta_m',bcv,m))
                  CALL flush_err_msg(abort=.true.)
               ENDIF
            ENDIF
         ENDIF
      ENDDO

! Check K-Epsilon BCs.
      IF(k_epsilon) THEN
         IF(bc_k_turb_g(bcv) == undefined) THEN
            WRITE(err_msg, 1000) trim(ivar('BC_K_Turb_G',bcv))
            CALL flush_err_msg(abort=.true.)

         ELSEIF(bc_e_turb_g(bcv) == undefined) THEN
            WRITE(err_msg, 1000) trim(ivar('BC_E_Turb_G',bcv))
            CALL flush_err_msg(abort=.true.)
         ENDIF
      ENDIF

! Check scalar equation BCs.
      DO n = 1, nscalar
         IF(bc_scalar(bcv,n) == undefined) THEN
            WRITE(err_msg, 1001) trim(ivar('BC_Scalar',bcv,n))
            CALL flush_err_msg(abort=.true.)
         ENDIF
      ENDDO

      CALL finl_err_msg

      RETURN

 1000 FORMAT('Error 1000: Required input not specified: ',a,/'Please ',&
         'correct the mfix.dat file.')

 1001 FORMAT('Error 1001: Illegal or unknown input: ',a,' = ',a,/   &
         'Please correct the mfix.dat file.')

      END SUBROUTINE check_bc_inflow


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
! Subroutine: CHECK_BC_MASS_INFLOW                                     !
! Author: J.Musser                                    Date: 01-Mar-14  !
!                                                                      !
! Purpose: Provided a detailed error message on BC                     !
!                                                                      !
! Comments:                                                            !
!     The velocities at the inflow face are fixed and the momentum     !
!     equations are not solved in the inflow cells. Since the flow is  !
!     into the domain all other scalars that are used need to be       !
!     specified (e.g., mass fractions, void fraction, etc.,)           !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_bc_mass_inflow(M_TOT, SKIP, BCV)

! Modules
!---------------------------------------------------------------------//
      use bc, only: bc_ep_g, bc_p_g
      use bc, only: bc_rop_s, bc_ep_s, bc_x_s
      use bc, only: bc_massflow_g
      use eos, only: eoss
      use param, only: dim_m
      use param1, only: undefined, one, zero
      use physprop, only: ro_g0, ro_s0
      use physprop, only: inert_species, x_s0
      use run, only: solve_ros
      use toleranc, only: compare
      use error_manager
      IMPLICIT NONE

! Dummy arguments
!---------------------------------------------------------------------//
      INTEGER, INTENT(in) :: BCV
      INTEGER, INTENT(in) :: M_TOT
      LOGICAL, INTENT(in) :: SKIP(dim_m)

! Local variables
!---------------------------------------------------------------------//
! loop/variable indices
      INTEGER :: M
      DOUBLE PRECISION :: SUM_EP
! Solids phase density in BC region.
      DOUBLE PRECISION :: BC_ROs(dim_m)
! Index of inert species
      INTEGER :: INERT

!---------------------------------------------------------------------//

      CALL init_err_msg("CHECK_BC_MASS_INFLOW")

! Check gas phase volume fraction.
      IF(bc_ep_g(bcv) == undefined) THEN
         WRITE(err_msg, 1000) trim(ivar('BC_EP_g',bcv))
         CALL flush_err_msg(abort=.true.)
      ENDIF

! Verify compressible boundary condition variables.
      IF(ro_g0 == undefined) THEN
         IF(bc_p_g(bcv) == undefined) THEN
            IF(bc_massflow_g(bcv) /= undefined .AND.                   &
               bc_massflow_g(bcv) /= zero) THEN
               WRITE(err_msg, 1100) trim(ivar('BC_P_g',bcv))
               CALL flush_err_msg(abort=.true.)
            ENDIF
 1100 FORMAT('Error 1100: ',a,' must be specified for compressible ',  &
         'flows',/'when specifying BC_MASSFLOW_g to make the ',        &
         'conversion to velocity.',/'Please correct the mfix.dat file.')

         ELSEIF(bc_p_g(bcv) <= zero) THEN
            WRITE(err_msg, 1101) bcv, trim(ival(bc_p_g(bcv)))
            CALL flush_err_msg(abort=.true.)
         ENDIF
 1101 FORMAT('Error 1101: Pressure must be greater than zero for ',    &
         'compressible flow',/' >>>  BC_P_g(',i3,') = ',a,/'Please ',  &
         'correct the mfix.dat file.')
      ENDIF

! Calculate the solids volume fraction from the gas phase if there is
! only one solids phase.
      IF(m_tot == 1 .AND. bc_ep_s(bcv,1) == undefined) THEN
         bc_ep_s(bcv,1) = one - bc_ep_g(bcv)
      ENDIF

! Bulk density or solids volume fraction must be explicitly defined
! if there are more than one solids phase.
      IF(m_tot > 1 .AND. .NOT.compare(bc_ep_g(bcv),one)) THEN
         DO m = 1, m_tot
            IF(bc_rop_s(bcv,m) == undefined .AND. &
               bc_ep_s(bcv,m) == undefined) THEN
               WRITE(err_msg, 1200) m, bcv, 'BC_ROP_s and BC_EP_s'
               CALL flush_err_msg(abort=.true.)
            ENDIF
         ENDDO
      ENDIF
 1200 FORMAT('Error 1200: Insufficient solids phase ',i2,' data ',     &
         'for BC',i3,'. ',/a,' not specified.',/'Please correct the ', &
         'mfix.dat file.')

! Initialize the sum of the total volume fraction.
      sum_ep = bc_ep_g(bcv)
      DO m = 1, m_tot

! If this phase is not present, clear out EPs and ROPs for the BC and
! cycle the solids loop. No need to continue checks.
         IF(skip(m)) THEN
            bc_ep_s(bcv,m)  = zero
            bc_rop_s(bcv,m) = zero
            cycle
         ENDIF

! Set the solids density for the BC region.
         IF(.NOT.solve_ros(m)) THEN
            bc_ros(m) = ro_s0(m)
         ELSE
! presence of non-zero inert species is checked by bc_inflow
            inert = inert_species(m)
            bc_ros(m) = eoss(ro_s0(m), x_s0(m,inert),&
               bc_x_s(bcv,m,inert))
         ENDIF

! If both input parameters are defined. Make sure they are equivalent.
         IF(bc_rop_s(bcv,m) /= undefined .AND.                         &
            bc_ep_s(bcv,m) /= undefined) THEN

            IF(.NOT.compare(bc_ep_s(bcv,m)*bc_ros(m),                  &
               bc_rop_s(bcv,m))) THEN
               WRITE(err_msg,1214) bcv
               CALL flush_err_msg(abort=.true.)
            ENDIF
 1214 FORMAT('Error 1214: Illegal initial condition region : ',i3,/    &
         'BC_EP_s and BC_ROP_s are inconsistent. Please correct the ',/&
         'mfix.dat file.')

! Compute BC_EP_s from BC_ROP_s
         ELSEIF(bc_ep_s(bcv,m) == undefined) THEN
            bc_ep_s(bcv,m) = bc_rop_s(bcv,m) / bc_ros(m)

! Compute BC_ROP_s from BC_EP_s and BC_ROs
         ELSEIF(bc_rop_s(bcv,m) == undefined) THEN
            bc_rop_s(bcv,m) = bc_ep_s(bcv,m) * bc_ros(m)

         ENDIF
! Add this phase to the total volume fraction.
         sum_ep = sum_ep + bc_ep_s(bcv,m)
      ENDDO

! Verify that the volume fractions sum to one.
      IF(.NOT.compare(sum_ep,one)) THEN
         WRITE(err_msg,1215) bcv, trim(ival(sum_ep))
         CALL flush_err_msg(abort=.true.)
      ENDIF
 1215 FORMAT('Error 1215: Illegal boundary condition region: ',i3,'. ',&
         'Sum of volume',/'fractions does NOT equal ONE. (SUM = ',a,   &
         ')',/'Please correct the mfix.dat file.')

      CALL finl_err_msg

      RETURN

 1000 FORMAT('Error 1000: Required input not specified: ',a,/'Please ',&
         'correct the mfix.dat file.')

 1001 FORMAT('Error 1001: Illegal or unknown input: ',a,' = ',a,/   &
         'Please correct the mfix.dat file.')

      END SUBROUTINE check_bc_mass_inflow


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
! Subroutine: CHECK_BC_P_INFLOW                                        !
! Author: J.Musser                                    Date: 01-Mar-14  !
!                                                                      !
! Purpose: Provided detailed error message on bc                       !
!                                                                      !
! Comments:                                                            !
!     Unlike the MI boundary, for the PI boundary the velocities at    !
!     the inflow face are calculated by solving the momentum eqns      !
!     and are not fixed. In this way, the PI is similar to the PO      !
!     except that the flow is into the domain and hence all other      !
!     scalars (e.g., mass fractions, void fraction, temperature,       !
!     etc.,) at the inflow cells need to be specified. To satisfy      !
!     the error routines at the start of the simulation, both the      !
!     tangential and normal components at the inflow also need to      !
!     be specified. The velocities values essentially serve as IC.     !
!                                                                      !
!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
      SUBROUTINE check_bc_p_inflow(M_TOT, SKIP, BCV)

! Modules
!---------------------------------------------------------------------//
      use bc, only: bc_p_g, bc_rop_s
      use bc, only: bc_u_g, bc_v_g, bc_w_g
      use bc, only: bc_u_s, bc_v_s, bc_w_s
      use geometry, only: no_i, no_j, no_k
      use param, only: dim_m
      use param1, only: undefined, zero
      use physprop, only: ro_g0
      use error_manager
      IMPLICIT NONE

! Dummy arguments
!---------------------------------------------------------------------//
      INTEGER, INTENT(in) :: BCV
      INTEGER, INTENT(in) :: M_TOT
      LOGICAL, INTENT(in) :: SKIP(dim_m)

! Local variables
!---------------------------------------------------------------------//
      INTEGER :: M

!---------------------------------------------------------------------//

      CALL init_err_msg("CHECK_BC_P_INFLOW")

! Remove checks on bc_ep_g/bc_rop_s; using routine check_bc_outflow

      IF (bc_p_g(bcv) == undefined) THEN
         WRITE(err_msg,1000) 'BC_P_g', bcv
         CALL flush_err_msg(abort=.true.)
 1000 FORMAT('Error 1000: Required input not specified: ',a,/'Please ',&
         'correct the mfix.dat file.')

      ELSEIF (bc_p_g(bcv)<=zero .AND. ro_g0==undefined) THEN
         WRITE(err_msg, 1101) bcv, trim(ival(bc_p_g(bcv)))
         CALL flush_err_msg(abort=.true.)
 1101 FORMAT('Error 1101: Pressure must be greater than zero for ',    &
         'compressible flow',/' >>>  BC_P_g(',i3,') = ',a,/'Please ',  &
         'correct the mfix.dat file.')
      ENDIF

! Check that velocities are also specified. These are essentially used
! as initial conditions for the boundary region. If they are not
! specified then a default value is set here otherwise check_data_20
! will complain and cause MFIX to exit.
      IF(bc_u_g(bcv) == undefined) THEN
         bc_u_g(bcv) = zero
         IF(.NOT.no_i) WRITE(err_msg, 1300) trim(ivar('BC_U_g',bcv))
      ENDIF

      IF(bc_v_g(bcv) == undefined) THEN
         bc_v_g(bcv) = zero
         IF(.NOT.no_j) WRITE(err_msg, 1300) trim(ivar('BC_V_g',bcv))
      ENDIF

      IF(bc_w_g(bcv) == undefined) THEN
         bc_w_g(bcv) = zero
         IF(.NOT.no_k) WRITE(err_msg, 1300) trim(ivar('BC_W_g',bcv))
      ENDIF

      DO m = 1, m_tot
         IF (skip(m)) THEN
            bc_u_s(bcv,m) = zero
            bc_v_s(bcv,m) = zero
            bc_w_s(bcv,m) = zero
         ELSE
            IF(bc_u_s(bcv,m) == undefined) THEN
               bc_u_s(bcv,m) = zero
               IF(bc_rop_s(bcv,m) /= zero .AND. .NOT.no_i) &
                  WRITE(err_msg, 1300) trim(ivar('BC_U_s',bcv,m))
            ENDIF

            IF(bc_v_s(bcv,m) == undefined) THEN
               bc_v_s(bcv,m) = zero
               IF(bc_rop_s(bcv,m) /= zero .AND. .NOT.no_j) &
                  WRITE(err_msg, 1300) trim(ivar('BC_V_s',bcv,m))
            ENDIF

            IF(bc_w_s(bcv,m) == undefined) THEN
               bc_w_s(bcv,m) = zero
               IF(bc_rop_s(bcv,m) /= zero .AND. .NOT.no_k) &
                  WRITE(err_msg, 1300) trim(ivar('BC_W_s',bcv,m))
            ENDIF
         ENDIF
      ENDDO

 1300 FORMAT('Warning 1300: ',a,' was undefined. This variable was ', &
         'set ',/ 'to zero to be used as the initial value in the BC ',&
         'region.')

      CALL finl_err_msg

      RETURN
      END SUBROUTINE check_bc_p_inflow