check_boundary_conditions.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: CHECK_BOUNDARY_CONDITIONS                               !
!  Author: P. Nicoletti                               Date: 10-DEC-91  !
!                                                                      !
!  Purpose: Check boundary condition specifications                    !
!     - convert physical locations to i, j, k's (GET_FLOW_BC)          !
!     - compute area of boundary surfaces (GET_BC_AREA)                !
!     - convert mass and volumetric flows to velocities (FLOW_TO_VEL)  !
!     - check specification of physical quantities                     !
!                                                                      !
!  Comments:                                                           !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_boundary_conditions

! Global Variables:
!---------------------------------------------------------------------//
! Total number of (actual) continuum solids.
      use physprop, only: smax, mmax
! Total number of discrete solids.
      use discretelement, only: des_mmax
! Flag: BC dimensions or Type is specified
      use bc, only: bc_defined
! Use specified BC type
      use bc
! User specified BC solids bulk density
      use bc, only: bc_rop_s
! Solids volume fraction at BC
      use bc, only: bc_ep_s
      use bc, only: bc_ep_g
! Run-time flag for DEM solids
      use run, only: dem_solids
! Run-time flag for PIC solids
      use run, only: pic_solids

! Global Parameters:
!---------------------------------------------------------------------//
! Parameter constants
      use param1, only: zero, one, undefined
! Maximum number of BCs
      use param, only: dimension_bc
! Maximum number of disperse phases
      use param, only: dim_m

! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager


      IMPLICIT NONE


! Local Variables:
!---------------------------------------------------------------------//
! Loop counter for BCs
      INTEGER :: BCV
! Total number of solids phases (continuum + discrete)
      INTEGER :: MMAX_TOT
! Flag to skip checks on indexed solid phase.
      LOGICAL :: SKIP(1:dim_m)
!......................................................................!


! Initialize the error manager.
      CALL init_err_msg("CHECK_BOUNDARY_CONDITIONS")

! Determine which BCs are DEFINED
      CALL check_bc_geometry

