get_data.f

Go to the documentation of this file.

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  MODULE: GET_DATA                                                    C
!  Purpose: read and verify input data, open files                     C
!                                                                      C
!  Author: P. Nicoletti                               Date: 04-DEC-91  C
!  Reviewer: M.SYAMLAL, W.ROGERS, P.NICOLETTI         Date: 24-JAN-92  C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
MODULE read_input

  CONTAINS

      SUBROUTINE get_data

!-----------------------------------------------
! Modules
!-----------------------------------------------
      USE check_data_cg, only: adjust_ijk_size, check_data_cartesian
      USE cut_cell_preproc, only: cut_cell_preprocessing
      USE compar
      USE constant, only: l_scale0
      USE cutcell
      USE dashboard
      USE des_allocate
      USE des_rxns
      USE des_thermo
      USE desgrid, only: desgrid_init
      USE discretelement
      USE error_manager
      USE funits
      USE gridmap
      USE iterate, only: max_nit
      USE leqsol
      USE mfix_pic
      USE mpi_init_des, only: desmpi_init
      USE parallel
      USE param
      USE param1
      USE qmom_kinetic_equation
      USE run
      USE stl_preproc_des, only: des_stl_preprocessing
      USE visc_g, only: l_scale

      IMPLICIT NONE
!-----------------------------------------------
! Local variables
!-----------------------------------------------
! shift DX, DY and DZ values
      LOGICAL, PARAMETER :: SHIFT = .true.

! This module call routines to initialize the namelist variables.
      CALL init_namelist
! Read in the namelist variables from the ascii input file.
      CALL read_namelist(0,"mfix.dat")

! Initialize the error manager. This call occurs after the mfix.dat
! is read so that message verbosity can be set and the .LOG file
! can be opened.
      CALL init_error_manager

! Write header in the .LOG file and to screen.
! Not sure if the values are correct or useful
      CALL write_header

! Open files
      CALL open_files(run_name, run_type, n_spx)

! These checks verify that sufficient information was provided
! to setup the domain indices and DMP gridmap.
      CALL check_geometry_prereqs
      CALL check_dmp_prereqs

! Set up the physical domain indicies (cell index max/min values).
      CALL set_max2

! Set constants
      CALL set_constants

! Adjust partition for better load balance (done when RE_INDEXING is .TRUE.)
      CALL adjust_ijk_size

! Partition the domain and set indices
      CALL gridmap_init

! Check the minimum solids phase requirements.
      CALL check_solids_model_prereqs

      CALL check_run_control
      CALL check_numerics
      CALL check_output_control

      CALL check_gas_phase
      CALL check_solids_phases
      CALL set_parameters

! Basic geometry checks.
      CALL check_geometry(shift)
      IF(discrete_element) CALL check_geometry_des

! Set grid spacing variables.
      CALL set_geometry
      IF(discrete_element) CALL set_geometry_des

      CALL check_initial_conditions
      CALL check_boundary_conditions
      CALL check_internal_surfaces
      CALL check_point_sources

      CALL check_chemical_rxns
      CALL check_odepack_stiff_chem



!----------------------  DOMAIN SPECIFIC CHECKS  --------------------!


! This call needs to occur before any of the IC/BC checks.
      CALL set_icbc_flag

! Compute area of boundary surfaces.
      CALL get_bc_area

! Convert (mass, volume) flows to velocities.
      CALL set_bc_flow

! Set the flags for identifying computational cells
      CALL set_flags
! Set arrays for computing indices
      CALL set_increments
      CALL set_increments3

! Cartesian grid implementation
      CALL check_data_cartesian
      IF(cartesian_grid) THEN
         CALL cut_cell_preprocessing
      ELSE
         CALL allocate_dummy_cut_cell_arrays
      ENDIF

      IF(discrete_element) THEN
         CALL desgrid_init
         CALL desmpi_init
         CALL des_stl_preprocessing
      ENDIF

!--------------------------  ARRAY ALLOCATION -----------------------!

! Allocate array storage.
      CALL allocate_arrays
      IF(discrete_element) CALL des_allocate_arrays
      IF(qmomk) CALL qmomk_allocate_arrays

! Initialize arrays.
      CALL init_fvars
      IF(discrete_element) CALL des_init_arrays

! This is all that happens in SET_L_SCALE so it needs moved, maybe
! this should go in int_fluid_var.?
!     CALL SET_L_SCALE
      l_scale(:) = l_scale0

!======================================================================
! Data initialization for Dashboard
!======================================================================
      init_time = time
      smmin =  large_number
      smmax = -large_number

      dtmin =  large_number
      dtmax = -large_number

      nit_min = max_nit
      nit_max = 0

      n_dashboard = 0


      RETURN

    END SUBROUTINE get_data

!vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvC
!                                                                      C
!  Subroutine: SET_CONSTANTS                                           C
!  Purpose: Set various constants                                      C
!                                                                      C
!  Author: M. Syamlal                                 Date: 30-JAN-92  C
!                                                                      C
!^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^C
      SUBROUTINE set_constants

! Modules
!---------------------------------------------------------------------//
      USE param1, only: zero, one, undefined
      USE constant, only: gas_const
      USE constant, only: gravity, gravity_x, gravity_y, gravity_z
      USE constant, only: to_si
      USE constant, only: k_scale
      USE run, only: lam_hys, units
      USE error_manager, only: err_msg, init_err_msg, finl_err_msg
      USE error_manager, only: flush_err_msg

      IMPLICIT NONE
!---------------------------------------------------------------------//

! Note that the cell flags are not set when this routine is called.

! Dimensionless constants
      k_scale = .08d0   ! this actually isn't used anywhere...

! Enter the value of all constants in various units (CGS or SI)
      IF (units == 'SI') THEN
         IF (gravity == undefined) gravity = 9.80665d0 ! m/s2
         gas_const = 8314.56d0                !Pa.m3/kmol.K, or kg m2/s2 kmol K (Perry and Green, 1984)
         to_si = 0.1d0                        !to convert dyne/cm2 to Pa. e.g. calc_mu_g.f
         IF (lam_hys == undefined) lam_hys = 0.000001d0    ! m
      ELSEIF (units == 'CGS') THEN
         IF (gravity == undefined) gravity = 980.665d0 !cm/s2
         gas_const = 8314.56d4                !g.cm2/s2.mol.K
         to_si = one                          !does not do anything in CGS. e.g.: calc_mu_g.f
         IF (lam_hys == undefined) lam_hys = 0.0001d0    ! cm
      ELSE
! Initialize the error manager.
         CALL init_err_msg("SET_CONSTANTS")
         WRITE(err_msg,1005) units
         CALL flush_err_msg(abort=.true.)
         CALL finl_err_msg
 1005 FORMAT('Error 1005: Unknown UNITS = ',a,/ &
         'Please correct the mfix.dat file.')
      ENDIF

! If all components of the gravitational acceleration vector are
! undefined (zero), then use the default value for the negative
! y-direction. This ensures backward compatibility with the old
! (legacy) GRAVITY keyword. At this point GRAVITY is defined,
! either from mfix.dat or by default above
      IF(gravity_x==zero.AND.gravity_y==zero.AND.gravity_z==zero) THEN
         gravity_x = zero
         gravity_y = - gravity
         gravity_z = zero
      ENDIF

      RETURN
      END SUBROUTINE set_constants
    END MODULE read_input