check_point_sources.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  SUBROUTINE: CHECK_POINT_SOURCES                                     !
!  Author: J. Musser                                  Date: 10-JUN-13  !
!                                                                      !
!  Purpose: Check point source specifications.                         !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_point_sources

! Global Variables:
!---------------------------------------------------------------------//
! Flag: PS geometry was detected.
      use ps, only: ps_defined

! Global Parameters:
!---------------------------------------------------------------------//
! Maximum number of PS.
      use param, only: dimension_ps

! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager

      implicit none

! Local Variables:
!---------------------------------------------------------------------//
! Loop counter for BCs
      INTEGER :: PSV
!......................................................................!


! Initialize the error manager.
      CALL init_err_msg("CHECK_POINT_SOURCES")

! Determine which PSs are DEFINED
      CALL check_ps_geometry

! Loop over all PS arrays.
      DO psv = 1, dimension_ps

! Verify user input for defined defined PS.
         IF(ps_defined(psv)) THEN
            CALL get_ps(psv)
            CALL check_ps_gas_phase(psv)
            CALL check_ps_solids_phases(psv)
         ELSE
! Verify that no data was defined for unspecified PS.
            CALL check_ps_overflow(psv)
         ENDIF
      ENDDO

! Clear the error manager.
      CALL finl_err_msg

      RETURN
      END SUBROUTINE check_point_sources


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  SUBROUTINE: CHECK_PS_GEOMETRY                                       !
!  Author: J. Musser                                  Date: 10-JUN-13  !
!                                                                      !
!  Purpose: Check point source specifications.                         !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_ps_geometry


! Global Variables:
!---------------------------------------------------------------------//
! Flag: PS contains geometric data and/or specified type
      use ps, only: ps_defined, point_source
! User specified: PS geometry
      use ps, only: ps_x_e, ps_x_w, ps_i_e, ps_i_w
      use ps, only: ps_y_n, ps_y_s, ps_j_n, ps_j_s
      use ps, only: ps_z_t, ps_z_b, ps_k_t, ps_k_b
! User specified: System geometry
      use geometry, only: no_i, xlength
      use geometry, only: no_j, ylength
      use geometry, only: no_k, zlength

! Global Parameters:
!---------------------------------------------------------------------//
! The max number of BCs.
      use param, only: dimension_ps
! Parameter constants
      use param1, only: zero, undefined, undefined_i

! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager


      implicit none


! Local Variables:
!---------------------------------------------------------------------//
! PS loop counter.
      INTEGER :: PSV
!......................................................................!

! Initialize the error manager.
      CALL init_err_msg("CHECK_PS_GEOMETRY")

! Initialize the PS runtime flag.
      point_source = .false.

! Determine which point source indices have values.
      psv_lp: do psv = 1, dimension_ps

         IF (ps_x_w(psv) /= undefined)   ps_defined(psv) = .true.
         IF (ps_x_e(psv) /= undefined)   ps_defined(psv) = .true.
         IF (ps_y_s(psv) /= undefined)   ps_defined(psv) = .true.
         IF (ps_y_n(psv) /= undefined)   ps_defined(psv) = .true.
         IF (ps_z_b(psv) /= undefined)   ps_defined(psv) = .true.
         IF (ps_z_t(psv) /= undefined)   ps_defined(psv) = .true.
         IF (ps_i_w(psv) /= undefined_i) ps_defined(psv) = .true.
         IF (ps_i_e(psv) /= undefined_i) ps_defined(psv) = .true.
         IF (ps_j_s(psv) /= undefined_i) ps_defined(psv) = .true.
         IF (ps_j_n(psv) /= undefined_i) ps_defined(psv) = .true.
         IF (ps_k_b(psv) /= undefined_i) ps_defined(psv) = .true.
         IF (ps_k_t(psv) /= undefined_i) ps_defined(psv) = .true.

! Skip consistency checks if nothing was defined.
         IF (.NOT.ps_defined(psv)) cycle psv_lp

