set_ro_s.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: SET_RO_s                                                !
!                                                                      !
!  Author: J.Musser                                   Date: 09-Oct-13  !
!  Reviewer:                                                           !
!                                                                      !
!  Purpose: Initialize solids densities.                               !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE set_ro_s

! Global Variables:
!---------------------------------------------------------------------/
! Number of solids phases.
      use physprop, only: mmax
! Solids density field variable.
      use fldvar, only: ro_s, rop_s
! Solid phase species mass fractions.
      use fldvar, only: x_s
! Initial mass fraction of inert species
      use physprop, only: x_s0
! Index of inert solids phase species.
      use physprop, only: inert_species
! Inert solids phase species mass fraction in dilute region.
      use physprop, only: dil_inert_x_vsd
! Factor to define dilute region where DIL_INERT_X_VSD is used
      use physprop, only: dil_factor_vsd
! Run-time flag for variable soilds density
      use run, only: solve_ros
! Constant solids density.
      use physprop, only: ro_s0
! Minimum solids volume fraction
      use toleranc, only: dil_ep_s

! Function for evaluating solids density.
      use eos, only: eoss

! Modules needed to support function.inc
      use compar
      use geometry
      use indices
      use functions

      implicit none

! Local Variables:
!---------------------------------------------------------------------/
! Solids phase index
      INTEGER :: M
! Fluid cell index
      INTEGER :: IJK
! Index of the inert solids species.
      INTEGER :: IIS
! Flag for debugging.
      LOGICAL, parameter :: dbgMode = .false.

      DOUBLE PRECISION :: minROPs

! Loop over all solids
      DO m=1,mmax

! Variable solids density.
         IF (solve_ros(m)) THEN
! Set the index of the intert phase.
            iis = inert_species(m)
! Calculate the minimum solids denisty.
!            minROPs = RO_s0(M)*DIL_EP_s
            minrops = ro_s0(m)*(dil_factor_vsd*dil_ep_s)
! Debug/Development option.
            IF(dbgmode) CALL check_set_ros()

! Calculate Ro_s in all fluid and flow boundary cells.
            DO ijk = ijkstart3, ijkend3
               IF(wall_at(ijk)) cycle
               IF(rop_s(ijk,m) > minrops) THEN
                  ro_s(ijk,m) = eoss(ro_s0(m), x_s0(m,iis),         &
                     x_s(ijk,m,iis))
               ELSE
!                  RO_s(IJK,M) = RO_s0(M)
                  ro_s(ijk,m) = eoss(ro_s0(m), x_s0(m,iis),            &
                     dil_inert_x_vsd(m))
               ENDIF
            ENDDO
         ELSE
! Constant solids density.
            DO ijk = ijkstart3, ijkend3
               IF (wall_at(ijk)) cycle
               ro_s(ijk,m) = ro_s0(m)
            ENDDO
         ENDIF
      ENDDO

      RETURN

      CONTAINS

!``````````````````````````````````````````````````````````````````````!
!  Subroutine: CHECK_SET_ROs                                           !
!  Author: J.Musser                                   Date: 21-JAN-92  !
!                                                                      !
!  Purpose: Verify that all the variable solids density information is !
!           present for solids phase M.                                !
!                                                                      !
!           Note: The check_data routines should have caught any       !
!           problematic IC/BC specifications. This is included mainly  !
!           for development efforts.                                   !
!``````````````````````````````````````````````````````````````````````!
      SUBROUTINE check_set_ros()

      use exit, only: mfix_exit
! Flag for who writes
      use funits, only: dmp_log
! Solids species mass fractions.
      use fldvar, only: x_s

      use param1, only: zero
! Number of phase species.
      use physprop, only: nmax
! Index of inert species.
      use physprop, only: inert_species

      use toleranc

      implicit none

! Sum of solids phase mass fractions.
      DOUBLE PRECISION :: SUM_Xs
! Index of inert solids phase species.
      INTEGER :: INERT
