calc_rrates_des.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Module name: CALC_RRATES_DES                                        !
!  Author: J. Musser                                  Date: 10-Oct-12  !
!                                                                      !
!  Purpose: Calculate reaction rates for various reactions for DES.    !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE calc_rrates_des(NP, pRgp, pRgc, pRPhase, pHoRg, pSUMRg)

      USE compar
      USE constant
      USE des_rxns
      USE des_thermo
      USE discretelement
      USE energy
      USE fldvar
      USE funits
      USE geometry
      USE indices
      USE parallel
      USE param
      USE param1
      USE physprop
      USE run
      USE rxns
      USE sendrecv
      USE usr
      Use parse
      use functions
      use toleranc, only: zero_x_gs, compare
      use physprop, only: nmax
      use param1, only: dimension_lm
      use param, only: dimension_m

      IMPLICIT NONE

! Passed variables
!---------------------------------------------------------------------//
      INTEGER, INTENT(IN) :: NP   ! particle index

! Local gas phase values.
      DOUBLE PRECISION, INTENT(OUT) :: pRgp(nmax(0)) ! Rate of production
      DOUBLE PRECISION, INTENT(OUT) :: pRgc(nmax(0)) ! Rate of consumption
      DOUBLE PRECISION, INTENT(OUT) :: pHoRg   ! Heat of reaction
      DOUBLE PRECISION, INTENT(OUT) :: pSUMRg
      DOUBLE PRECISION, INTENT(OUT) :: pRPhase(dimension_lm+dimension_m-1)

! Local variables
!---------------------------------------------------------------------//
      INTEGER :: pM   ! Global Solids Phase index
      INTEGER :: IJK  ! fluid cell index

      INTEGER :: H    ! Reaction loop counter
      INTEGER :: M    ! Global Phase index loop counter
      INTEGER :: NN   ! Global species index
      INTEGER :: lN   ! Local reaction speices index/loop counter
      INTEGER :: LM   !

      INTEGER :: mXfr ! Global phase index for mass transfer

! User-defined reaction rates returned from USR_RATES
      DOUBLE PRECISION :: DES_RATES(no_of_des_rxns)

      DOUBLE PRECISION :: lRate
      DOUBLE PRECISION :: lTp
      DOUBLE PRECISION :: lHoRs, llHoRg

      DOUBLE PRECISION :: RxH

! Reaction limiters. If a species mass fraction is less than this
! value, then the reaction is suppressed.
      DOUBLE PRECISION :: speciesLimiter

! External functions
!---------------------------------------------------------------------//
! Enthalpy calculations (cal/gram)
      DOUBLE PRECISION, EXTERNAL :: CALC_H

! Alias particle temperature.
      ltp = des_t_s(np)
      ijk = pijk(np,4)
      pm = pijk(np,5)

! Initialize storage arrays
      prgp(:) = zero
      prgc(:) = zero
      phorg = zero

      prphase = zero
      psumrg = zero

! Set the species limiter:
      specieslimiter = zero_x_gs

! Calculate user defined reaction rates.
      des_rates(:) = zero
      CALL usr_rates_des(np, pm, ijk, des_rates)

! Loop over reactions.
      rxn_lp: DO h = 1, no_of_des_rxns

! Skip empty reactions
         IF(des_reaction(h)%nSpecies == 0) cycle rxn_lp
         IF(compare(des_rates(h),zero)) cycle rxn_lp

! Initialize local loop arrays
         llhorg = zero
         lhors = zero
         rxh = zero

! Calculate the rate of formation/consumption for each species.
!---------------------------------------------------------------------//
         DO ln = 1, des_reaction(h)%nSpecies
! Global phase index.
            m = des_reaction(h)%Species(ln)%pMap
! Global species index.
            nn = des_reaction(h)%Species(ln)%sMap
! Index for interphase mass transfer. For a gas/solid reaction, the
! index is stored with the gas phase.
            mxfr = des_reaction(h)%Species(ln)%mXfr
            lrate = des_rates(h) * des_reaction(h)%Species(ln)%MWxStoich
! Gas Phase:
            IF(m == 0) THEN
! Consumption of gas phase species.
               IF(lrate < zero) THEN
                  IF(x_g(ijk,nn) > specieslimiter) THEN
                     prgc(nn) = prgc(nn) - lrate