! Flag that one or more point sources has been detected.
         point_source = .true.

         IF(ps_x_w(psv)==undefined .AND. ps_i_w(psv)==undefined_i) THEN
            IF(no_i) THEN
               ps_x_w(psv) = zero
            ELSE
               WRITE(err_msg,1101) psv, 'PS_X_w and PS_I_w '
               CALL flush_err_msg(abort=.true.)
            ENDIF
         ENDIF
         IF(ps_x_e(psv)==undefined .AND. ps_i_e(psv)==undefined_i) THEN
            IF(no_i) THEN
               ps_x_e(psv) = xlength
            ELSE
               WRITE(err_msg,1101) psv, 'PS_X_e and PS_I_e '
               CALL flush_err_msg(abort=.true.)
            ENDIF
         ENDIF
         IF(ps_y_s(psv)==undefined .AND. ps_j_s(psv)==undefined_i) THEN
            IF(no_j) THEN
               ps_y_s(psv) = zero
            ELSE
               WRITE(err_msg,1101) psv, 'PS_Y_s and PS_J_s '
               CALL flush_err_msg(abort=.true.)
            ENDIF
         ENDIF
         IF(ps_y_n(psv)==undefined .AND. ps_j_n(psv)==undefined_i) THEN
            IF(no_j) THEN
               ps_y_n(psv) = ylength
            ELSE
               WRITE(err_msg,1101) psv, 'PS_Y_n and PS_J_n '
               CALL flush_err_msg(abort=.true.)
            ENDIF
         ENDIF
         IF(ps_z_b(psv)==undefined .AND. ps_k_b(psv)==undefined_i) THEN
            IF(no_k) THEN
               ps_z_b(psv) = zero
            ELSE
               WRITE(err_msg,1101) psv, 'PS_Z_b and PS_K_b '
               CALL flush_err_msg(abort=.true.)
            ENDIF
         ENDIF
         IF(ps_z_t(psv)==undefined .AND. ps_k_t(psv)==undefined_i) THEN
            IF(no_k) THEN
               ps_z_t(psv) = zlength
            ELSE
               WRITE(err_msg,1101) psv, 'PS_Z_t and PS_K_t '
               CALL flush_err_msg(abort=.true.)
            ENDIF
         ENDIF

 1101 FORMAT('Error 1101: Point source ',i3,' is ill-defined.',/a,     &
         ' are not specified.',/'Please correct the mfix.dat file.')

      ENDDO psv_lp

      CALL finl_err_msg

      RETURN
      END SUBROUTINE check_ps_geometry


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  SUBROUTINE: CHECK_PS_GAS_PHASE                                      !
!  Author: J. Musser                                  Date: 10-JUN-13  !
!                                                                      !
!  Purpose: Check point source specifications.                         !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_ps_gas_phase(PSV)

! Global Variables:
!---------------------------------------------------------------------//
! Gas phase mass flowrate for PS
      use ps, only: ps_massflow_g
! Gas phase velocity for PS
      use ps, only: ps_u_g, ps_v_g, ps_w_g
! Gas phase tempture and species mass fractions
      use ps, only: ps_t_g, ps_x_g
! Flag: Solve energy equations.
      use run, only: energy_eq
! Flag: Solve species equations.
      use run, only: species_eq
! Number of species.
      use physprop, only: nmax

! Global Parameters:
!---------------------------------------------------------------------//
! Parameter constants
      use param1, only: zero, one, undefined

! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager

      use toleranc

      implicit none

! Dummy Arguments:
!---------------------------------------------------------------------//
      INTEGER, INTENT(in) :: PSV

! Local Variables:
!---------------------------------------------------------------------//
! Loop counter
      INTEGER :: N
! Sum of solids mass fractions.
      DOUBLE PRECISION :: SUM
!......................................................................!

! Initialze the error manager.
      CALL init_err_msg("CHECK_PS_GAS_PHASE")