! Total number of solids. (this won't work for GHD/hybrid)
      mmax_tot = smax + des_mmax

! Loop over each defined BC and check the user data.
      DO bcv = 1, dimension_bc

         IF (bc_defined(bcv)) THEN

! Determine which solids phases are present.
            skip=(bc_rop_s(bcv,:)==undefined.OR.bc_rop_s(bcv,:)==zero) &
               .AND.(bc_ep_s(bcv,:)==undefined.OR.bc_ep_s(bcv,:)==zero)

            IF(mmax_tot == 1 .AND. bc_ep_g(bcv)/=one) skip(1) = .false.

            SELECT CASE (bc_type_enum(bcv))

            CASE (mass_inflow)
               CALL check_bc_geometry_flow(bcv)
               CALL check_bc_mass_inflow(mmax_tot, skip, bcv)
               CALL check_bc_inflow(mmax_tot,skip,bcv)

            CASE (p_inflow)
               CALL check_bc_geometry_flow(bcv)
               CALL check_bc_p_inflow(mmax_tot, skip, bcv)
               CALL check_bc_inflow(mmax_tot, skip, bcv)
               CALL check_bc_outflow(mmax_tot, bcv)

            CASE (outflow)
               CALL check_bc_geometry_flow(bcv)
               CALL check_bc_outflow(mmax_tot, bcv)

            CASE (mass_outflow)
               CALL check_bc_geometry_flow(bcv)
               CALL check_bc_mass_outflow(mmax_tot, bcv)
               CALL check_bc_outflow(mmax_tot, bcv)

            CASE (p_outflow)
               CALL check_bc_geometry_flow(bcv)
               CALL check_bc_p_outflow(mmax_tot, bcv)
               CALL check_bc_outflow(mmax_tot, bcv)

            CASE (free_slip_wall)
               CALL check_bc_geometry_wall(bcv)
               CALL check_bc_walls(mmax_tot, skip, bcv)

            CASE (no_slip_wall)
               CALL check_bc_geometry_wall(bcv)
               CALL check_bc_walls(mmax_tot, skip, bcv)

            CASE (par_slip_wall)
               CALL check_bc_geometry_wall(bcv)
               CALL check_bc_walls(mmax_tot, skip, bcv)

            END SELECT

! Check whether BC values are specified for undefined BC locations
         ELSEIF(bc_type_enum(bcv) /= dummy .AND.                          &
            .NOT.is_cg(bc_type_enum(bcv))) THEN

            CALL check_bc_range(bcv)

         ENDIF
      ENDDO

      mmax_tot = mmax+des_mmax
! Additional checks needed for DEM boundaries
      IF(dem_solids) CALL check_bc_dem(mmax_tot)
! Additional checks needed for PIC inflow/outflow boundaries
      IF(pic_solids) CALL check_bc_pic(mmax_tot)

! Cleanup and exit.
      CALL finl_err_msg

      RETURN

      END SUBROUTINE check_boundary_conditions



!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv!
!                                                                      !
!  Subroutine: CHECK_BC_RANGE                                          !
!  Author: P. Nicoletti                               Date: 10-DEC-91  !
!                                                                      !
!  Purpose: Verify that data was not given for undefined BC regions.   !
!                                                                      !
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^!
      SUBROUTINE check_bc_range(BCV)

! Global Variables:
!---------------------------------------------------------------------//
! Gas phase BC varaibles
      use bc, only: bc_ep_g, bc_t_g, bc_x_g, bc_p_g
      use bc, only: bc_u_g, bc_v_g, bc_w_g
! Solids phase BC variables.
      USE bc, only: bc_ep_s, bc_rop_s, bc_t_s, bc_x_s
      use bc, only: bc_u_s, bc_v_s, bc_w_s
! Scalar equation BC variables.
      USE bc, only: bc_scalar


! Global Parameters:
!---------------------------------------------------------------------//
! Parameter constant for unspecified values.
      use param1, only: undefined
! Maximum number of disperse phases.
      use param, only: dim_m
! Maximum number of species gas/solids
      use param, only: dimension_n_g, dimension_n_s
! Maximum number of scalar equations.
      use param, only: dim_scalar


! Use the error manager for posting error messages.
!---------------------------------------------------------------------//
      use error_manager


      IMPLICIT NONE


! Dummy Arguments:
!---------------------------------------------------------------------/
! Boundary condition index.
      INTEGER, INTENT(in) :: BCV

! Local Variables:
!---------------------------------------------------------------------//
! Generic loop varaibles.
      INTEGER :: M, N
!......................................................................!


! Initialize the error manager.
      CALL init_err_msg("CHECK_BC_RANGE")


! Check gas phase variables.
      IF(bc_u_g(bcv) /= undefined) THEN
         WRITE(err_msg,1100) trim(ivar('BC_U_g',bcv))
         CALL flush_err_msg(abort=.true.)
      ENDIF
      IF(bc_v_g(bcv) /= undefined) THEN
         WRITE(err_msg,1100) trim(ivar('BC_V_g',bcv))
         CALL flush_err_msg(abort=.true.)
      ENDIF
      IF (bc_w_g(bcv) /= undefined) THEN
         WRITE(err_msg,1100) trim(ivar('BC_W_g',bcv))
         CALL flush_err_msg(abort=.true.)
      ENDIF
      IF (bc_ep_g(bcv) /= undefined) THEN
         WRITE(err_msg,1100) trim(ivar('BC_EP_g',bcv))
         CALL flush_err_msg(abort=.true.)
      ENDIF
      IF (bc_p_g(bcv) /= undefined) THEN
         WRITE(err_msg,1100) trim(ivar('BC_P_g',bcv))
         CALL flush_err_msg(abort=.true.)
      ENDIF
      IF (bc_t_g(bcv) /= undefined) THEN
         WRITE(err_msg,1100) trim(ivar('BC_T_g',bcv))
         CALL flush_err_msg(abort=.true.)
      ENDIF

      DO n = 1, dimension_n_g
         IF(bc_x_g(bcv,n) /= undefined) THEN
            WRITE(err_msg,1100) trim(ivar('BC_X_g',bcv,n))
            CALL flush_err_msg(abort=.true.)
         ENDIF
      ENDDO

! Check solids phase variables.
      DO m = 1, dim_m
         IF(bc_rop_s(bcv,m) /= undefined) THEN
            WRITE(err_msg,1100) trim(ivar('BC_ROP_s',bcv,m))
            CALL flush_err_msg(abort=.true.)
         ENDIF
         IF(bc_ep_s(bcv,m) /= undefined) THEN
            WRITE(err_msg,1100) trim(ivar('BC_EP_s',bcv,m))
            CALL flush_err_msg(abort=.true.)
         ENDIF
         IF(bc_u_s(bcv,m) /= undefined) THEN
            WRITE(err_msg,1100) trim(ivar('BC_U_s',bcv,m))
            CALL flush_err_msg(abort=.true.)
         ENDIF
         IF(bc_v_s(bcv,m) /= undefined) THEN
            WRITE(err_msg,1100) trim(ivar('BC_V_s',bcv,m))
            CALL flush_err_msg(abort=.true.)
         ENDIF

         IF(bc_w_s(bcv,m) /= undefined) THEN
            WRITE(err_msg,1100) trim(ivar('BC_W_s',bcv,m))
            CALL flush_err_msg(abort=.true.)
         ENDIF
         IF(bc_t_s(bcv,m) /= undefined) THEN
            WRITE(err_msg,1100) trim(ivar('BC_T_s',bcv,m))
            CALL flush_err_msg(abort=.true.)
         ENDIF

         DO n = 1, dimension_n_s
            IF(bc_x_s(bcv,m,n) /= undefined) THEN
               WRITE(err_msg,1100) trim(ivar('BC_X_s',bcv,m,n))
               CALL flush_err_msg(abort=.true.)
            ENDIF
         ENDDO

      ENDDO

! Check scalar equation variables.
      DO n = 1, dim_scalar
         IF(bc_scalar(bcv,n) /= undefined) THEN
            WRITE(err_msg,1100) trim(ivar('BC_Scalar',bcv))
            CALL flush_err_msg(abort=.true.)
         ENDIF
      ENDDO


      CALL finl_err_msg


      RETURN

 1100 FORMAT('Error 1100:',a,' specified for an undefined BC location')

      END SUBROUTINE check_bc_range