! Enthalpy transfer associated with mass transfer. (gas/solid)
                     IF(m /= mxfr) rxh = rxh +                         &
                        lrate*calc_h(t_g(ijk),0,nn)
                  ELSE
! There is an insignificant amount of reactant. Skip this reaction.
                     des_rates(h) = zero
                     cycle rxn_lp
                  ENDIF
               ELSE
! Formation of gas phase species.
                  prgp(nn) = prgp(nn) + lrate
! Enthalpy transfer associated with mass transfer. (gas/solid)
                  IF(m /= mxfr) rxh = rxh + lrate*calc_h(ltp,0,nn)
               ENDIF
! Discrete Solids Phase:
            ELSE
! Formation/consumption of solids phase species.
               des_r_s(np,nn) = des_r_s(np,nn) + lrate
            ENDIF
         ENDDO ! Loop of species


! Calculate and store the heat of reaction.
!---------------------------------------------------------------------//
         IF(energy_eq) THEN
! Automated heat of reaction calculations
            IF(des_reaction(h)%Calc_DH) THEN
! Loop over reaction species.
               DO ln = 1, des_reaction(h)%nSpecies
! Global phase index.
                  m = des_reaction(h)%Species(ln)%pMap
! Global species index.
                  nn = des_reaction(h)%Species(ln)%sMap
! Rate of formation/consumption for speices N
                  lrate = des_rates(h) * &
                     des_reaction(h)%Species(ln)%MWxStoich
! Gas phase enthalpy chnage from energy equation derivation.
                  IF(m == 0) THEN
                     llhorg = llhorg + calc_h(t_g(ijk),0,nn) * lrate
! Solid phase enthalpy change from energy equation derivation.
                  ELSE
                     lhors = lhors + calc_h(ltp,m,nn) * lrate
                  ENDIF
               ENDDO

! Apply enthalpy transfer associated with mass transfer to get the
! complete heat of reaction for Reaction H.
               llhorg = llhorg - rxh
               lhors = lhors + rxh

! Convert the heat of reaction to the appropriate units (if SI), and
! store in the global array.
               IF(units == 'SI') THEN
                  phorg = phorg + 4.183925d3*llhorg
                  q_source(np) = q_source(np) - 4.183925d3*lhors
               ELSE
                  phorg = phorg + llhorg
                  q_source(np) = q_source(np) - lhors
               ENDIF
            ELSE
! User-defined heat of reaction.
               hor_g(ijk) = hor_g(ijk) + &
                  des_reaction(h)%HoR(0) * des_rates(h)
               q_source(np) = q_source(np) - &
                  des_reaction(h)%HoR(pm) * des_rates(h)
            ENDIF
         ENDIF

! Update rate of interphase mass transfer.
!---------------------------------------------------------------------//
         lm = 1 + (pm - 1)*pm/2
         prphase(lm) = prphase(lm) + &
            des_rates(h) * des_reaction(h)%rPHASE(lm)

      ENDDO rxn_lp ! Loop over reactions.

! Calculate the toal rate of formation and consumption for each species.
!---------------------------------------------------------------------//
      IF(species_eq(0)) THEN
         psumrg = sum(prgp(:nmax(0)) - prgc(:nmax(0)))
      ELSE
         DO h=1, no_of_des_rxns
            IF(des_reaction(h)%nPhases <= 0) cycle
            lm = 1 + ((pm-1)*pm)/2
            psumrg = psumrg + &
               des_rates(h) * des_reaction(h)%rPHASE(lm)
         ENDDO
      ENDIF

      RETURN
      END SUBROUTINE calc_rrates_des


!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!  Subroutine name: CALC_RRATE_DES                                     !
!                                                                      !
!  Purpose: This routine manages gas-solid reactions for the continuum !
!  phase.                                                              !
!                                                                      !
!  Author: J.Musser                                   Date: 16-May-11  !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE zero_rrate_des

      USE des_rxns
      USE param1, only: zero

      IMPLICIT NONE

      des_r_gp(:,:) = zero
      des_r_gc(:,:) = zero
      des_r_phase(:,:) = zero
      des_hor_g(:) = zero
      des_sum_r_g(:) = zero

      RETURN
      END SUBROUTINE zero_rrate_des