! Check mass flow and velocity
      IF(ps_massflow_g(psv) == undefined) THEN
         IF(ps_u_g(psv) /= undefined .OR. &
            ps_v_g(psv) /= undefined .OR. &
            ps_w_g(psv) /= undefined) THEN

            WRITE(err_msg,1100) psv, trim(ivar('PS_MASSFLOW_G',psv))
            CALL flush_err_msg(abort=.true.)

 1100 FORMAT('Error 1100: Invalid specification for point source ',i3,&
         '.',/a,' is undefined but velocity is given.',/'Please ',    &
         'correct the mfix.dat file.')

         ELSE
            ps_massflow_g(psv) = zero
            ps_u_g(psv) = zero
            ps_v_g(psv) = zero
            ps_w_g(psv) = zero
         ENDIF

      ELSEIF(ps_massflow_g(psv) == zero) THEN
         IF(ps_u_g(psv) /= zero .OR. &
            ps_v_g(psv) /= zero .OR. &
            ps_w_g(psv) /= zero) THEN

            WRITE(err_msg,1101) psv, trim(ivar('PS_MASSFLOW_G',psv))
            CALL flush_err_msg(abort=.true.)
         ENDIF

 1101 FORMAT('Error 1101: Invalid specification for point source ',i3,&
         '.',/a,' is zero but velocity is given.',/'Please correct ', &
         'the mfix.dat file.')

! Verify a physical mass flow
      ELSEIF(ps_massflow_g(psv) < zero) THEN
         WRITE(err_msg,1102) psv, trim(ivar('PS_MASSFLOW_G',psv))
         CALL flush_err_msg(abort=.true.)

 1102 FORMAT('Error 1102: Invalid specifications for point source ',i3,&
         '.',/a,' < 0.0. Point sources can only add mass to a system',/&
         'Please correct the mfix.dat file.')


! Mass flow is specified:
      ELSE

! Velocity does not have to be defined (no momentum source). If the
! components are UNDEFINED, zero them out.
         IF(ps_u_g(psv) == undefined) ps_u_g(psv) = zero
         IF(ps_v_g(psv) == undefined) ps_v_g(psv) = zero
         IF(ps_w_g(psv) == undefined) ps_w_g(psv) = zero

! Sum together defiend gas phase species mass fractions.
         sum = zero
         DO n = 1, nmax(0)
            IF(ps_x_g(psv,n) /= undefined) THEN
               sum = sum + ps_x_g(psv,n)
            ELSE
               ps_x_g(psv,n) = zero
            ENDIF
         ENDDO

! Enforce that the species mass fractions must sum to one.
         IF(.NOT.compare(one,sum)) THEN

            IF(species_eq(0)) THEN
               WRITE(err_msg, 1110) psv
               CALL flush_err_msg(abort=.true.)

 1110 FORMAT('Error 1110: PS_X_g(',i3,',:) do NOT sum to ONE and the ',&
         'gas phase',/'species equations are solved. Please correct ', &
         'the mfix.dat file.')

            ELSEIF(.NOT.compare(sum,zero)) THEN
               WRITE(err_msg, 1111) psv
               CALL flush_err_msg(abort=.true.)

 1111 FORMAT('Error 1111: PS_X_g(',i3,',:) do not sum to ONE or ZERO ',&
         'and they',/'are not needed. Please correct the mfix.dat ',   &
         'the mfix.dat file.')

            ELSE
               ps_x_g(psv,:) = zero
               ps_x_g(psv,1) = one
            ENDIF

         ENDIF

! Verify that a temperature is provided.
         IF(energy_eq)THEN
            IF(ps_t_g(psv) == undefined) THEN
               WRITE(err_msg,1000) trim(ivar('PS_T_g',psv))
               CALL flush_err_msg(abort=.true.)