! Integer Error Flag.
      INTEGER :: IER(2)

! Error file log.
      INTEGER, parameter :: lUnit = 8454
      LOGICAL :: lExists
      CHARACTER(LEN=64) :: lFName

! Initialize error flags.
      ier = 0

! Set the inert species index.
      inert = inert_species(m)

! Check all computational cells.
      DO ijk = ijkstart3, ijkend3
! Skip walls.
         IF (wall_at(ijk)) cycle
! Calculate the solids species mass fraction sum.
         sum_xs = sum(x_s(ijk,m,:nmax(m)))
! Verify that the species mass fractions are specified and valid.
         IF(.NOT.compare(one,sum_xs)) ier(1) = ier(1)+1
! Verify that the inert species mass fraction is greater than zero.
         IF(x_s(ijk,m,inert) <= zero) ier(2) = ier(2)+1

      ENDDO

! An error was detected. Open a log file.
      IF(sum(ier) /= 0) THEN
         lfname=''
         IF(numpes == 1) THEN
            WRITE(lfname,"('setROs.log')")
         ELSE
            WRITE(lfname,"('setROs_',I6.6,'.log')") mype
         ENDIF
         inquire(file=trim(lfname),exist=lexists)
         IF(lexists) THEN
            OPEN(convert='BIG_ENDIAN',unit=lunit,file=trim(lfname),status='replace')
         ELSE
            OPEN(convert='BIG_ENDIAN',unit=lunit,file=trim(lfname),status='new')
         ENDIF
      ENDIF


! An error was detected in species mass fraction sum.
      IF(ier(1) /= 0)THEN
         WRITE(lunit,1100) mype
! Skip walls.
         DO ijk = ijkstart3, ijkend3
            IF (wall_at(ijk)) cycle
! Calculate the solids species mass fraction sum.
            sum_xs = sum(x_s(ijk,m,:nmax(m)))
! Verify that the species mass fractions are specified and valid.
            IF(.NOT.compare(one,sum_xs)) WRITE(lunit,1101) ijk, sum_xs
         ENDDO
         WRITE(lunit,9999)
      ENDIF

! An error was detected in inert species mass fraction.
      IF(ier(2) /= 0)THEN
         WRITE(lunit,1200) mype
         WRITE(lunit,1201) m
         WRITE(lunit,1202) inert
! Skip walls.
         DO ijk = ijkstart3, ijkend3
            IF (wall_at(ijk)) cycle
! Calculate the solids species mass fraction sum.
! Verify that the species mass fractions are specified and valid.
            IF(x_s(ijk,m,inert) <= zero) WRITE(lunit,1203)             &
               ijk, x_s(ijk,m,inert)
         ENDDO
         WRITE(lunit,9999)
      ENDIF

! Close the file, cleanup, and exit.
      IF(sum(ier) /= 0) THEN
         CLOSE(lunit)
         IF(dmp_log) THEN
         ENDIF
         CALL mfix_exit(mype)
      ENDIF


      RETURN

 1100 FORMAT(//1x,70('*')/' From: CHECK_SET_ROs',/,' Error 1100:',     &
         ' One or more fluid cells contain invalid species mass',/     &
         ' fractions which do NOT sum to one.'/,'   > myPE = ',i6)

 1101 FORMAT('   > sum(X_s(',i6,')) = ',g12.5)

 1200 FORMAT(//1x,70('*')/' From: CHECK_SET_ROs',/,' Error 1200:',     &
         ' One or more fluid cells contain an invalid species mass',/  &
         ' fraction for the inert material.'/,'   > myPE = ',i6)

 1201 FORMAT('   > Solid Phase: ',i2)

 1202 FORMAT('   > Inert species index: ',i4)

 1203 FORMAT('   > X_s(',i6,',INERT) = ',g12.5)

 9999 FORMAT(1x,70('*')/)

      END SUBROUTINE check_set_ros

      END SUBROUTINE set_ro_s