! Verify that a given temperature is physical.
            ELSEIF(ps_t_g(psv) <= zero) THEN
               WRITE(err_msg,1001) psv, trim(ivar('PS_T_g',psv)),      &
                  trim(ival(ps_t_g(psv)))
               CALL flush_err_msg(abort=.true.)
            ENDIF
         ENDIF

      ENDIF

      CALL finl_err_msg

      RETURN

 1000 FORMAT('Error 1000: Required input not specified: ',a,/'Please ',&
         'correct the mfix.dat file.')

 1001 FORMAT('Error 1001: Illegal or unknown input: ',a,' = ',a,/      &
         'Please correct the mfix.dat file.')

      END SUBROUTINE check_ps_gas_phase


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  SUBROUTINE: CHECK_PS_SOLIDS_PHASES                                  !
!  Author: J. Musser                                  Date: 10-JUN-13  !
!                                                                      !
!  Purpose: Check point source specifications.                         !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_ps_solids_phases(PSV)

! Global Variables:
!---------------------------------------------------------------------//
! Solids phase mass flowrate for PS
      use ps, only: ps_massflow_s
! Solids phase velocity for PS
      use ps, only: ps_u_s, ps_v_s, ps_w_s
! Solids phase tempture and species mass fractions
      use ps, only: ps_t_s, ps_x_s
! Flag: Solve energy equations.
      use run, only: energy_eq
! Flag: Solve species equations.
      use run, only: species_eq
! Type of each solids phase.
      use run, only: solids_model
! Number of (TFM) solids.
      use physprop, only: smax
! Number of discrete solids phases.
      use discretelement, only: des_mmax
! Number of solids species.
      use physprop, only: smax, nmax

! Global Parameters:
!---------------------------------------------------------------------//
! Parameter constants
      use param1, only: zero, one, undefined

! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager

      use toleranc

      implicit none

! Dummy Arguments:
!---------------------------------------------------------------------//
      INTEGER, INTENT(in) :: PSV

! Local Variables:
!---------------------------------------------------------------------//
! Total number of solid phases
      INTEGER :: MMAX_TOT
! Loop counters
      INTEGER :: M, N
! Sum of solids mass fractions.
      DOUBLE PRECISION :: SUM
!......................................................................!

! Initialize the error manager.
      CALL init_err_msg("CHECK_PS_SOLIDS_PHASES")

! The total number of solids phases (all models).
      mmax_tot = smax + des_mmax

      DO m=1, mmax_tot

! Check mass flow and velocity
         IF(ps_massflow_s(psv,m) == undefined) THEN
            IF(ps_u_s(psv,m) /= undefined .OR. &
               ps_v_s(psv,m) /= undefined .OR. &
               ps_w_s(psv,m) /= undefined) THEN

               WRITE(err_msg,1100)psv, trim(ivar('PS_MASSFLOW_S',psv,m))
               CALL flush_err_msg(abort=.true.)

 1100 FORMAT('Error 1100: Invalid specification for point source ',i3,&
         '.',/a,' is undefined but velocity is given.',/'Please ',    &
         'correct the mfix.dat file.')

            ELSE
               ps_massflow_s(psv,m) = zero
               ps_u_s(psv,m) = zero
               ps_v_s(psv,m) = zero
               ps_w_s(psv,m) = zero
            ENDIF

         ELSEIF(ps_massflow_s(psv,m) == zero) THEN
            IF(ps_u_s(psv,m) /= zero .OR. &
               ps_v_s(psv,m) /= zero .OR. &
               ps_w_s(psv,m) /= zero) THEN

               WRITE(err_msg,1101)psv, trim(ivar('PS_MASSFLOW_S',psv,m))
               CALL flush_err_msg(abort=.true.)
            ENDIF

 1101 FORMAT('Error 1100: Invalid specification for point source ',i3,&
         '.',/a,' is zero but velocity is given.',/'Please correct ', &
         'the mfix.dat file.')

         ELSEIF(ps_massflow_s(psv,m) < zero) THEN
            WRITE(err_msg,1102) psv, trim(ivar('PS_MASSFLOW_S',psv,m))
            CALL flush_err_msg(abort=.true.)

 1102 FORMAT('Error 1102: Invalid specifications for point source ',i3,&
         '.',/a,' < 0.0. Point sources can only add mass to a system',/&
         'Please correct the mfix.dat file.')


! Mass flow is specified:
         ELSE

! Currently, only TFM solids can be used with point sources. However,
! the could be implemented for PIC solids as well.
            SELECT CASE(solids_model(m))
            CASE ('DEM','PIC')
               WRITE(err_msg, 1110) psv, solids_model(m)
               CALL flush_err_msg(abort=.true.)
            CASE DEFAULT
            END SELECT

 1110 FORMAT('Error 1110: Invalid specifications for point source ',i3,&
         '.',/'Point sources are not supported for ',a,' solids.',/    &
         'Please correct the mfix.dat file.')

! Velocity does not have to be defined (no momentum source). If the
! components are UNDEFINED, zero them out.
            IF(ps_u_s(psv,m) == undefined) ps_u_s(psv,m) = zero
            IF(ps_v_s(psv,m) == undefined) ps_v_s(psv,m) = zero
            IF(ps_w_s(psv,m) == undefined) ps_w_s(psv,m) = zero

! Sum together defiend gas phase species mass fractions.
            sum = zero
            DO n = 1, nmax(m)
               IF(ps_x_s(psv,m,n) /= undefined) THEN
               sum = sum + ps_x_s(psv,m,n)
               ELSE
                  ps_x_s(psv,m,n) = zero
               ENDIF
            ENDDO

! Enforce that the species mass fractions must sum to one.
            IF(.NOT.compare(one,sum)) THEN

               IF(species_eq(m)) THEN
                  WRITE(err_msg, 1120) psv,m
                  CALL flush_err_msg(abort=.true.)

 1120 FORMAT('Error 1120: PS_X_s(',i3,',',i2,',:) do NOT sum to ONE ', &
         'and the solids phase',/'species equations are solved. ',     &
         'Please correct the mfix.dat file.')

               ELSEIF(.NOT.compare(sum,zero)) THEN
                  WRITE(err_msg, 1121) psv,m
                  CALL flush_err_msg(abort=.true.)

 1121 FORMAT('Error 1121: PS_X_s(',i3,',',i2,',:) do not sum to ONE ', &
         'or ZERO and they',/'are not needed. Please correct the ',    &
         'mfix.dat the mfix.dat file.')

               ELSE
                  ps_x_s(psv,m,1)  = one
                  ps_x_s(psv,m,2:) = zero
               ENDIF

            ENDIF

! Verify that a temperature is provided.
            IF(energy_eq)THEN
               IF(ps_t_s(psv,m) == undefined) THEN
                  WRITE(err_msg,1000) trim(ivar('PS_T_s',psv,m))
                  CALL flush_err_msg(abort=.true.)

! Verify that a given temperature is physical.
               ELSEIF(ps_t_s(psv,m) <= zero) THEN
                  WRITE(err_msg,1001) psv, trim(ivar('PS_T_s',psv,m)), &
                     trim(ival(ps_t_s(psv,m)))
                  CALL flush_err_msg(abort=.true.)
               ENDIF
            ENDIF
         ENDIF
      ENDDO

      CALL finl_err_msg

      RETURN

 1000 FORMAT('Error 1000: Required input not specified: ',a,/'Please ',&
         'correct the mfix.dat file.')

 1001 FORMAT('Error 1001: Illegal or unknown input: ',a,' = ',a,/      &
         'Please correct the mfix.dat file.')

      END SUBROUTINE check_ps_solids_phases



!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  SUBROUTINE: CHECK_PS_OVERFLOW                                       !
!  Author: J. Musser                                  Date: 10-JUN-13  !
!                                                                      !
!  Purpose: Check point source specifications.                         !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_ps_overflow(PSV)

! Global Variables:
!---------------------------------------------------------------------//
! Gas phase mass flowrate for PS and velocities
      use ps, only: ps_massflow_g, ps_u_g, ps_v_g, ps_w_g
! Gas phase tempture and species mass fractions
      use ps, only: ps_t_g, ps_x_g
! Solids phase mass flowrate and velocity
      use ps, only: ps_massflow_s, ps_u_s, ps_v_s, ps_w_s
! Solids phase tempture and species mass fractions
      use ps, only: ps_t_s, ps_x_s

! Global Parameters:
!---------------------------------------------------------------------//
! Maximum input array sizes.
      use param, only: dim_m, dim_n_g, dim_n_s
! Parameter constants
      use param1, only: undefined

! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager

      implicit none

! Dummy Arguments:
!---------------------------------------------------------------------//
      INTEGER, INTENT(in) :: PSV

! Local Variables:
!---------------------------------------------------------------------//
! Loop counters
      INTEGER :: M, N
!......................................................................!


! Initialize the error manager.
      CALL init_err_msg("CHECK_PS_OVERFLOW")


      IF(ps_massflow_g(psv) /= undefined) THEN
         WRITE(err_msg,1010) trim(ivar('PS_MASSFLOW_G',psv))
         CALL flush_err_msg(abort=.true.)
      ELSEIF(ps_u_g(psv) /= undefined) THEN
         WRITE(err_msg,1010) trim(ivar('PS_U_g',psv))
         CALL flush_err_msg(abort=.true.)
      ELSEIF(ps_v_g(psv) /= undefined) THEN
         WRITE(err_msg,1010) trim(ivar('PS_V_g',psv))
         CALL flush_err_msg(abort=.true.)
      ELSEIF(ps_w_g(psv) /= undefined) THEN
         WRITE(err_msg,1010) trim(ivar('PS_W_g',psv))
         CALL flush_err_msg(abort=.true.)
      ELSEIF(ps_t_g(psv) /= undefined) THEN
         WRITE(err_msg,1010) trim(ivar('PS_T_g',psv))
         CALL flush_err_msg(abort=.true.)
      ENDIF
      DO n = 1, dim_n_g
         IF(ps_x_g(psv,n) /= undefined) THEN
            WRITE(err_msg,1010) trim(ivar('PS_X_G',psv,n))
            CALL flush_err_msg(abort=.true.)
         ENDIF
      ENDDO

      DO m=1, dim_m
         IF(ps_massflow_s(psv,m) /= undefined) THEN
            WRITE(err_msg,1010) trim(ivar('PS_MASSFLOW_S',psv,m))
            CALL flush_err_msg(abort=.true.)
         ELSEIF(ps_u_s(psv,m) /= undefined) THEN
            WRITE(err_msg,1010) trim(ivar('PS_U_s',psv,m))
            CALL flush_err_msg(abort=.true.)
         ELSEIF(ps_v_s(psv,m) /= undefined) THEN
            WRITE(err_msg,1010) trim(ivar('PS_V_s',psv,m))
            CALL flush_err_msg(abort=.true.)
         ELSEIF(ps_w_s(psv,m) /= undefined) THEN
            WRITE(err_msg,1010) trim(ivar('PS_W_s',psv,m))
            CALL flush_err_msg(abort=.true.)
         ELSEIF(ps_t_s(psv,m) /= undefined) THEN
            WRITE(err_msg,1010) trim(ivar('PS_T_s',psv,m))
            CALL flush_err_msg(abort=.true.)
         ENDIF
         DO n = 1, dim_n_s
            IF(ps_x_s(psv,m,n) /= undefined) THEN
               WRITE(err_msg,1010) trim(ivar('PS_X_S',psv,m,n))
               CALL flush_err_msg(abort=.true.)
            ENDIF
         ENDDO
      ENDDO

      CALL finl_err_msg

      RETURN

 1010 FORMAT('Error 1010: ',a,' specified in an undefined PS region.')

      END SUBROUTINE check_ps_overflow